/*
 * Copyright (c) 2018 The DragonFly Project.  All rights reserved.
 *
 * This code is derived from software contributed to The DragonFly Project
 * by Matthew Dillon <dillon@backplane.com>
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 *
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in
 *    the documentation and/or other materials provided with the
 *    distribution.
 * 3. Neither the name of The DragonFly Project nor the names of its
 *    contributors may be used to endorse or promote products derived
 *    from this software without specific, prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
 * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
 * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
 * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
 * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
 * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 * SUCH DAMAGE.
 */
#include <machine/asm.h>

/*
 * %rdi:ptr %rsi:data %rdx:bytes
 */
ENTRY(memset)
	movq	%rdi,%r8	/* Save base pointer for return */
	movq    %rdx,%rcx	/* Setup count in %rcx */
	movq	%rsi,%rax	/* Setup data in %rax for byte store */
	cld
	cmpq	$15,%rdx	/* trivial case */
	jle	2f
	testq	%rax,%rax	/* trivial case (0) */
	jz	1f

	andq	$0xFF,%rax	/* shift 0:7 to all bytes in %rax */
	movq	%rax,%rsi
	salq	$8,%rax
	orq	%rsi,%rax
	orq	%rax,%rsi
	salq	$16,%rsi
	orq	%rsi,%rax
	orq	%rax,%rsi
	salq	$32,%rsi
	orq	%rsi,%rax
1:
	shrq    $3,%rcx
	rep
	stosq
	movq    %rdx,%rcx
	andq    $7,%rcx
	jnz     2f
	movq	%r8,%rax
	ret
2:      rep
	stosb
	movq	%r8,%rax
	ret
END(memset)

	.section .note.GNU-stack,"",%progbits
