xref: /dports/graphics/grads/grads-1.9b4/configure.in

dnl
dnl configure.in:
dnl
dnl  Source file for GrADS auto-configuration script.
dnl
dnl  Run ./bootstrap to generate a configure script from this file
dnl  using autoconf.
dnl
dnl  See acinclude.m4 for definitions of the GA_xxx macros

# The version number
# below is the "master" version that will appear in all code, etc.
AC_INIT(GrADS, [1.9b4])

# Require autoconf 2.52 (comes with Mac OS X 10.2) or newer
AC_PREREQ(2.52)

# Supporting scripts are in etc/
AC_CONFIG_AUX_DIR(etc)

# Require automake 1.6 (comes with Mac OS X 10.2) or newer,
# don't #define PACKAGE and VERSION,
# disable dependency checking
AM_INIT_AUTOMAKE([1.6 no-define no-dependencies])

AM_CONFIG_HEADER([src/config.h])

# The following macro prevents annoying interactions between CVS and
# automake, which result in make attempting to invoke autotools
# even when the configure script is up to date
AM_MAINTAINER_MODE


# I personally think it is nicer to have binaries go to ./bin by default,
# rather than /usr/bin.
AC_PREFIX_DEFAULT(`pwd`)


# ----------------------------------------------------
#  Additional arguments for the configure script
# ----------------------------------------------------

AC_ARG_WITH(readline, AC_HELP_STRING([--with-readline],
                    [command line editing via readline]))
AC_ARG_WITH(printim,  AC_HELP_STRING([--with-printim],
                    [printim command - image output using GD]))
AC_ARG_WITH(lats,     AC_HELP_STRING([--with-lats],
                    [LATS interface for generating GRIB and netCDF files]))
AC_ARG_WITH(gui,      AC_HELP_STRING([--with-gui],
                    [Athena X11 widget-based GUI]))
AC_ARG_WITH(nc,      AC_HELP_STRING([--with-nc],
                     [gradsnc executable, with netCDF support]))
AC_ARG_WITH(dods,     AC_HELP_STRING([--with-dods],
                     [gradsdods executable, with netCDF and DODS support]))
AC_ARG_WITH(hdf,      AC_HELP_STRING([--with-hdf],
                     [gradshdf executable, with netCDF and NCSA HDF4]))
AC_ARG_WITH(xlibemu,  AC_HELP_STRING([--with-xlibemu],
		     [Use X11 Emulation library (Win32 only)]))

AC_ARG_WITH(wi,       AC_HELP_STRING([--with-wi],
                    [wi command - image output using ImageMagick \
                     (Note: this feature is deprecated in favor of the \
		      printim command,  and is disabled by default.]))

AC_ARG_ENABLE(old-supplibs, AC_HELP_STRING([--enable-old-supplibs],
    [Use pre-1.9 non-canonical names for supplib directories]),
    [old_supplibs="yes"])

AC_ARG_ENABLE(dyn-supplibs, AC_HELP_STRING([--enable-dyn-supplibs],
    [Use dynamic (shared object) system libraries, if present, for optional features. This will produce smaller, but possibly less portable, binaries. By default, only static libraries from a GrADS supplibs distribution will be used for optional feature support to maximize binary portability.]),
    [ GA_ENABLE_DYNAMIC() ])

AC_ARG_VAR(SUPPLIBS,
           [Custom path (must be absolute) to a GrADS supplib distribution])


# ----------------------------------------------------
# Checks for programs
# ----------------------------------------------------

echo
echo "Checking for programs"
echo "------------------"
if test -z "$CFLAGS" ; then
  CFLAGS="-g -O"
fi
AC_PROG_AWK
AC_PROG_CC
AC_PROG_CXX
AC_PROG_INSTALL
AC_PROG_LN_S
echo

echo "Setting host specific options"
echo "-------------------------"

# ----------------------------------------------------
# Get host platform
# ----------------------------------------------------

AC_CANONICAL_HOST()

# echo Host machine:   "$host"
# echo Host vendor: "$host_vendor"
# echo Host OS:     "$host_os"
# echo Host CPU:    "$host_cpu"

# ----------------------------------------------------
# Set supplibs directory name
# ----------------------------------------------------

GA_SET_SUPPLIBS([. ..])

# ----------------------------------------------------
# Set host specific options
# ----------------------------------------------------

case "$host" in

  alpha-*-osf*)
    # Option needed for IEEE floating points
    CFLAGS="$(CFLAGS) -ieee"
  ;;

  cray-*-*)
    # Used for define below
    is_cray="yes"
  ;;

  i*86-pc-linux-*)
  ;;

  sparc-sun-solaris*)
    # Some system calls are in unusual places
    host_ldadd="-lsocket -lnsl -lw"
    guilibadd="-lSM -lICE"
  ;;

