dnl Process this file with autoconf to produce a configure script.
AC_INIT(sid.h)

dnl Use Automake
AM_INIT_AUTOMAKE(resid, 0.16vice)
LTVERSION=5:0:0

dnl Use C++ for tests.
AC_LANG_CPLUSPLUS

AC_CANONICAL_HOST

dnl Enable inlining.
AC_ARG_ENABLE(inline,
[  --enable-inline         enable inlining of functions [default=yes]])

if test "$enable_inline" != no; then
  RESID_INLINING=1
  RESID_INLINE=inline
else
  RESID_INLINING=0
  RESID_INLINE=
fi

AC_SUBST(RESID_INLINING)
AC_SUBST(RESID_INLINE)

dnl Enable experimental 8580 filters.
AC_ARG_ENABLE([new8580filter],
  [AC_HELP_STRING([--enable-new8580filter],
    [enable experimental 8580 filters [default=no]])],
  [],
  [])

AS_IF([test x"$enable_new8580filter" = "xyes"],
  [AC_SUBST([NEW_8580_FILTER], [1])],
  [AC_SUBST([NEW_8580_FILTER], [0])])

dnl Checks for programs.
AC_PROG_CXX([g++ clang++])

dnl Set CXXFLAGS for g++. Use -fno-exceptions if supported.
if test "$GXX" = yes; then
  if test "$ac_test_CXXFLAGS" != set; then
    CXXFLAGS="-g -Wall -O2 -funroll-loops -fomit-frame-pointer -fno-exceptions"
    AC_MSG_CHECKING([whether the C++ compiler ($CXX $CXXFLAGS $LDFLAGS) works])
    AC_TRY_COMPILE([],
                   [int test;],
                   [ AC_MSG_RESULT(yes) ],
                   [ AC_MSG_RESULT(no)
                     CXXFLAGS="-g -Wall -O2 -funroll-loops -fomit-frame-pointer"
                     ])
  fi
  case $host_os in
  darwin*)
    CFLAGS="$CFLAGS -mmacosx-version-min=10.9"
    OBJCFLAGS="$OBJCFLAGS -mmacosx-version-min=10.9"
    CXXFLAGS="$CXXFLAGS -mmacosx-version-min=10.9"
    LDFLAGS="$LDFLAGS -mmacosx-version-min=10.9"
    ;;
  *)
    ;;
  esac
fi


AC_CHECK_PROG(AR, ar, ar, ar)
AC_PROG_RANLIB

dnl Libtool

dnl AC_DISABLE_SHARED
dnl AM_PROG_LIBTOOL
dnl AC_SUBST(LIBTOOL_DEPS)
dnl AC_SUBST(LTVERSION)

dnl Checks for libraries.

dnl Checks for header files.

dnl Checks for typedefs, structures, and compiler characteristics.
AC_CHECK_SIZEOF(int, 4)

if test $ac_cv_sizeof_int -lt 4; then
  AC_MSG_ERROR([only 32 bit or better CPUs are supported])
fi

AC_CACHE_CHECK([for working bool], ac_cv_cxx_bool,
[AC_TRY_COMPILE(,
[
bool flag;
],
ac_cv_cxx_bool=yes, ac_cv_cxx_bool=no)])

if test $ac_cv_cxx_bool = no; then
  RESID_HAVE_BOOL=0
else
  RESID_HAVE_BOOL=1
fi

AC_SUBST(RESID_HAVE_BOOL)

AC_MSG_CHECKING([if the mmintrin.h include can be used])
AC_TRY_COMPILE([#include <mmintrin.h>],
               [int test;],
               [ AC_MSG_RESULT(yes)
                 HAVE_MMINTRIN_H=1
                 ],
               [ AC_MSG_RESULT(no)
                 HAVE_MMINTRIN_H=0
                 ])

if test $HAVE_MMINTRIN_H = 0; then
  old_CXXFLAGS=$CXXFLAGS
  CXXFLAGS="$CXXFLAGS -mmmx"
  AC_MSG_CHECKING([if -mmmx is needed to activate MMX])
  AC_TRY_COMPILE([#include <mmintrin.h>],
                 [int test;],
                 [ AC_MSG_RESULT(yes)
                   HAVE_MMINTRIN_H=1
                   ],
                 [ AC_MSG_RESULT(no)
                   HAVE_MMINTRIN_H=0
                   CXXFLAGS=$old_CXXFLAGS
                   ])
fi

AC_SUBST(HAVE_MMINTRIN_H)

dnl Checks for library functions.

AC_OUTPUT(Makefile siddtvdefs.h)