1package App::Netdisco::Worker::Plugin::PortControl;
2
3use Dancer ':syntax';
4use App::Netdisco::Worker::Plugin;
5use aliased 'App::Netdisco::Worker::Status';
6
7use App::Netdisco::Transport::SNMP;
8use App::Netdisco::Util::Port ':all';
9
10register_worker({ phase => 'check' }, sub {
11  my ($job, $workerconf) = @_;
12  return Status->error('Missing device (-d).') unless defined $job->device;
13  return Status->error('Missing port (-p).') unless defined $job->port;
14  return Status->error('Missing status (-e).') unless defined $job->subaction;
15
16  vars->{'port'} = get_port($job->device, $job->port)
17    or return Status->error(sprintf "Unknown port name [%s] on device %s",
18                              $job->port, $job->device);
19
20  my $port_reconfig_check = port_reconfig_check(vars->{'port'});
21  return Status->error("Cannot alter port: $port_reconfig_check")
22    if $port_reconfig_check;
23
24  return Status->done('PortControl is able to run');
25});
26
27register_worker({ phase => 'main', driver => 'snmp' }, sub {
28  my ($job, $workerconf) = @_;
29  my ($device, $pn) = map {$job->$_} qw/device port/;
30
31  # need to remove "-other" which appears for power/portcontrol
32  (my $sa = $job->subaction) =~ s/-\w+//;
33  $job->subaction($sa);
34
35  if ($sa eq 'bounce') {
36    $job->subaction('down');
37    my $status = _action($job);
38    return $status if $status->not_ok;
39    $job->subaction('up');
40  }
41
42  return _action($job);
43});
44
45sub _action {
46  my $job = shift;
47  my ($device, $pn, $data) = map {$job->$_} qw/device port subaction/;
48
49  # snmp connect using rw community
50  my $snmp = App::Netdisco::Transport::SNMP->writer_for($device)
51    or return Status->defer("failed to connect to $device to update up_admin");
52
53  my $iid = get_iid($snmp, vars->{'port'})
54    or return Status->error("Failed to get port ID for [$pn] from $device");
55
56  my $rv = $snmp->set_i_up_admin($data, $iid);
57
58  if (!defined $rv) {
59      return Status->error(sprintf "Failed to set [%s] up_admin to [%s] on $device: %s",
60                    $pn, $data, ($snmp->error || ''));
61  }
62
63  # confirm the set happened
64  $snmp->clear_cache;
65  my $state = ($snmp->i_up_admin($iid) || '');
66  if (ref {} ne ref $state or $state->{$iid} ne $data) {
67      return Status->error("Verify of [$pn] up_admin failed on $device");
68  }
69
70  # update netdisco DB
71  vars->{'port'}->update({up_admin => $data});
72
73  return Status->done("Updated [$pn] up_admin on [$device] to [$data]");
74}
75
76true;
77