1include (../liteidex.pri)
2include (api/liteapi/liteapi.pri)
3
4isEmpty(PRECOMPILED_HEADER):PRECOMPILED_HEADER = $$IDE_SOURCE_TREE/src/pch/liteide_gui_pch.h
5
6DESTDIR = $$IDE_PLUGIN_PATH
7LIBS += -L$$IDE_PLUGIN_PATH
8LIBS += -L$$IDE_LIBRARY_PATH
9
10INCLUDEPATH += $$IDE_SOURCE_TREE/src/api
11INCLUDEPATH += $$IDE_SOURCE_TREE/src/utils
12INCLUDEPATH += $$IDE_SOURCE_TREE/src/3rdparty
13
14isEmpty(TARGET) {
15    error("liteideplugin.pri: You must provide a TARGET")
16}
17
18macx {
19    QMAKE_LFLAGS_SONAME = -Wl,-install_name,@executable_path/../PlugIns/
20} else:linux-* {
21    #do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
22    QMAKE_RPATHDIR += \$\$ORIGIN
23    QMAKE_RPATHDIR += \$\$ORIGIN/..
24    QMAKE_RPATHDIR += \$\$ORIGIN/../..
25    IDE_PLUGIN_RPATH = $$join(QMAKE_RPATHDIR, ":")
26    QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${IDE_PLUGIN_RPATH}\'
27    QMAKE_RPATHDIR =
28}
29
30
31contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
32
33CONFIG += plugin plugin_with_soname
34
35!macx {
36    target.path = $$PLUGINPREFIX
37    INSTALLS += target
38}
39
40TARGET = $$qtLibraryTarget($$TARGET)
41
42