1TEMPLATE = subdirs
2
3TOOLS_SUBDIRS = src_tools_bootstrap src_tools_moc src_tools_rcc
4!contains(QT_CONFIG, no-gui): TOOLS_SUBDIRS += src_tools_uic
5!cross_compile {
6    contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_tools_uic3
7    win32:!wince*: SRC_SUBDIRS += src_tools_idc
8}
9
10# Set subdir and respective target name
11src_tools_bootstrap.subdir = $$QT_SOURCE_TREE/src/tools/bootstrap
12src_tools_bootstrap.target = sub-tools-bootstrap
13src_tools_moc.subdir = $$QT_SOURCE_TREE/src/tools/moc
14src_tools_moc.target = sub-moc
15src_tools_rcc.subdir = $$QT_SOURCE_TREE/src/tools/rcc
16src_tools_rcc.target = sub-rcc
17src_tools_uic.subdir = $$QT_SOURCE_TREE/src/tools/uic
18src_tools_uic.target = sub-uic
19src_tools_uic3.subdir = $$QT_SOURCE_TREE/src/tools/uic3
20src_tools_uic3.target = sub-uic3
21src_tools_idc.subdir = $$QT_SOURCE_TREE/src/tools/idc
22src_tools_idc.target = sub-idc
23
24!wince*:!ordered {
25    # Set dependencies for each subdir
26    src_tools_moc.depends = src_tools_bootstrap
27    src_tools_rcc.depends = src_tools_bootstrap
28    src_tools_uic.depends = src_tools_bootstrap
29}
30
31# Special handling, depending on type of project, if it used debug/release or only has one configuration
32EXTRA_DEBUG_TARGETS =
33EXTRA_RELEASE_TARGETS =
34!symbian {
35    for(subname, TOOLS_SUBDIRS) {
36        subdir = $$subname
37        !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
38        subpro = $$subdir/$${basename(subdir)}.pro
39        !exists($$subpro):next()
40        subtarget = $$replace(subdir, [^A-Za-z0-9], _)
41        reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
42        subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
43        subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
44        subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
45        SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
46        !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
47            #debug
48            debug-$${subtarget}.depends = $${subdir}$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS
49            debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug)
50            EXTRA_DEBUG_TARGETS += debug-$${subtarget}
51            QMAKE_EXTRA_TARGETS += debug-$${subtarget}
52            #release
53            release-$${subtarget}.depends = $${subdir}$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS
54            release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release)
55            EXTRA_RELEASE_TARGETS += release-$${subtarget}
56            QMAKE_EXTRA_TARGETS += release-$${subtarget}
57        } else { #do not have a real debug target/release
58            #debug
59            debug-$${subtarget}.depends = $${subdir}$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS
60            debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first)
61            EXTRA_DEBUG_TARGETS += debug-$${subtarget}
62            QMAKE_EXTRA_TARGETS += debug-$${subtarget}
63            #release
64            release-$${subtarget}.depends = $${subdir}$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS
65            release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first)
66            EXTRA_RELEASE_TARGETS += release-$${subtarget}
67            QMAKE_EXTRA_TARGETS += release-$${subtarget}
68        }
69    }
70}
71
72SUBDIRS = $$TOOLS_SUBDIRS $$SUBDIRS
73isEqual(TARGET,tools): SUBDIRS += $$SRC_SUBDIRS
74