1#version 450
2#define LOCAL_SZ_X 256
3layout(binding = 0) readonly buffer Input0{
4    float image_data[];
5};
6layout(binding = 1) readonly buffer Input1 {
7    float bias_data[];
8};
9layout(binding = 2) readonly buffer Input3{
10    float weight_data[];
11};
12layout(binding = 3) writeonly buffer Output{
13    float convolved_image_data[];
14};
15
16layout(push_constant) uniform pushBlock {
17    int in_h;
18    int in_w;
19    int out_h;
20    int out_w;
21    int stride_h;
22    int stride_w;
23    int pad_h;
24    int pad_w;
25    int filter_h;
26    int filter_w;
27    int dilation_h;
28    int dilation_w;
29    int channels;
30    int batch;
31    int has_bias;
32    int M;
33    int K;
34    int N;
35    int basic_shader_batch_idx;
36    int basic_shader_partition_idx;
37    int basic_shader_partition_size;
38} p;
39
40layout(local_size_x = LOCAL_SZ_X, local_size_y = 1, local_size_z = 1) in;
41void main()
42{
43    int gx = int(gl_GlobalInvocationID.x);
44    int gy = int(gl_GlobalInvocationID.y) + p.basic_shader_partition_idx * p.basic_shader_partition_size;
45    int gz = p.basic_shader_batch_idx;
46    if(gx < p.M && gy < p.N)
47    {
48        float sum = 0.0f;
49        int output_y = gx / p.out_w;
50        int output_x = gx % p.out_w;
51        int org_y = output_y * p.stride_h - p.pad_h;
52        int org_x = output_x * p.stride_w - p.pad_w;
53        int weight_off = gy * p.K;
54        int input_off = gz * p.in_h * p.in_w * p.channels + (org_y * p.in_w + org_x);
55        for(int c = 0; c < p.channels; c++)
56        {
57            for(int y = 0; y < p.filter_h; y++)
58            {
59                for(int x = 0; x < p.filter_w; x++)
60                {
61                    if((org_y + y * p.dilation_h >= 0) && (org_y + y * p.dilation_h < p.in_h) && (org_x + x * p.dilation_w >= 0) && (org_x + x * p.dilation_w < p.in_w))
62                    {
63                        sum += image_data[input_off + x * p.dilation_w] * weight_data[weight_off + x];
64                    }
65                }
66                input_off += p.in_w * p.dilation_h;
67                weight_off += p.filter_w;
68            }
69            input_off += p.in_h * p.in_w - p.in_w * p.filter_h * p.dilation_h;
70        }
71        int offset = gz * p.M * p.N + gx  + gy * p.M;
72        if (p.has_bias == 1)
73            sum += bias_data[gy];
74        convolved_image_data[offset] = sum;
75    }
76}
77