1AC_DEFUN([AC_FLDIGI_OSS], [
2  AC_REQUIRE([AC_FLDIGI_MACOSX])
3  AC_REQUIRE([AC_FLDIGI_WIN32])
4  if test "x$target_darwin" = "xno" && test "x$target_win32" = "xno"; then
5      AC_ARG_ENABLE([oss],
6                    AC_HELP_STRING([--disable-oss], [disable support for OSS @<:@autodetect@:>@]),
7                    [case "${enableval}" in
8                      yes|no) ac_cv_want_oss="${enableval}" ;;
9                      *)      AC_MSG_ERROR([bad value "${enableval}" for --disable-oss]) ;;
10                     esac],
11                     [ac_cv_want_oss=check])
12  else
13      AC_MSG_NOTICE([disabling OSS driver on $target_os])
14      ac_cv_want_oss=no
15  fi
16
17  ac_cv_oss=no
18  if test "x$ac_cv_want_oss" = "xno"; then
19      AC_DEFINE(USE_OSS, 0, [Defined if we are using OSS])
20  else
21      AC_CHECK_HEADER( [sys/soundcard.h], [ac_cv_oss=yes],
22                       [AC_CHECK_HEADER([machine/soundcard.h], [ac_cv_oss=yes],
23		       [AC_CHECK_HEADER([soundcard.h], [ac_cv_oss=yes], [])])])
24      if test "x$ac_cv_want_oss" = "xcheck"; then
25          if test "x$ac_cv_oss" = "xyes"; then
26              AC_DEFINE(USE_OSS, 1, [Defined if we are using OSS])
27          else
28              AC_MSG_NOTICE([disabling OSS driver])
29              AC_DEFINE(USE_OSS, 0, [Defined if we are using OSS])
30          fi
31      else # $ac_cv_want_oss is yes
32          if test "x$ac_cv_oss" = "xno"; then
33              AC_MSG_FAILURE([--enable-oss was given, but test for OSS failed])
34          else
35              AC_DEFINE(USE_OSS, 1, [Defined if we are using OSS])
36          fi
37      fi
38  fi
39])
40
41