1--source include/have_wsrep.inc
2--source include/have_symlink.inc
3--source include/not_windows.inc
4--source include/have_innodb.inc
5
6--echo #
7--echo # MDEV-5226 mysql_tzinfo_to_sql errors with tzdata 2013f and above
8--echo #
9
10--exec mkdir $MYSQLTEST_VARDIR/zoneinfo
11--exec ln -s $MYSQLTEST_VARDIR/zoneinfo $MYSQLTEST_VARDIR/zoneinfo/posix
12--copy_file std_data/zoneinfo/GMT $MYSQLTEST_VARDIR/zoneinfo/GMT
13--copy_file std_data/words.dat $MYSQLTEST_VARDIR/zoneinfo/garbage
14--copy_file std_data/words.dat $MYSQLTEST_VARDIR/zoneinfo/ignored.tab
15
16--echo # Verbose run
17--replace_result $MYSQLTEST_VARDIR MYSQLTEST_VARDIR
18--exec $MYSQL_TZINFO_TO_SQL --verbose $MYSQLTEST_VARDIR/zoneinfo 2>&1
19
20--echo # Silent run
21--replace_result $MYSQLTEST_VARDIR MYSQLTEST_VARDIR
22--exec $MYSQL_TZINFO_TO_SQL $MYSQLTEST_VARDIR/zoneinfo 2>&1
23
24--echo #
25--echo # Testing with explicit timezonefile
26--echo #
27
28--replace_result $MYSQLTEST_VARDIR MYSQLTEST_VARDIR
29--exec $MYSQL_TZINFO_TO_SQL $MYSQLTEST_VARDIR/zoneinfo/GMT XXX 2>&1
30
31--echo #
32--echo # Testing --leap
33--echo #
34
35--exec $MYSQL_TZINFO_TO_SQL --leap $MYSQLTEST_VARDIR/zoneinfo/GMT 2>&1
36
37#
38# Cleanup
39#
40
41--exec rm -rf $MYSQLTEST_VARDIR/zoneinfo
42