1# ex:ts=8 sw=4:
2# $OpenBSD: Signature.pm,v 1.29 2023/06/13 09:07:17 espie Exp $
3#
4# Copyright (c) 2010 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17
18# this is the code that handles "update signatures", which has nothing
19# to do with cryptography
20
21use v5.36;
22
23package OpenBSD::PackingElement;
24sub signature($, $) {}
25
26package OpenBSD::PackingElement::VersionElement;
27sub signature($self, $hash)
28{
29	$hash->{$self->signature_key} = $self;
30}
31
32sub always($)
33{
34	return 1;
35}
36
37package OpenBSD::PackingElement::Version;
38sub signature($self, $hash)
39{
40	$hash->{VERSION}{name} += $self->name;
41}
42
43package OpenBSD::PackingElement::Dependency;
44sub signature_key($self)
45{
46	return $self->{pkgpath};
47}
48
49sub sigspec($self)
50{
51	return OpenBSD::PackageName->from_string($self->{def});
52}
53
54sub long_string($self)
55{
56	return '@'.$self->sigspec->to_string;
57}
58
59sub compare($a, $b)
60{
61	return $a->sigspec->compare($b->sigspec);
62}
63
64sub always($)
65{
66	return 0;
67}
68
69package OpenBSD::PackingElement::Wantlib;
70sub signature_key($self)
71{
72	my $spec = $self->spec;
73	if ($spec->is_valid) {
74		return $spec->key;
75	} else {
76		return "???";
77	}
78}
79
80sub compare($a, $b)
81{
82	return $a->spec->compare($b->spec);
83}
84
85sub long_string($self)
86{
87	return $self->spec->to_string;
88}
89
90sub always($)
91{
92	return 1;
93}
94
95package OpenBSD::PackingElement::Version;
96sub signature_key($)
97{
98	return 'VERSION';
99}
100
101sub long_string($self)
102{
103	return $self->{name};
104}
105
106sub compare($a, $b)
107{
108	return $a->{name} <=> $b->{name};
109}
110
111package OpenBSD::Signature;
112sub from_plist($class, $plist)
113{
114	my $k = {};
115	$k->{VERSION} = OpenBSD::PackingElement::Version->new(0);
116	$plist->visit('signature', $k);
117
118	if ($plist->has('always-update')) {
119		return $class->full->new($plist->pkgname, $k, $plist);
120	} else {
121		return $class->new($plist->pkgname, $k);
122	}
123}
124
125sub full($)
126{
127	return "OpenBSD::Signature::Full";
128}
129
130sub new($class, $pkgname, $extra)
131{
132	bless { name => $pkgname, extra => $extra }, $class;
133}
134
135sub string($self)
136{
137	return join(',', $self->{name}, sort map {$_->long_string} values %{$self->{extra}});
138}
139
140sub compare($a, $b, $state)
141{
142	return $b->revert_compare($a, $state);
143}
144
145sub revert_compare($b, $a, $state)
146{
147	if ($a->{name} eq $b->{name}) {
148		# first check if system version changed
149		# then we don't have to go any further
150		my $d = $b->{extra}{VERSION}->compare($a->{extra}{VERSION});
151		if ($d < 0) {
152			return 1;
153		} elsif ($d > 0) {
154			return -1;
155		}
156
157		my $shortened = $state->defines("SHORTENED");
158		my $awins = 0;
159		my $bwins = 0;
160		my $done = {};
161		my $errors = 0;
162		while (my ($k, $v) = each %{$a->{extra}}) {
163			if (!defined $b->{extra}{$k}) {
164				$state->errsay(
165				    "Couldn't find #1 in second signature", $k);
166				$errors++;
167				next;
168			}
169			$done->{$k} = 1;
170			next if $shortened && !$v->always;
171			my $r = $v->compare($b->{extra}{$k});
172			if ($r > 0) {
173				$awins++;
174			} elsif ($r < 0) {
175				$bwins++;
176			}
177		}
178		for my $k (keys %{$b->{extra}}) {
179			if (!$done->{$k}) {
180				$state->errsay(
181				    "Couldn't find #1 in first signature", $k);
182				$errors++;
183			}
184		}
185		if ($errors) {
186			$a->print_error($b, $state);
187			return undef;
188		}
189		if ($awins == 0) {
190			return -$bwins;
191		} elsif ($bwins == 0) {
192			return $awins;
193		} else {
194			return undef;
195		}
196	} else {
197		return OpenBSD::PackageName->from_string($a->{name})->compare(OpenBSD::PackageName->from_string($b->{name}));
198	}
199}
200
201sub print_error($a, $b, $state)
202{
203	$state->errsay("Error: #1 exists in two non-comparable versions",
204	    $a->{name});
205	$state->errsay("Someone forgot to bump a REVISION");
206	$state->errsay("#1 vs. #2", $a->string, $b->string);
207}
208
209package OpenBSD::Signature::Full;
210our @ISA=qw(OpenBSD::Signature);
211
212sub new($class, $pkgname, $extra, $plist)
213{
214	my $o = $class->SUPER::new($pkgname, $extra);
215	my $a = $plist->get('always-update');
216	# TODO remove after 2025
217	if (!defined $a->{hash}) {
218		$a->hash_plist($plist);
219	}
220	$o->{hash} = $a->{hash};
221	return $o;
222}
223
224sub string($self)
225{
226	return join(',', $self->SUPER::string, $self->{hash});
227}
228
229sub revert_compare($b, $a, $state)
230{
231	my $r = $b->SUPER::revert_compare($a, $state);
232	if (defined $r && $r == 0) {
233		if ($a->string ne $b->string) {
234			return undef;
235		}
236	}
237	return $r;
238}
239
240sub compare($a, $b, $state)
241{
242	my $r = $a->SUPER::compare($b, $state);
243	if (defined $r && $r == 0) {
244		if ($a->string ne $b->string) {
245			return undef;
246		}
247	}
248	return $r;
249}
250
2511;
252