1. THIS IS THE DATAPLOT PROGRAM FILE     BOXCHEM.DP
2. CHEMICAL YIELD (BOX, HUNTER, & HUNTER), P. 325
3. COMPLETE ANALYSIS OF 2**4 DESIGN
4. INPUT DATA FILE--BOXCHEM.DAT
5. OUTPUT FILES--DPPL1F.DAT (A POSTSCRIPT FILE CONTAINING ALL PLOT OUTPUT)
6.               OUT1. (YATES ANALYSIS OUTPUT)
7.               OUT2. (PREDICTED VALUES AND RESIDUALS FROM FINAL MODEL)
8.               OUT3. (SORTED Y AND CARRY-ALONG X'S)
9.
10. -----START POINT----------
11.
12DIMENSION 20 VARIABLES
13DEVICE 2 POSTSCRIPT
14.
15. STEP 1--READ IN THE DATA
16.
17SKIP 25
18READ BOXCHEM.DAT Y X1 X2 X3 X4
19.
20. STEP 2--GENERATE DEX SCATTER PLOT & DEX MEAN PLOT
21.
22MULTIPLOT 2 1
23LABEL SIZE 4
24X3LABEL AUTOMATIC
25CHAR X; LINES BLANK
26DEX SCATTER PLOT Y X1 X2 X3 X4
27CHAR BLANK; LINES SOLID
28DEX MEAN PLOT Y X1 X2 X3 X4
29LINES SOLID ALL; LINES BLANK BLANK
30.
31. STEP 3--GENERATE MATRIX OF MEAN PLOTS (USE DEXSTAT2.DP MACRO)
32.
33ER
34MULTIPLOT OFF
35X3LABEL
36LET NUMFAC = 4
37LET DP = 2
38LET STRING STAT = MEAN
39YLIMITS 50 90
40LET STRING S0 = CONVERSION YIELD
41LET STRING S1 = CATALYST CHARGE (X1)
42LET STRING S2 = TEMPERATURE (X2)
43LET STRING S3 = PRESSURE (X3)
44LET STRING S4 = CONCENTRATION (X4)
45CALL DEXSTAT2.DP
46YLIMITS
47.
48. STEP 4--GENERATE BLOCK PLOTS
49.
50MULTIPLOT 2 2
51CHAR 1 2; LINES BLANK BLANK
52CHAR SIZE 3 ALL; LABEL SIZE 3; TIC LABEL SIZE 3
53X3LABEL AUTOMATIC
54BLOCK PLOT Y X2 X3 X4 X1
55BLOCK PLOT Y X1 X3 X4 X2
56BLOCK PLOT Y X1 X2 X4 X3
57BLOCK PLOT Y X1 X2 X3 X4
58MULTIPLOT OFF
59CHAR SIZE 2 ALL; LABEL SIZE 2; TIC LABEL SIZE 2
60.
61. STEP 5--DO YATES ANALYSIS (DATA ASSUMED TO BE IN YATES ORDER)
62.         NOTE--COEFFICIENTS STORED OUT TO FILE  DPST1F.DAT
63.
64ER
65YATES Y
66CAPTURE OUT1.
67YATES Y
68END OF CAPTURE
69.
70. STEP 6--GENERATE NORMAL AND HALFNORMAL PROBABILITY PLOTS ON THE EFFECTS
71.         NOTE--MUST READ COEFFICIENTS IN FROM FILE  DPST1F.DAT
72.
73SKIP 0
74READ DPST1F.DAT TAG COEF T RESSD1 RESSD2
75WRITE TAG COEF T RESSD1 RESSD2
76CHAR X; LINES BLANK
77LABEL SIZE 4
78X3LABEL AUTOMATIC
79MULTIPLOT 2 2
80NORMAL PROBABILITY PLOT COEF
81LET ABSCOEF = ABS(COEF)
82HALFNORMAL PROBABILITY PLOT ABSCOEF
83.
84. STEP 7--GENERATE PREDICTED VALUES AND RESIDUALS FOR PARTIAL MODEL
85.
86LET MU = MEAN Y
87LET B2 = COEF(1)
88LET B1 = COEF(2)
89LET B4 = COEF(3)
90LET B24 = COEF(4)
91LET RESSD = RESSD2(4)
92LET PRED = MU+0.5*(B2*X2+B1*X1+B4*X4+B24*X2*X4)
93LET RES = Y-PRED
94ER
95SET WRITE DECIMALS 2
96WRITE X1 X2 X3 X4 Y PRED RES
97WRITE OUT2. X1 X2 X3 X4 Y PRED RES
98.
99. STEP 8--GENERATE NORMAL PROBABILITY PLOT OF RESIDUALS
100.
101X1LABEL PREDICTED Y = ^MU+0.5*( ^B2*X2+^B1*X1+^B24*X2*X4+^B4*X4 )
102X2LABEL RESIDUAL STANDARD DEVIATION = ^RESSD
103LABEL SIZE 3
104PLOT
105NORMAL PROBABILITY PLOT RES
106X1LABEL
107X2LABEL
108LABEL SIZE 2
109MULTIPLOT OFF
110.
111. STEP 9--GENERATE CONTOUR PLOT FOR THE 2 MOST IMPORTANT FACTORS
112.          (USE MACRO DEXCONT.DP)
113.
114LET YCONT = DATA 50 60 70 80 90 100
115LET U1 = X2
116LET U2 = X1
117CHAR BLANK ALL; LINES SOLID ALL
118X1LABEL TEMPERATURE (X2)
119Y1LABEL CATALYST CHARGE (X1)
120X3LABEL
121CALL DEXCONT.DP
122X1LABEL
123Y1LABEL
124.
125. STEP 10--SORT Y AND CARRY ALONG X... FACTORS
126.
127ER
128LET YSORT = SORTC Y X1 X2 X3 X4
129SET WRITE DECIMALS 0
130WRITE X1 X2 X3 X4 YSORT
131WRITE OUT3. X1 X2 X3 X4 YSORT
132.
133