1package App::Netdisco::Worker::Plugin::Hook::HTTP;
2
3use Dancer ':syntax';
4use App::Netdisco::Worker::Plugin;
5use aliased 'App::Netdisco::Worker::Status';
6
7use MIME::Base64 'decode_base64';
8use HTTP::Tiny;
9use Template;
10
11register_worker({ phase => 'main' }, sub {
12  my ($job, $workerconf) = @_;
13  my $extra = from_json( decode_base64( $job->extra || '' ) );
14  $job->subaction('');
15
16  my $event_data  = $extra->{'event_data'};
17  my $action_conf = $extra->{'action_conf'};
18  $action_conf->{'body'} ||= to_json($event_data);
19
20  return Status->error('missing url parameter to http Hook')
21    if !defined $action_conf->{'url'};
22
23  my $tt = Template->new({ ENCODING => 'utf8' });
24  my $http = HTTP::Tiny
25    ->new( timeout => (($action_conf->{'timeout'} || 5000) / 1000) );
26
27  $action_conf->{'custom_headers'} ||= {};
28  $action_conf->{'custom_headers'}->{'Content-Type'}
29    ||= 'application/json; charset=UTF-8';
30  $action_conf->{'custom_headers'}->{'Authorization'}
31    = ('Bearer '. $action_conf->{'bearer_token'})
32      if $action_conf->{'bearer_token'};
33
34  my ($orig_url, $url) = ($action_conf->{'url'}, undef);
35  $action_conf->{'url_is_template'} ||= 1
36    if !exists $action_conf->{'url_is_template'};
37  $tt->process(\$orig_url, $event_data, \$url)
38    if $action_conf->{'url_is_template'};
39  $url ||= $orig_url;
40
41  my ($orig_body, $body) = ($action_conf->{'body'} , undef);
42  $action_conf->{'body_is_template'} ||= 1
43    if !exists $action_conf->{'body_is_template'};
44  $tt->process(\$orig_body, $event_data, \$body)
45    if $action_conf->{'body_is_template'};
46  $body ||= $orig_body;
47
48  my $response = $http->request(
49    ($action_conf->{'method'} || 'POST'), $url,
50    { headers => $action_conf->{'custom_headers'},
51      content => $body },
52  );
53
54  if ($action_conf->{'ignore_failure'} or $response->{'success'}) {
55    return Status->done(sprintf 'HTTP Hook: %s %s',
56      $response->{'status'}, $response->{'reason'});
57  }
58  else {
59    return Status->error(sprintf 'HTTP Hook: %s %s',
60      $response->{'status'}, $response->{'reason'});
61  }
62});
63
64true;
65