1package App::Netdisco::Worker::Plugin::Power;
2
3use Dancer ':syntax';
4use App::Netdisco::Worker::Plugin;
5use aliased 'App::Netdisco::Worker::Status';
6
7use App::Netdisco::Transport::SNMP;
8use App::Netdisco::Util::Port ':all';
9
10register_worker({ phase => 'check' }, sub {
11  my ($job, $workerconf) = @_;
12  my ($device, $pn) = map {$job->$_} qw/device port/;
13
14  return Status->error('Missing device (-d).') unless defined $job->device;
15  return Status->error('Missing port (-p).') unless defined $job->port;
16  return Status->error('Missing status (-e).') unless defined $job->subaction;
17
18  vars->{'port'} = get_port($job->device, $job->port)
19    or return Status->error(sprintf "Unknown port name [%s] on device %s",
20                              $job->port, $job->device);
21
22  my $port_reconfig_check = port_reconfig_check(vars->{'port'});
23  return Status->error("Cannot alter port: $port_reconfig_check")
24    if $port_reconfig_check;
25
26  return Status->error("No PoE service on port [$pn] on device $device")
27    unless vars->{'port'}->power;
28
29  return Status->done('Power is able to run');
30});
31
32register_worker({ phase => 'main', driver => 'snmp' }, sub {
33  my ($job, $workerconf) = @_;
34  my ($device, $pn) = map {$job->$_} qw/device port/;
35
36  # munge data
37  (my $data = $job->subaction) =~ s/-\w+//; # remove -other
38  $data = 'true'  if $data =~ m/^(on|yes|up)$/;
39  $data = 'false' if $data =~ m/^(off|no|down)$/;
40
41  # snmp connect using rw community
42  my $snmp = App::Netdisco::Transport::SNMP->writer_for($device)
43    or return Status->defer("failed to connect to $device to set power");
44
45  my $powerid = get_powerid($snmp, vars->{'port'})
46    or return Status->error("failed to get power ID for [$pn] from $device");
47
48  my $rv = $snmp->set_peth_port_admin($data, $powerid);
49
50  if (!defined $rv) {
51      return Status->error(sprintf 'failed to set [%s] power to [%s] on [%s]: %s',
52                    $pn, $data, $device, ($snmp->error || ''));
53  }
54
55  # confirm the set happened
56  $snmp->clear_cache;
57  my $state = ($snmp->peth_port_admin($powerid) || '');
58  if (ref {} ne ref $state or $state->{$powerid} ne $data) {
59      return Status->error("Verify of [$pn] power failed on $device");
60  }
61
62  # update netdisco DB
63  vars->{'port'}->power->update({
64    admin => $data,
65    status => ($data eq 'false' ? 'disabled' : 'searching'),
66  });
67
68  return Status->done("Updated [$pn] power status on $device to [$data]");
69});
70
71true;
72