dnl ARLINDO please edit the win stuff appropriately
  i*86-*-win*)

    if test "$with_xlibemu" != "no" ; then
      echo "Check for X emulation libraries..."
      AC_CHECK_LIB(grx20, main, [use_xlibemu=yes])
      if test "$use_xlibemu" = "yes" ; then
       	xlibemu_libs="-lgrx20 -mwindows"
	AC_SUBST(xlibemu_libs)
      fi
    fi
  ;;

  *-hpux11*)
     # Used for define below
     is_hpux11="yes"
  ;;

  *-darwin*)
     # Used for DODS 3.2 linking kludge
     is_darwin="yes"
  ;;
esac

if test is_cray!="yes" ; then
   AC_DEFINE(GRADS_CRAY, 0, [Machine is NOT a Cray])
else
    AC_DEFINE(GRADS_CRAY, 1, [Machine is a Cray])
fi

if test is_hpux11!="yes" ; then
AC_DEFINE(GRADS_HP64, 0, [Machine is NOT a 64-bit HP])
else
AC_DEFINE(GRADS_HP64, 1, [Machine is 64-bit HP])
fi

# ----------------------------------------------------
# Check for basic libraries.
# ----------------------------------------------------

echo
echo "Checking system libraries, headers, and compiler features"
echo "-----------------------------------------"

AC_CHECK_LIB(m,cos,, AC_MSG_ERROR([Fatal: Math library not found]))

dnl get X11 library path
AC_PATH_XTRA

dnl for basic X-windows support
dnl joew: Don't think this is needed after AC_PATH_XTRA
# AC_CHECK_LIB(X11, XOpenDisplay,, AC_MSG_ERROR([Fatal: X11 library not found]))

echo

# ----------------------------------------------------
# Check for basic header files.
# ----------------------------------------------------

AC_HEADER_STDC
AC_CHECK_HEADERS(malloc.h sys/file.h unistd.h)
echo

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST

dnl joew - In autoconf 2.52, AC_C_BIGENDIAN seems to ignore its
dnl parameters, so I test the internal variable that it sets.  Note
dnl that AC_BIG_ENDIAN defines its own macro, WORDS_BIGENDIAN, so
dnl really it would make most sense to replace the instances of
dnl BYTEORDER in the GrADS source; but that might cause confusion
dnl among longtime users.
AC_C_BIGENDIAN
if test $ac_cv_c_bigendian = "yes" ; then
   AC_DEFINE(BYTEORDER,1,[BIG_ENDIAN machine])
else
   AC_DEFINE(BYTEORDER,0,[little_endian machine])
fi

dnl The following tests all check for functions and typedefs that are
dnl required for GrADS, but 1) I don't think we support any platforms
dnl where they fail, and 2) if they do, there is no backup plan
dnl anyway. So I figure we might as well speed the script up a bit by
dnl commenting them out, unless/until there is some actual handling
dnl for failure.

dnl AC_TYPE_SIZE_T AC_STRUCT_TM

