// Tencent is pleased to support the open source community by making ncnn available.
//
// Copyright (C) 2019 THL A29 Limited, a Tencent company. All rights reserved.
//
// Licensed under the BSD 3-Clause License (the "License"); you may not use this file except
// in compliance with the License. You may obtain a copy of the License at
//
// https://opensource.org/licenses/BSD-3-Clause
//
// Unless required by applicable law or agreed to in writing, software distributed
// under the License is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR
// CONDITIONS OF ANY KIND, either express or implied. See the License for the
// specific language governing permissions and limitations under the License.

#version 450

#if NCNN_fp16_storage
#extension GL_EXT_shader_16bit_storage: require
#endif
#if NCNN_fp16_arithmetic
#extension GL_EXT_shader_explicit_arithmetic_types_float16: require
#endif

layout (constant_id = 0) const int region_type = 0;
layout (constant_id = 1) const int pad_head = 0;
layout (constant_id = 2) const int pad_tail = 0;

#define shape_constant_id_offset 3
layout (constant_id = shape_constant_id_offset + 0) const int dims = 0;
layout (constant_id = shape_constant_id_offset + 1) const int w = 0;
layout (constant_id = shape_constant_id_offset + 2) const int h = 0;
layout (constant_id = shape_constant_id_offset + 3) const int c = 0;
layout (constant_id = shape_constant_id_offset + 4) const int cstep = 0;

layout (constant_id = shape_constant_id_offset + 5) const int outdims = 0;
layout (constant_id = shape_constant_id_offset + 6) const int outw = 0;
layout (constant_id = shape_constant_id_offset + 7) const int outh = 0;
layout (constant_id = shape_constant_id_offset + 8) const int outc = 0;
layout (constant_id = shape_constant_id_offset + 9) const int outcstep = 0;

#if NCNN_image_shader
layout (binding = 0) uniform unfp sampler3D bottom_blob;
layout (binding = 1, r32f) writeonly uniform highp image3D square_workspace;
#else
layout (binding = 0) readonly buffer bottom_blob { sfp bottom_blob_data[]; };
layout (binding = 1) writeonly buffer square_workspace { float square_workspace_data[]; };
#endif

layout (push_constant) uniform parameter
{
    int dims;
    int w;
    int h;
    int c;
    int cstep;

    int outdims;
    int outw;
    int outh;
    int outc;
    int outcstep;
} p;

void main()
{
    int gx = int(gl_GlobalInvocationID.x);
    int gy = int(gl_GlobalInvocationID.y);
    int gz = int(gl_GlobalInvocationID.z);

    if (gx >= psc(outw) || gy >= psc(outh) || gz >= psc(outc))
        return;

    afp res;

    if (region_type == 0)
    {
        int z = gz - pad_head;

        if (z >= 0 && z < psc(c))
        {
#if NCNN_image_shader
            afp v = image3d_ld1(bottom_blob, ivec3(gx, gy, z));
#else
            int v_offset = z * psc(cstep) + gy * psc(w) + gx;
            afp v = buffer_ld1(bottom_blob_data, v_offset);
#endif
            res = v * v;
        }
        else
        {
            res = afp(0.f);
        }
    }
    else
    {
        int x = gx - pad_head;
        int y = gy - pad_head;

        if (x >= 0 && x < psc(w) && y >= 0 && y < psc(h))
        {
#if NCNN_image_shader
            afp v = image3d_ld1(bottom_blob, ivec3(x, y, gz));
#else
            int v_offset = gz * psc(cstep) + y * psc(w) + x;
            afp v = buffer_ld1(bottom_blob_data, v_offset);
#endif
            res = v * v;
        }
        else
        {
            res = afp(0.f);
        }
    }

#if NCNN_image_shader
    imageStore(square_workspace, ivec3(gx, gy, gz), vec4(float(res)));
#else
    const int gi = gz * psc(outcstep) + gy * psc(outw) + gx;

    square_workspace_data[gi] = float(res);
#endif
}