1# Qt network kernel module
2
3PRECOMPILED_HEADER = ../corelib/global/qt_pch.h
4INCLUDEPATH += $$PWD
5
6HEADERS += kernel/qtnetworkglobal.h \
7           kernel/qtnetworkglobal_p.h \
8           kernel/qauthenticator.h \
9           kernel/qauthenticator_p.h \
10           kernel/qhostaddress.h \
11           kernel/qhostaddress_p.h \
12           kernel/qhostinfo.h \
13           kernel/qhostinfo_p.h \
14           kernel/qnetworkdatagram.h \
15           kernel/qnetworkdatagram_p.h \
16           kernel/qnetworkinterface.h \
17           kernel/qnetworkinterface_p.h \
18           kernel/qnetworkinterface_unix_p.h \
19           kernel/qnetworkproxy.h \
20           kernel/qnetconmonitor_p.h
21
22SOURCES += kernel/qauthenticator.cpp \
23           kernel/qhostaddress.cpp \
24           kernel/qhostinfo.cpp \
25           kernel/qnetworkdatagram.cpp \
26           kernel/qnetworkinterface.cpp \
27           kernel/qnetworkproxy.cpp
28
29qtConfig(ftp) {
30    HEADERS += kernel/qurlinfo_p.h
31    SOURCES += kernel/qurlinfo.cpp
32}
33
34qtConfig(dnslookup) {
35    HEADERS += kernel/qdnslookup.h \
36               kernel/qdnslookup_p.h
37
38    SOURCES += kernel/qdnslookup.cpp
39}
40
41unix {
42    !integrity:qtConfig(dnslookup): SOURCES += kernel/qdnslookup_unix.cpp
43
44    SOURCES += kernel/qhostinfo_unix.cpp
45
46    qtConfig(dlopen): QMAKE_USE_PRIVATE += libdl
47
48    qtConfig(linux-netlink): SOURCES += kernel/qnetworkinterface_linux.cpp
49    else: SOURCES += kernel/qnetworkinterface_unix.cpp
50}
51
52android:qtConfig(dnslookup) {
53    SOURCES -= kernel/qdnslookup_unix.cpp
54    SOURCES += kernel/qdnslookup_android.cpp
55}
56
57win32: {
58    SOURCES += kernel/qhostinfo_win.cpp
59
60    !winrt {
61        SOURCES += kernel/qnetworkinterface_win.cpp
62        qtConfig(dnslookup): SOURCES += kernel/qdnslookup_win.cpp
63        LIBS_PRIVATE += -ldnsapi -liphlpapi
64    } else {
65        SOURCES += kernel/qnetworkinterface_winrt.cpp
66        qtConfig(dnslookup): SOURCES += kernel/qdnslookup_winrt.cpp
67    }
68}
69
70mac {
71    LIBS_PRIVATE += -framework CoreFoundation
72    !uikit: LIBS_PRIVATE += -framework CoreServices -framework SystemConfiguration
73}
74
75macos | ios {
76    OBJECTIVE_SOURCES += \
77        kernel/qnetconmonitor_darwin.mm
78
79    LIBS_PRIVATE += -framework SystemConfiguration
80} else:qtConfig(netlistmgr) {
81    SOURCES += kernel/qnetconmonitor_win.cpp
82} else {
83    SOURCES += kernel/qnetconmonitor_stub.cpp
84}
85
86qtConfig(gssapi): QMAKE_USE_PRIVATE += gssapi
87
88uikit:HEADERS += kernel/qnetworkinterface_uikit_p.h
89osx:SOURCES += kernel/qnetworkproxy_mac.cpp
90else:win32:!winrt: SOURCES += kernel/qnetworkproxy_win.cpp
91else: qtConfig(libproxy) {
92    SOURCES += kernel/qnetworkproxy_libproxy.cpp
93    QMAKE_USE_PRIVATE += libproxy libdl
94}
95else:android: SOURCES += kernel/qnetworkproxy_android.cpp
96else: SOURCES += kernel/qnetworkproxy_generic.cpp
97
98android: ANDROID_BUNDLED_JAR_DEPENDENCIES = \
99        jar/QtAndroidNetwork.jar
100