dnl Checks for library functions.
dnl AC_TYPE_SIGNAL
dnl AC_FUNC_STRFTIME
dnl AC_FUNC_VPRINTF
dnl AC_CHECK_FUNCS(strdup strstr strtod strtol)

dnl In this case we do have an alternative - valprs()
AC_CHECK_FUNCS(strtod)

dnl Check for and set up large file support via fseeko()
AC_TYPE_OFF_T
AC_SYS_LARGEFILE
AC_FUNC_FSEEKO

# ----------------------------------------------------
# Check for optional feature support
# ----------------------------------------------------

echo
echo Checking for optional feature support
echo ------------------------------------

AC_MSG_CHECKING([whether to use dynamic linking])
if test "$ga_dyn_supplibs" = "yes" ; then
   AC_MSG_RESULT([yes (Warning: binaries may not be suitable for distribution)])
else
   AC_MSG_RESULT([no])
fi

echo

use_readline=no
if test "$with_readline" != "no" ; then
  echo "Check GrADS command line editing support..."
  GA_CHECK_READLINE([use_readline=yes])
fi
if test $use_readline = "yes" ; then
  echo "+ Command line editing enabled"
  GA_SET_LIB_VAR(readline_libs, readline)
  AC_SUBST(readline_libs)
  AC_DEFINE(READLINE, 1, [Enable command line editing])
  AC_DEFINE(MM_READLINE,,[Enhanced readline with history])
else
  echo "- Command line editing disabled"
  AC_DEFINE(READLINE, 0, [Enable command line editing])
fi
echo


use_gui=no
if test "$with_gui" != "no" ; then
   echo "Check GrADS GUI support..."
   GA_CHECK_GUI([use_gui=yes])
fi
if test $use_gui = "yes" ; then
  AC_DEFINE(USEGUI, 1, [Enable GUI widgets])
  echo "+ GUI enabled"
  GA_SET_LIB_VAR(gui_libs, [sx freq])
  gui_libs="$gui_libs -lXaw -lXmu -lXt $guilibadd"
  AC_SUBST(gui_libs)
else
  AC_DEFINE(USEGUI, 0, [Enable GUI widgets])
  echo  "- GUI disabled"
fi
echo


use_printim=no
if test "$with_printim" != "no" ; then
  echo "Check GrADS printim support..."
  GA_CHECK_GD([use_printim=yes], [])
fi

