#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)
AC_INIT(pdnmesh, 0.2.2, pdnmesh-bugs@lists.soureforge.net)
# for automake
AM_INIT_AUTOMAKE(pdnmesh,0.2.2)

# unique file in soure dir to check it really exists
AC_CONFIG_SRCDIR(src/pdnmesh.c)
AC_CONFIG_HEADERS(config.h)

dnl # Checks for programs.
AC_PROG_AWK
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AM_PROG_LEX
AC_PROG_YACC
AC_PROG_F77
dnl # Checks for libraries.
AC_PATH_X
AC_PATH_XTRA

dnl # GTK
AM_PATH_GTKGLEXT_1_0(1.0.0,
 [LIBS="$LIBS $GTKGLEXT_LIBS"
 CFLAGS="$CFLAGS $GTKGLEXT_CFLAGS"],
 AC_MSG_ERROR(Cannot find GTKGLExt. You may need to install this.\
 If you have already installed it add  pkg-config into PATH and try again.))



# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([inttypes.h stddef.h stdlib.h string.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_SIZE_T

dnl # Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_REALLOC
AC_FUNC_STRTOD
AC_CHECK_FUNCS([memset pow sqrt strtol])

dnl # Check for POSIX threads
ACX_PTHREAD([AC_DEFINE(HAVE_PTHREAD,1,[Use pthreads])
           LIBS="$PTHREAD_LIBS $LIBS"
           CFLAGS="$CFLAGS $PTHREAD_CFLAGS" CC="$PTHREAD_CC"],
           AC_MSG_WARN([Cannot Find POSIX thread support. If you have a\ 
 single processor machine this is OK. But if you have \
 a machine with multiprocessor or hyperthreadin support\
 enabling thread support will improve performance.]))

dnl # Check for BLAS and LAPACK
ACX_BLAS
ACX_LAPACK([AC_DEFINE(USE_LAPACK,1,[Use LAPACK])
           LIBS="$LAPACK_LIBS $BLAS_LIBS $LIBS"],
 AC_MSG_WARN([Cannot find LAPACK. If You have LAPACK try again\ 
 with --with-lapack=<libpath>. Otherwise generic eigenroutines will be used.]))

dnl # Check for ARPACK
AC_ARG_ENABLE(arpack,
   [AC_HELP_STRING([--enable-arpack],
         [Enable ARPACK support])],
   [ arpack_lib="-larpack"],
   [ arpack_lib=""])
if test  "${arpack_lib}" != ""; then
  AC_DEFINE(USE_ARPACK,,[Use ARPACK])
fi
AC_SUBST(F77LINK,"\$(LINK)")
AC_SUBST(arpack_lib)

AC_CONFIG_FILES([Makefile
  src/Makefile
  doc/Makefile
  doc/tutorial/Makefile
  doc/examples/Makefile
  man/Makefile
  man/pdnmesh.1
  man/pdnmesh_input.5
	win32/Makefile
  win32/res/Makefile
	pixmaps/Makefile
	debian/Makefile])
AC_CONFIG_COMMANDS([default],[[echo timestamp > stamp-h ]],[[]])
AC_OUTPUT