1dnl SMB_CHECK_ICONV(hdr, msg, action-if-found,action-if-not-found)
2AC_DEFUN(SMB_CHECK_ICONV,[
3  AC_MSG_CHECKING($2)
4  AC_TRY_RUN([#include <stdlib.h>
5#include <$1>
6
7int main()
8{
9   iconv_t cd = iconv_open("ASCII","UCS-2LE");
10   if (cd == 0 || cd == (iconv_t)-1) return -1;
11   return 0;
12}
13   ],[AC_MSG_RESULT(yes); $3],[AC_MSG_RESULT(no); $4])
14])
15
16dnl SMB_CHECK_ICONV_DIR(dir,action-if-found,action-if-not-found)
17AC_DEFUN(SMB_CHECK_ICONV_DIR,
18[
19	save_CPPFLAGS="$CPPFLAGS"
20	save_LDFLAGS="$LDFLAGS"
21	save_LIBS="$LIBS"
22	CPPFLAGS="-I$1/include"
23	LDFLAGS="-L$1/lib"
24	LIBS=-liconv
25
26	SMB_CHECK_ICONV(iconv.h,Whether iconv.h is present,[ AC_DEFINE(HAVE_ICONV_H,1,[Whether iconv.h is present]) $2 ], [
27        LIBS=-lgiconv
28        SMB_CHECK_ICONV(giconv.h,Whether giconv.h is present, [AC_DEFINE(HAVE_GICONV_H,1,[Whether giconv.h is present]) $2],[$3])
29	])
30
31	CPPFLAGS="$save_CPPFLAGS"
32	LDFLAGS="$save_LDFLAGS"
33	LIBS="$save_LIBS"
34])
35
36ICONV_FOUND=no
37LOOK_DIRS="/usr /usr/local /sw"
38AC_ARG_WITH(libiconv,
39[  --with-libiconv=BASEDIR Use libiconv in BASEDIR/lib and BASEDIR/include (default=auto) ],
40[
41  if test "$withval" = "no" ; then
42    AC_MSG_ERROR(I won't take no for an answer)
43  else
44     if test "$withval" != "yes" ; then
45	SMB_CHECK_ICONV_DIR($withval, [
46		ICONV_FOUND=yes;
47		ICONV_CPPFLAGS="$CPPFLAGS"
48		ICONV_LIBS="$LIBS"
49		ICONV_LDFLAGS="$LDFLAGS"
50		], [AC_MSG_ERROR([No iconv library found in $withval])])
51     fi
52  fi
53])
54
55if test x$ICONV_FOUND = xno; then
56	SMB_CHECK_ICONV(iconv.h,
57		[Whether iconv.h is present],
58		[AC_DEFINE(HAVE_ICONV_H,1,[Whether iconv.h is present]) ICONV_FOUND=yes])
59fi
60
61for i in $LOOK_DIRS ; do
62	if test x$ICONV_FOUND = xyes; then
63		break
64	fi
65
66	SMB_CHECK_ICONV_DIR($i, [
67		ICONV_FOUND=yes
68		ICONV_CPPFLAGS="$CPPFLAGS"
69		ICONV_LIBS="$LIBS"
70		ICONV_LDFLAGS="$LDFLAGS"
71		], [])
72done
73
74if test x"$ICONV_FOUND" = x"no"; then
75    AC_MSG_WARN([Sufficient support for iconv function was not found.
76    Install libiconv from http://www.gnu.org/software/libiconv/ for better charset compatibility!])
77	SMB_ENABLE(ICONV,NO)
78else
79	AC_DEFINE(HAVE_NATIVE_ICONV,1,[Whether external iconv is available])
80	SMB_ENABLE(ICONV,YES)
81fi
82
83SMB_EXT_LIB(ICONV,[${ICONV_LIBS}],[${ICONV_CFLAGS}],[${ICONV_CPPFLAGS}],[${ICONV_LDFLAGS}])
84