if test $use_printim = "yes" ; then
  AC_DEFINE(GXPNG, 1, [Enable printim using GD library \
                       (http://www.boutell.com/gd) for PNG/GIF images])
  GA_SET_LIB_VAR(printim_libs, [gd png z])
  AC_SUBST(printim_libs)
  extra_utils="$extra_utils gxtran"
  echo "+ printim enabled"
else
  AC_DEFINE(GXPNG, 0, [Enable printim using GD library \
                       (http://www.boutell.com/gd) for PNG/GIF images])
  echo "- printim disabled (Warning: gxtran will not be built)"
fi
echo


use_wi=no
AC_MSG_CHECKING([if wi command has been enabled])
# ImageMagick is disabled by default
if test "$with_wi" = "yes" ; then
   AC_MSG_RESULT(yes)
   echo "Checking for wi command's support libraries & headers..."
   GA_CHECK_IMG([use_wi=yes], [])
else
   AC_MSG_RESULT(no)
fi

if test $use_wi = "yes" ; then
   AC_DEFINE(USEIMG, 1, [Enable wi using ImageMagick library])
   echo "+ wi enabled (Warning: this feature is deprecated and may not"\
        " build properly)"
   LIBS="-lMagick -ljpeg $LIBS -lXext"
   GA_SET_LIB_VAR(wi_libs, [Magick jpeg])
   AC_SUBST(wi_libs)
   wi_libadd="-lXext"
   AC_SUBST(wi_libadd)
else
   AC_DEFINE(USEIMG, 0, [Enable wi using ImageMagick library])
   echo "- wi disabled"
fi
echo

if test "$with_lats" != "no" ; then
  AC_DEFINE(USELATS, 1, [Enable LATS ])
  echo "+ LATS enabled"
  use_lats=yes
else
  AC_DEFINE(USELATS, 0, [Enable LATS ])
  echo "- LATS disabled"
  use_lats=no
fi

echo
echo Checking which GrADS binaries can be built
echo ------------------------------------

use_nc=no
if test "$with_nc" != "no" ; then
     GA_CHECK_NC([use_nc=yes])
fi
if test $use_nc = "yes" ; then
  GA_SET_LIB_VAR(nc_libs, [netcdf udunits])
  AC_SUBST(nc_libs)
  extra_bins="$extra_bins gradsnc"
  echo "+ gradsnc (plain netCDF) build enabled"
else
  echo "- gradsnc (plain netCDF) build disabled"
fi
echo


use_hdf=no
if test "$with_hdf" != "no" ; then
  GA_CHECK_HDF([use_hdf=yes])
fi
if test $use_hdf = "yes" ; then
    GA_SET_LIB_VAR(hdf_libs, [mfhdf df jpeg udunits z])
    AC_SUBST(hdf_libs)
    extra_bins="$extra_bins gradshdf"
    echo "+ gradshdf (HDF-SDS/netCDF) build enabled"
else
  echo "- gradshdf (HDF-SDS/netCDF) build disabled"
fi
echo


use_dods=no
if test "$with_dods" != "no" ; then
  GA_CHECK_DODS([use_dods=yes])
fi

if test $use_dods = "yes" ; then

    extra_bins="$extra_bins gradsdods"
    GA_SET_LIB_VAR(dods_libs, [udunits www rx z])


    GA_CHECK_LIB(gadods, main, [use_gadods=yes], [use_gadods=no])
    if test $use_gadods = "yes" ; then
       dods_rep_libs="-lgadods -lnc-dods -ldap++"
       gadods_def="-DUSEGADODS=1"
       echo "+ gradsdods (OPeNDAP/netCDF) build enabled - gridded and station interfaces"
    else
       dods_rep_libs="-lnc-dods -ldap++"
       gadods_def="-DUSEGADODS=0"
       echo "+ gradsdods (OPeNDAP/netCDF) build enabled - gridded interface only"
    fi

    dods_libs="$dods_rep_libs $dods_rep_libs $dods_libs"
    AC_SUBST(dods_libs)
    AC_SUBST(gadods_def)
else
    echo "- gradsdods (OPeNDAP/netCDF) build disabled"
fi

echo

#  ----------------------------------------------------
# Send test results to makefile and config.h
# ----------------------------------------------------

# Some non-configuration-dependent GrADS macros
AC_DEFINE(GRADS_VERSION, "AC_PACKAGE_VERSION", [GrADS version])
AC_DEFINE(GRADS_DESC,, [Obsolete feature description string])
AC_DEFINE(PRINT_EPS,,[Integrate gxeps command into print])
dnl AC_DEFINE(PRINTIM_JPEG)
dnl AC_DEFINE(MM_NEW_PROMPT)

# These are used to add the necessary source files to Makefile targets
AM_CONDITIONAL(READLINE, [ test "$use_readline"  = "yes" ] )
AM_CONDITIONAL(USEGUI,   [ test "$use_gui"  = "yes" ] )
AM_CONDITIONAL(GXPNG,    [ test "$use_printim"  = "yes" ] )
AM_CONDITIONAL(USEIMG,   [ test "$use_wi"  = "yes" ] )
AM_CONDITIONAL(USELATS,  [ test "$use_lats" = "yes" ] )
AM_CONDITIONAL(USEGADODS,[ test "$use_gadods" = "yes" ] )
AM_CONDITIONAL(XLIBEMU,  [ test "$use_xlibemu" = "yes" ] )

# These control which binaries are built
AM_CONDITIONAL(USEDODS,  [ test "$use_dods" = "yes" ] )
AM_CONDITIONAL(USENC,    [ test "$use_nc" = "yes" ] )
AM_CONDITIONAL(USEHDF,   [ test "$use_hdf" = "yes" ] )
AC_SUBST(extra_bins)
AC_SUBST(extra_utils)

# Host specific linker flags
AC_SUBST(host_ldadd)

# Hack to deal with Darwin C++ quirk: template instantiations can't
# be done inside archives, and must be separate objects.
# So inst.o is extracted from libdap++.a and linked separately.
AM_CONDITIONAL(DODS_DARWIN,   [ test "$is_darwin" = "yes" \
			      	&& test "$use_dods" = "yes"])


dnl ----------------------------------------------------
dnl Print summary and write output files
dnl ----------------------------------------------------

build_date=`date +%D`
build_host=`uname -sr`
build_info="Built `date` for ${host}"

   echo \
"  +=========================================================================+"
   echo "   GrADS "AC_PACKAGE_VERSION ":" $build_info
   echo \
"  +=========================================================================+"
   echo
   echo "  +----------------------------------+"
   echo "  |                                  |"
   echo "  | Configuration Summary            |"
   echo "  |                                  |"
if test "$use_readline" = "yes" ; then
   echo "  |  + readline enabled              |"
else
   echo "  |  - readline disabled             |"
fi
if test "$use_printim" = "yes" ; then
   echo "  |  + printim enabled               |"
else
   echo "  |  - printim disabled              |"
fi
if test "$use_gui" = "yes" ; then
   echo "  |  + GUI enabled                   |"
else
   echo "  |  - GUI disabled                  |"
fi
if test "$use_lats" = "yes" ; then
   echo "  |  + LATS enabled                  |"
else
   echo "  |  - LATS disabled                 |"
fi
if test "$use_wi" = "yes" ; then
   echo "  |  + wi enabled (deprecated)       |"
else
   echo "  |  - wi disabled (default)         |"
fi
   echo "  |                                  |"
   echo "  | Build Summary                    |"
   echo "  |                                  |"
   echo "  |  + gradsc    (classic) enabled   |"
if test "$use_nc" = "yes" ; then
   echo "  |  + gradsnc   (netCDF)  enabled   |"
else
   echo "  |  - gradsnc   (netCDF)  disabled  |"
fi
if test "$use_hdf" = "yes" ; then
   echo "  |  + gradshdf  (HDF-SDS) enabled   |"
else
   echo "  |  - gradshdf  (HDF-SDS) disabled  |"
fi
if test "$use_dods" = "yes" ; then
   echo "  |  + gradsdods (OPeNDAP) enabled   |"
  if test "$use_gadods" = "yes" ; then
   echo "  |    (both grid & stn interfaces)  |"
  else
   echo "  |    (grid interface only)         |"
  fi
else
   echo "  |  - gradsdods (OPeNDAP) disabled  |"
fi
   echo "  |                                  |"
if test "$ga_dyn_supplibs" = "yes" ; then
   echo "  |  + Dynamic linking enabled       |"
else
   echo "  |  - Dynamic linking disabled      |"
fi
   echo "  |                                  |"
   echo "  +----------------------------------+"

echo "configure: creating src/VERSION"
echo AC_PACKAGE_VERSION > src/VERSION

echo "configure: creating src/buildinfo.h"
mkdir -p src
echo "static char *buildinfo = \"${build_info}\";" > src/buildinfo.h

AC_CONFIG_FILES([Makefile src/Makefile])
AC_OUTPUT

echo
echo "Run 'make && make install' to build GrADS."
echo "Executables will be installed" \
     "to bin/ in current dir, unless prefix was specified."
echo