1(* ::Package:: *)
2
3(* ::Title::Bold::Closed:: *)
4(*\[Integral]Tanh[a+b x]^n \[DifferentialD]x*)
5
6
7(* ::Subsubsection:: *)
8(*Reference: G&R 2.243.17, CRC 556, A&S 4.5.79*)
9
10
11(* ::Subsubsection:: *)
12(*Derivation: Reciprocal rule*)
13
14
15(* ::Subsubsection:: *)
16(*Basis: Tanh[z]=Sinh[z]/Cosh[z]*)
17
18
19(* ::Subsubsection:: *)
20(*Rule:*)
21
22
23(* ::Subsubtitle::Bold:: *)
24(*\[Integral]Tanh[a+b x]\[DifferentialD]x  \[LongRightArrow]  (Log[Cosh[a+b x]]/b)*)
25
26
27(* ::Subsubsection:: *)
28(*Program code:*)
29
30
31(* ::Code:: *)
32Int[Tanh[a_.+b_.*x_],x_Symbol] :=
33  Log[Cosh[a+b*x]]/b /;
34FreeQ[{a,b},x]
35
36
37(* ::Subsubsection:: *)
38(*Reference: G&R 2.423.33, CRC 557, A&S 4.5.82*)
39
40
41(* ::Code:: *)
42Int[Coth[a_.+b_.*x_],x_Symbol] :=
43  Log[Sinh[a+b*x]]/b /;
44FreeQ[{a,b},x]
45
46
47(* ::Subsubsection:: *)
48(**)
49
50
51(* ::Subsubsection:: *)
52(*Reference: G&R 2.423.22, CRC 569*)
53
54
55(* ::Subsubsection:: *)
56(*Derivation: Algebraic expansion*)
57
58
59(* ::Subsubsection:: *)
60(*Basis: Tanh[z]^2=1-Sech[z]^2*)
61
62
63(* ::Subsubsection:: *)
64(*Rule:*)
65
66
67(* ::Subsubtitle::Bold:: *)
68(*\[Integral]Tanh[a+b x]^2 \[DifferentialD]x  \[LongRightArrow]  x-Tanh[a+b x]/b*)
69
70
71(* ::Subsubsection:: *)
72(*Program code:*)
73
74
75(* ::Code:: *)
76Int[Tanh[a_.+b_.*x_]^2,x_Symbol] :=
77  x - Tanh[a+b*x]/b /;
78FreeQ[{a,b},x]
79
80
81(* ::Subsubsection:: *)
82(*Reference: G&R 2.423.38, CRC 573*)
83
84
85(* ::Code:: *)
86Int[Coth[a_.+b_.*x_]^2,x_Symbol] :=
87  x - Coth[a+b*x]/b /;
88FreeQ[{a,b},x]
89
90
91(* ::Subsubsection:: *)
92(**)
93
94
95(* ::Subsubsection:: *)
96(*Reference: G&R 2.411.3, CRC 570, A&S 4.5.87*)
97
98
99(* ::Subsubsection:: *)
100(*Derivation: Integration by parts with a double-back flip*)
101
102
103(* ::Subsubsection:: *)
104(*Basis: Tanh[z]^n=(Tanh[z]^(n-1) Sinh[z])/Cosh[z]*)
105
106
107(* ::Subsubsection:: *)
108(*Rule: If  n>1, then*)
109
110
111(* ::Subsubtitle::Bold:: *)
112(*\[Integral](c Tanh[a+b x])^n \[DifferentialD]x  \[LongRightArrow]  -((c (c Tanh[a+b x])^(n-1))/(b (n-1)))+c^2 \[Integral](c Tanh[a+b x])^(n-2) \[DifferentialD]x*)
113
114
115(* ::Subsubsection:: *)
116(*Program code:*)
117
118
119(* ::Code:: *)
120Int[(c_.*Tanh[a_.+b_.*x_])^n_,x_Symbol] :=
121  -c*(c*Tanh[a+b*x])^(n-1)/(b*(n-1)) +
122  Dist[c^2,Int[(c*Tanh[a+b*x])^(n-2),x]] /;
123FreeQ[{a,b,c},x] && RationalQ[n] && n>1
124
125
126(* ::Subsubsection:: *)
127(*Reference: G&R 2.411.4, CRC 574, A&S 4.5.88*)
128
129
130(* ::Code:: *)
131Int[(c_.*Coth[a_.+b_.*x_])^n_,x_Symbol] :=
132  -c*(c*Coth[a+b*x])^(n-1)/(b*(n-1)) +
133  Dist[c^2,Int[(c*Coth[a+b*x])^(n-2),x]] /;
134FreeQ[{a,b,c},x] && RationalQ[n] && n>1
135
136
137(* ::Subsubsection:: *)
138(**)
139
140
141(* ::Subsubsection:: *)
142(*Reference: G&R 2.411.4, CRC 574'*)
143
144
145(* ::Subsubsection:: *)
146(*Derivation: Inverted integration by parts with a double-back flip*)
147
148
149(* ::Subsubsection:: *)
150(*Rule: If  n<-1, then*)
151
152
153(* ::Subsubtitle::Bold:: *)
154(*\[Integral](c Tanh[a+b x])^n \[DifferentialD]x  \[LongRightArrow]  ((c Tanh[a+b x])^(n+1)/(b c (n+1)))+1/c^2 \[Integral](c Tanh[a+b x])^(n+2) \[DifferentialD]x*)
155
156
157(* ::Subsubsection:: *)
158(*Program code:*)
159
160
161(* ::Code:: *)
162Int[(c_.*Tanh[a_.+b_.*x_])^n_,x_Symbol] :=
163  (c*Tanh[a+b*x])^(n+1)/(b*c*(n+1)) +
164  Dist[1/c^2,Int[(c*Tanh[a+b*x])^(n+2),x]] /;
165FreeQ[{a,b,c},x] && RationalQ[n] && n<-1
166
167
168(* ::Subsubsection:: *)
169(*Reference: G&R 2.411.3, CRC 570'*)
170
171
172(* ::Code:: *)
173Int[(c_.*Coth[a_.+b_.*x_])^n_,x_Symbol] :=
174  (c*Coth[a+b*x])^(n+1)/(b*c*(n+1)) +
175  Dist[1/c^2,Int[(c*Coth[a+b*x])^(n+2),x]] /;
176FreeQ[{a,b,c},x] && RationalQ[n] && n<-1
177
178
179(* ::PageBreak:: *)
180(**)
181
182
183(* ::Title::Bold::Closed:: *)
184(*\[Integral](a+b Tanh[c+d x])^n \[DifferentialD]x  when  a^2-b^2=0*)
185
186
187(* ::Subsubsection:: *)
188(*Rule: If  a^2-b^2=0, then*)
189
190
191(* ::Subsubtitle::Bold:: *)
192(*\[Integral]1/(a+b Tanh[c+d x]) \[DifferentialD]x  \[LongRightArrow]  (x/(2 a))-a/(2 b d (a+b Tanh[c+d x]))*)
193
194
195(* ::Subsubsection:: *)
196(*Program code:*)
197
198
199(* ::Code:: *)
200Int[1/(a_+b_.*Tanh[c_.+d_.*x_]),x_Symbol] :=
201  x/(2*a) - a/(2*b*d*(a+b*Tanh[c+d*x])) /;
202FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2]
203
204
205(* ::Code:: *)
206Int[1/(a_+b_.*Coth[c_.+d_.*x_]),x_Symbol] :=
207  x/(2*a) - a/(2*b*d*(a+b*Coth[c+d*x])) /;
208FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2]
209
210
211(* ::Subsubsection:: *)
212(**)
213
214
215(* ::Subsubsection:: *)
216(*Rule: If  a^2-b^2=0 \[And] a>0, then*)
217
218
219(* ::Subsubtitle::Bold:: *)
220(*\[Integral]Sqrt[a+b Tanh[c+d x]]\[DifferentialD]x  \[LongRightArrow]  ((Sqrt[2] b)/(d Sqrt[a]))ArcTanh[Sqrt[a+b Tanh[c+d x]]/(Sqrt[2] Sqrt[a])]*)
221
222
223(* ::Subsubsection:: *)
224(*Program code:*)
225
226
227(* ::Code:: *)
228Int[Sqrt[a_+b_.*Tanh[c_.+d_.*x_]],x_Symbol] :=
229  Sqrt[2]*b/(d*Rt[a,2])*ArcTanh[Sqrt[a+b*Tanh[c+d*x]]/(Sqrt[2]*Rt[a,2])] /;
230FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2] && PosQ[a]
231
232
233(* ::Code:: *)
234Int[Sqrt[a_+b_.*Coth[c_.+d_.*x_]],x_Symbol] :=
235  (Sqrt[2]*b/(d*Rt[a,2])*ArcCoth[Sqrt[a+b*Coth[c+d*x]]/(Sqrt[2]*Rt[a,2])]) /;
236FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2] && PosQ[a]
237
238
239(* ::Subsubsection:: *)
240(**)
241
242
243(* ::Subsubsection:: *)
244(*Rule: If  a^2-b^2=0 \[And] \[Not](a>0), then*)
245
246
247(* ::Subsubtitle::Bold:: *)
248(*\[Integral]Sqrt[a+b Tanh[c+d x]]\[DifferentialD]x  \[LongRightArrow]  -((Sqrt[2] b)/(d Sqrt[-a]))ArcTan[Sqrt[a+b Tanh[c+d x]]/(Sqrt[2] Sqrt[-a])]*)
249
250
251(* ::Subsubsection:: *)
252(*Program code:*)
253
254
255(* ::Code:: *)
256Int[Sqrt[a_+b_.*Tanh[c_.+d_.*x_]],x_Symbol] :=
257  -Sqrt[2]*b/(d*Rt[-a,2])*ArcTan[Sqrt[a+b*Tanh[c+d*x]]/(Sqrt[2]*Rt[-a,2])] /;
258FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2] && NegQ[a]
259
260
261(* ::Code:: *)
262Int[Sqrt[a_+b_.*Coth[c_.+d_.*x_]],x_Symbol] :=
263  Sqrt[2]*b/(d*Rt[-a,2])*ArcCot[Sqrt[a+b*Coth[c+d*x]]/(Sqrt[2]*Rt[-a,2])] /;
264FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2] && NegQ[a]
265
266
267(* ::Subsubsection:: *)
268(**)
269
270
271(* ::Subsubsection:: *)
272(*Rule: If  a^2-b^2=0 \[And] n\[Element]\[DoubleStruckCapitalF] \[And] n>1, then*)
273
274
275(* ::Subsubtitle::Bold:: *)
276(*\[Integral](a+b Tanh[c+d x])^n \[DifferentialD]x  \[LongRightArrow]  -((a^2 (a+b Tanh[c+d x])^(n-1))/(b d (n-1)))+2 a \[Integral](a+b Tanh[c+d x])^(n-1) \[DifferentialD]x*)
277
278
279(* ::Subsubsection:: *)
280(*Program code:*)
281
282
283(* ::Code:: *)
284Int[(a_+b_.*Tanh[c_.+d_.*x_])^n_,x_Symbol] :=
285  -a^2*(a+b*Tanh[c+d*x])^(n-1)/(b*d*(n-1)) +
286  Dist[2*a,Int[(a+b*Tanh[c+d*x])^(n-1),x]] /;
287FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2] && FractionQ[n] && n>1
288
289
290(* ::Code:: *)
291Int[(a_+b_.*Coth[c_.+d_.*x_])^n_,x_Symbol] :=
292  -a^2*(a+b*Coth[c+d*x])^(n-1)/(b*d*(n-1)) +
293  Dist[2*a,Int[(a+b*Coth[c+d*x])^(n-1),x]] /;
294FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2] && FractionQ[n] && n>1
295
296
297(* ::Subsubsection:: *)
298(**)
299
300
301(* ::Subsubsection:: *)
302(*Rule: If  a^2-b^2=0 \[And] n<0, then*)
303
304
305(* ::Subsubtitle::Bold:: *)
306(*\[Integral](a+b Tanh[c+d x])^n \[DifferentialD]x  \[LongRightArrow]  ((a (a+b Tanh[c+d x])^n)/(2 b d n))+1/(2 a) \[Integral](a+b Tanh[c+d x])^(n+1) \[DifferentialD]x*)
307
308
309(* ::Subsubsection:: *)
310(*Program code:*)
311
312
313(* ::Code:: *)
314Int[(a_+b_.*Tanh[c_.+d_.*x_])^n_,x_Symbol] :=
315  a*(a+b*Tanh[c+d*x])^n/(2*b*d*n) +
316  Dist[1/(2*a),Int[(a+b*Tanh[c+d*x])^(n+1),x]] /;
317FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2] && RationalQ[n] && n<0
318
319
320(* ::Code:: *)
321Int[(a_+b_.*Coth[c_.+d_.*x_])^n_,x_Symbol] :=
322  a*(a+b*Coth[c+d*x])^n/(2*b*d*n) +
323  Dist[1/(2*a),Int[(a+b*Coth[c+d*x])^(n+1),x]] /;
324FreeQ[{a,b,c,d},x] && ZeroQ[a^2-b^2] && RationalQ[n] && n<0
325
326
327(* ::PageBreak:: *)
328(**)
329
330
331(* ::Title::Bold::Closed:: *)
332(*\[Integral](a+b Tanh[c+d x])^n \[DifferentialD]x  when  a^2+b^2!=0*)
333
334
335(* ::Subsubsection:: *)
336(*Derivation: Algebraic expansion and integration by substitution*)
337
338
339(* ::Subsubsection:: *)
340(*Basis: 1/(a+b Tanh[z])=a/(a^2-b^2)-b/((a^2-b^2) (a Cosh[z]+b Sinh[z])) \!\( *)
341(*\*SubscriptBox[\(\[PartialD]\), \(z\)]\((a\ Cosh[z] + b\ Sinh[z])\)\)*)
342
343
344(* ::Subsubsection:: *)
345(*Rule: If  a^2-b^2!=0, then*)
346
347
348(* ::Subsubtitle::Bold:: *)
349(*\[Integral]1/(a+b Tanh[c+d x]) \[DifferentialD]x  \[LongRightArrow]  ((a x)/(a^2-b^2))-(b Log[a Cosh[c+d x]+b Sinh[c+d x]])/(d (a^2-b^2))*)
350
351
352(* ::Subsubsection:: *)
353(*Program code:*)
354
355
356(* ::Code:: *)
357Int[1/(a_+b_.*Tanh[c_.+d_.*x_]),x_Symbol] :=
358  a*x/(a^2-b^2) - b*Log[a*Cosh[c+d*x]+b*Sinh[c+d*x]]/(d*(a^2-b^2)) /;
359FreeQ[{a,b,c,d},x] && NonzeroQ[a^2-b^2]
360
361
362(* ::Code:: *)
363Int[1/(a_+b_.*Coth[c_.+d_.*x_]),x_Symbol] :=
364  a*x/(a^2-b^2) - b*Log[b*Cosh[c+d*x]+a*Sinh[c+d*x]]/(d*(a^2-b^2)) /;
365FreeQ[{a,b,c,d},x] && NonzeroQ[a^2-b^2]
366
367
368(* ::PageBreak:: *)
369(**)
370
371
372(* ::Title::Bold::Closed:: *)
373(*\[Integral](A+B Tanh[c+d x])(a+b Tanh[c+d x])^n \[DifferentialD]x*)
374
375
376(* ::Subsubsection:: *)
377(*Derivation: Algebraic expansion*)
378
379
380(* ::Subsubsection:: *)
381(*Basis: (A+B z)/(a+b z)=B/b+(b A-a B)/b 1/(a+b z)*)
382
383
384(* ::Subsubsection:: *)
385(*Rule: If  b A-a B!=0, then*)
386
387
388(* ::Subsubtitle::Bold:: *)
389(*\[Integral](A+B Tanh[c+d x])/(a+b Tanh[c+d x]) \[DifferentialD]x  \[LongRightArrow]  ((B x)/b)+(b A-a B)/b \[Integral]1/(a+b Tanh[c+d x]) \[DifferentialD]x*)
390
391
392(* ::Subsubsection:: *)
393(*Program code:*)
394
395
396(* ::Code:: *)
397Int[(A_.+B_.*Tanh[c_.+d_.*x_])/(a_.+b_.*Tanh[c_.+d_.*x_]),x_Symbol] :=
398  B*x/b + Dist[(b*A-a*B)/b,Int[1/(a+b*Tanh[c+d*x]),x]] /;
399FreeQ[{a,b,c,d,A,B},x] && NonzeroQ[b*A-a*B]
400
401
402(* ::Code:: *)
403Int[(A_.+B_.*Coth[c_.+d_.*x_])/(a_.+b_.*Coth[c_.+d_.*x_]),x_Symbol] :=
404  B*x/b + Dist[(b*A-a*B)/b,Int[1/(a+b*Coth[c+d*x]),x]] /;
405FreeQ[{a,b,c,d,A,B},x] && NonzeroQ[b*A-a*B]
406
407
408(* ::Subsubsection:: *)
409(**)
410
411
412(* ::Subsubsection:: *)
413(*Note: This rule does not appear in published integral tables.*)
414
415
416(* ::Subsubsection:: *)
417(*Rule: If  A^2-B^2=0 \[And] b A+a B!=0, then*)
418
419
420(* ::Subsubtitle::Bold:: *)
421(*\[Integral](A+B Tanh[c+d x])/Sqrt[a+b Tanh[c+d x]] \[DifferentialD]x  \[LongRightArrow]  ((2 B)/(d Sqrt[(b A+a B)/B]))ArcTanh[Sqrt[a+b Tanh[c+d x]]/Sqrt[(b A+a B)/B]]*)
422
423
424(* ::Subsubsection:: *)
425(*Program code:*)
426
427
428(* ::Code:: *)
429Int[(A_+B_.*Tanh[c_.+d_.*x_])/Sqrt[a_.+b_.*Tanh[c_.+d_.*x_]],x_Symbol] :=
430  2*B/(d*Sqrt[(b*A+a*B)/B])*ArcTanh[Sqrt[a+b*Tanh[c+d*x]]/Sqrt[(b*A+a*B)/B]] /;
431FreeQ[{a,b,c,d,A,B},x] && ZeroQ[A^2-B^2] && NonzeroQ[b*A+a*B]
432
433
434(* ::Code:: *)
435Int[(A_+B_.*Coth[c_.+d_.*x_])/Sqrt[a_.+b_.*Coth[c_.+d_.*x_]],x_Symbol] :=
436  2*B/(d*Sqrt[(b*A+a*B)/B])*ArcTanh[Sqrt[a+b*Coth[c+d*x]]/Sqrt[(b*A+a*B)/B]] /;
437FreeQ[{a,b,c,d,A,B},x] && ZeroQ[A^2-B^2] && NonzeroQ[b*A+a*B]
438
439
440(* ::Subsubsection:: *)
441(**)
442
443
444(* ::Subsubsection:: *)
445(*Derivation: Algebraic expansion*)
446
447
448(* ::Subsubsection:: *)
449(*Basis: A+B z=(A+B)/2 (1+z)+(A-B)/2 (1-z)*)
450
451
452(* ::Subsubsection:: *)
453(*Rule: If  A^2-B^2!=0 \[And] a^2-b^2!=0, then*)
454
455
456(* ::Subsubtitle::Bold:: *)
457(*\[Integral](A+B Tanh[c+d x])/Sqrt[a+b Tanh[c+d x]] \[DifferentialD]x  \[LongRightArrow]  ((A+B)/2)\[Integral](1+Tanh[c+d x])/Sqrt[a+b Tanh[c+d x]] \[DifferentialD]x+(A-B)/2 \[Integral](1-Tanh[c+d x])/Sqrt[a+b Tanh[c+d x]] \[DifferentialD]x*)
458
459
460(* ::Subsubsection:: *)
461(*Program code:*)
462
463
464(* ::Code:: *)
465Int[(A_.+B_.*Tanh[c_.+d_.*x_])/Sqrt[a_.+b_.*Tanh[c_.+d_.*x_]],x_Symbol] :=
466  Dist[(A+B)/2,Int[(1+Tanh[c+d*x])/Sqrt[a+b*Tanh[c+d*x]],x]] +
467  Dist[(A-B)/2,Int[(1-Tanh[c+d*x])/Sqrt[a+b*Tanh[c+d*x]],x]] /;
468FreeQ[{a,b,c,d,A,B},x] && NonzeroQ[A^2-B^2] && NonzeroQ[a^2-b^2]
469
470
471(* ::Code:: *)
472Int[(A_.+B_.*Coth[c_.+d_.*x_])/Sqrt[a_.+b_.*Coth[c_.+d_.*x_]],x_Symbol] :=
473  Dist[(A+B)/2,Int[(1+Coth[c+d*x])/Sqrt[a+b*Coth[c+d*x]],x]] +
474  Dist[(A-B)/2,Int[(1-Coth[c+d*x])/Sqrt[a+b*Coth[c+d*x]],x]] /;
475FreeQ[{a,b,c,d,A,B},x] && NonzeroQ[A^2-B^2] && NonzeroQ[a^2-b^2]
476
477
478(* ::Subsubsection:: *)
479(**)
480
481
482(* ::Subsubsection:: *)
483(*Note: This rule does not appear in published integral tables.*)
484
485
486(* ::Subsubsection:: *)
487(*Rule: If  n>0, then*)
488
489
490(* ::Subsubtitle::Bold:: *)
491(*\[Integral](A+B Tanh[c+d x])(a+b Tanh[c+d x])^n \[DifferentialD]x  \[LongRightArrow]  *)
492(*-((B (a+b Tanh[c+d x])^n)/(d n))+\[Integral](a A+b B+(b A+a B) Tanh[c+d x])(a+b Tanh[c+d x])^(n-1) \[DifferentialD]x*)
493
494
495(* ::Subsubsection:: *)
496(*Program code:*)
497
498
499(* ::Code:: *)
500Int[(A_.+B_.*Tanh[c_.+d_.*x_])*(a_+b_.*Tanh[c_.+d_.*x_])^n_.,x_Symbol] :=
501  -B*(a+b*Tanh[c+d*x])^n/(d*n) +
502  Int[(a*A+b*B+(b*A+a*B)*Tanh[c+d*x])*(a+b*Tanh[c+d*x])^(n-1),x] /;
503FreeQ[{a,b,c,d,A,B},x] && RationalQ[n] && n>0
504
505
506(* ::Code:: *)
507Int[(A_.+B_.*Coth[c_.+d_.*x_])*(a_+b_.*Coth[c_.+d_.*x_])^n_.,x_Symbol] :=
508  -B*(a+b*Coth[c+d*x])^n/(d*n) +
509  Int[(a*A+b*B+(b*A+a*B)*Coth[c+d*x])*(a+b*Coth[c+d*x])^(n-1),x] /;
510FreeQ[{a,b,c,d,A,B},x] && RationalQ[n] && n>0
511
512
513(* ::Subsubsection:: *)
514(**)
515
516
517(* ::Subsubsection:: *)
518(*Note: This rule does not appear in published integral tables.*)
519
520
521(* ::Subsubsection:: *)
522(*Rule: If  a^2-b^2!=0 \[And] n<-1, then*)
523
524
525(* ::Subsubtitle::Bold:: *)
526(*\[Integral](A+B Tanh[c+d x])(a+b Tanh[c+d x])^n \[DifferentialD]x  \[LongRightArrow]  *)
527(*-(((b A-a B) (a+b Tanh[c+d x])^(n+1))/(d(a^2-b^2)(n+1)))+1/(a^2-b^2) \[Integral](a A-b B-(b A-a B) Tanh[c+d x])(a+b Tanh[c+d x])^(n+1) \[DifferentialD]x*)
528
529
530(* ::Subsubsection:: *)
531(*Program code:*)
532
533
534(* ::Code:: *)
535Int[(A_.+B_.*Tanh[c_.+d_.*x_])*(a_+b_.*Tanh[c_.+d_.*x_])^n_,x_Symbol] :=
536  -(b*A-a*B)*(a+b*Tanh[c+d*x])^(n+1)/(d*(a^2-b^2)*(n+1)) +
537  Dist[1/(a^2-b^2),Int[(a*A-b*B-(b*A-a*B)*Tanh[c+d*x])*(a+b*Tanh[c+d*x])^(n+1),x]] /;
538FreeQ[{a,b,c,d,A,B},x] && NonzeroQ[a^2-b^2] && RationalQ[n] && n<-1
539
540
541(* ::Code:: *)
542Int[(A_.+B_.*Coth[c_.+d_.*x_])*(a_+b_.*Coth[c_.+d_.*x_])^n_,x_Symbol] :=
543  -(b*A-a*B)*(a+b*Coth[c+d*x])^(n+1)/(d*(a^2-b^2)*(n+1)) +
544  Dist[1/(a^2-b^2),Int[(a*A-b*B-(b*A-a*B)*Coth[c+d*x])*(a+b*Coth[c+d*x])^(n+1),x]] /;
545FreeQ[{a,b,c,d,A,B},x] && NonzeroQ[a^2-b^2] && RationalQ[n] && n<-1
546
547
548(* ::PageBreak:: *)
549(**)
550
551
552(* ::Title::Bold::Closed:: *)
553(*\[Integral](a+b Tan[c+d x]^2)^n \[DifferentialD]x*)
554
555
556(* ::Subsubsection:: *)
557(*Derivation: Algebraic simplification*)
558
559
560(* ::Subsubsection:: *)
561(*Basis: If  a-b=0, then  a+b Tan[z]^2=b Sec[z]^2*)
562
563
564(* ::Subsubsection:: *)
565(*Rule: If  a-b=0 \[And] m\[Element]\[DoubleStruckCapitalZ], then*)
566
567
568(* ::Subsubtitle::Bold:: *)
569(*\[Integral]u (a+b Tan[v]^2)^m \[DifferentialD]x  \[LongRightArrow]  b^m\[Integral]u Sec[v]^(2m) \[DifferentialD]x*)
570
571
572(* ::Subsubsection:: *)
573(*Program code:*)
574
575
576(* ::Code:: *)
577Int[u_.*(a_+b_.*Tan[v_]^2)^m_,x_Symbol] :=
578  Dist[b^m,Int[u*Sec[v]^(2*m),x]] /;
579FreeQ[{a,b,m},x] && ZeroQ[a-b] && IntegerQ[m]
580
581
582(* ::Subsubsection:: *)
583(**)
584
585
586(* ::Subsubsection:: *)
587(*Derivation: Algebraic simplification*)
588
589
590(* ::Subsubsection:: *)
591(*Basis: If  a-b=0, then  a+b Tan[z]^2=b Sec[z]^2*)
592
593
594(* ::Subsubsection:: *)
595(*Rule: If  a-b=0 \[And] m\[NotElement]\[DoubleStruckCapitalZ], then*)
596
597
598(* ::Subsubtitle::Bold:: *)
599(*\[Integral]u (a+b Tan[v]^2)^m \[DifferentialD]x  \[LongRightArrow]  \[Integral]u (b Sec[v]^2)^m \[DifferentialD]x*)
600
601
602(* ::Subsubsection:: *)
603(*Program code:*)
604
605
606(* ::Code:: *)
607Int[u_.*(a_+b_.*Tan[v_]^2)^m_,x_Symbol] :=
608  Int[u*(b*Sec[v]^2)^m,x] /;
609FreeQ[{a,b,m},x] && ZeroQ[a-b] && Not[IntegerQ[m]]
610
611
612(* ::Subsubsection:: *)
613(**)
614
615
616(* ::Subsubsection:: *)
617(*Rule: If  a+b!=0, then*)
618
619
620(* ::Subsubtitle::Bold:: *)
621(*\[Integral]1/(a+b Tanh[c+d x]^2) \[DifferentialD]x  \[LongRightArrow]  (x/(a+b))+Sqrt[b]/(Sqrt[a] d (a+b)) ArcTan[(Sqrt[b] Tanh[c+d x])/Sqrt[a]]*)
622
623
624(* ::Subsubsection:: *)
625(*Program code:*)
626
627
628(* ::Code:: *)
629Int[1/(a_+b_.*Tanh[c_.+d_.*x_]^2),x_Symbol] :=
630  x/(a+b) + Sqrt[b]*ArcTan[Sqrt[b]*Tanh[c+d*x]/Sqrt[a]]/(Sqrt[a]*d*(a+b)) /;
631FreeQ[{a,b,c,d},x] && NonzeroQ[a+b]
632
633
634(* ::Code:: *)
635Int[1/(a_+b_.*Coth[c_.+d_.*x_]^2),x_Symbol] :=
636  x/(a+b) + Sqrt[b]*ArcTan[Sqrt[b]*Coth[c+d*x]/Sqrt[a]]/(Sqrt[a]*d*(a+b)) /;
637FreeQ[{a,b,c,d},x] && NonzeroQ[a+b]
638
639
640(* ::PageBreak:: *)
641(**)
642
643
644(* ::Title::Bold::Closed:: *)
645(*\[Integral]x^m Tanh[a+b x^n]^p \[DifferentialD]x*)
646
647
648(* ::Subsubsection:: *)
649(*Derivation: Algebraic expansion*)
650
651
652(* ::Subsubsection:: *)
653(*Basis: Tanh[z]=1-2/(1+E^(2z))*)
654
655
656(* ::Subsubsection:: *)
657(*Rule: If  m\[Element]\[DoubleStruckCapitalZ] \[And] m>0 \[And] m-n+1!=0, then*)
658
659
660(* ::Subsubtitle::Bold:: *)
661(*\[Integral]x^m Tanh[a+b x^n]\[DifferentialD]x  \[LongRightArrow]  (x^(m+1)/(m+1))-2\[Integral]x^m/(1+E^(2a+2b x^n)) \[DifferentialD]x*)
662
663
664(* ::Subsubsection:: *)
665(*Program code:*)
666
667
668(* ::Code:: *)
669Int[x_^m_.*Tanh[a_.+b_.*x_^n_.],x_Symbol] :=
670  x^(m+1)/(m+1) -
671  Dist[2,Int[x^m/(1+E^(2*a+2*b*x^n)),x]] /;
672FreeQ[{a,b,n},x] && IntegerQ[m] && m>0 && NonzeroQ[m-n+1]
673
674
675(* ::Code:: *)
676Int[x_^m_.*Coth[a_.+b_.*x_^n_.],x_Symbol] :=
677  x^(m+1)/(m+1) -
678  Dist[2,Int[x^m/(1-E^(2*a+2*b*x^n)),x]] /;
679FreeQ[{a,b,n},x] && IntegerQ[m] && m>0 && NonzeroQ[m-n+1]
680
681
682(* ::Subsubsection:: *)
683(**)
684
685
686(* ::Subsubsection:: *)
687(*Note: This rule does not appear in published integral tables.*)
688
689
690(* ::Subsubsection:: *)
691(*Rule: If  p>1 \[And] m-n+1!=0 \[And] 0<n<=m, then*)
692
693
694(* ::Subsubtitle::Bold:: *)
695(*\[Integral]x^m Tanh[a+b x^n]^p \[DifferentialD]x  \[LongRightArrow]  -((x^(m-n+1) Tanh[a+b x^n]^(p-1))/(b n (p-1)))+*)
696(*(m-n+1)/(b n (p-1)) \[Integral]x^(m-n) Tanh[a+b x^n]^(p-1) \[DifferentialD]x+\[Integral]x^m Tanh[a+b x^n]^(p-2) \[DifferentialD]x*)
697
698
699(* ::Subsubsection:: *)
700(*Program code:*)
701
702
703(* ::Code:: *)
704Int[x_^m_.*Tanh[a_.+b_.*x_^n_.]^p_,x_Symbol] :=
705  -x^(m-n+1)*Tanh[a+b*x^n]^(p-1)/(b*n*(p-1)) +
706  Dist[(m-n+1)/(b*n*(p-1)),Int[x^(m-n)*Tanh[a+b*x^n]^(p-1),x]] +
707  Int[x^m*Tanh[a+b*x^n]^(p-2),x] /;
708FreeQ[{a,b},x] && RationalQ[{m,n,p}] && p>1 && NonzeroQ[m-n+1] && 0<n<=m
709
710
711(* ::Code:: *)
712Int[x_^m_.*Coth[a_.+b_.*x_^n_.]^p_,x_Symbol] :=
713  -x^(m-n+1)*Coth[a+b*x^n]^(p-1)/(b*n*(p-1)) +
714  Dist[(m-n+1)/(b*n*(p-1)),Int[x^(m-n)*Coth[a+b*x^n]^(p-1),x]] +
715  Int[x^m*Coth[a+b*x^n]^(p-2),x] /;
716FreeQ[{a,b},x] && RationalQ[{m,n,p}] && p>1 && NonzeroQ[m-n+1] && 0<n<=m
717
718
719(* ::PageBreak:: *)
720(**)
721
722
723(* ::Title::Bold::Closed:: *)
724(*\[Integral]x^m Tanh[a+b x+c x^2]\[DifferentialD]x*)
725
726
727(* ::Subsubsection:: *)
728(*Rule:*)
729
730
731(* ::Subsubtitle::Bold:: *)
732(*\[Integral]x Tanh[a+b x+c x^2]\[DifferentialD]x  \[LongRightArrow]  (Log[Cosh[a+b x+c x^2]]/(2 c))-b/(2 c) \[Integral]Tanh[a+b x+c x^2]\[DifferentialD]x*)
733
734
735(* ::Subsubsection:: *)
736(*Program code:*)
737
738
739(* ::Code:: *)
740Int[x_*Tanh[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
741  Log[Cosh[a+b*x+c*x^2]]/(2*c) -
742  Dist[b/(2*c),Int[Tanh[a+b*x+c*x^2],x]] /;
743FreeQ[{a,b,c},x]
744
745
746(* ::Code:: *)
747Int[x_*Coth[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
748  Log[Sinh[a+b*x+c*x^2]]/(2*c) -
749  Dist[b/(2*c),Int[Coth[a+b*x+c*x^2],x]] /;
750FreeQ[{a,b,c},x]
751
752
753(* ::Subsubsection:: *)
754(**)
755
756
757(* ::Subsubsection:: *)
758(*Note: This rule is valid, but to be useful need a rule for reducing integrands of the form x^m Log[Cosh[a+b x+c x^2]].*)
759
760
761(* ::Subsubsection:: *)
762(*Rule: If  m>1, then*)
763
764
765(* ::Subsubtitle::Bold:: *)
766(*\[Integral]x^m Tanh[a+b x+c x^2]\[DifferentialD]x  \[LongRightArrow]  ((x^(m-1) Log[Cosh[a+b x+c x^2]])/(2 c))-*)
767(*b/(2 c) \[Integral]x^(m-1) Tanh[a+b x+c x^2]\[DifferentialD]x-(m-1)/(2 c) \[Integral]x^(m-2) Log[Cosh[a+b x+c x^2]]\[DifferentialD]x*)
768
769
770(* ::Subsubsection:: *)
771(*Program code:*)
772
773
774(* ::Code:: *)
775(* Int[x_^m_*Tanh[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
776  x^(m-1)*Log[Cosh[a+b*x+c*x^2]]/(2*c) -
777  Dist[b/(2*c),Int[x^(m-1)*Tanh[a+b*x+c*x^2],x]] -
778  Dist[(m-1)/(2*c),Int[x^(m-2)*Log[Cosh[a+b*x+c*x^2]],x]] /;
779FreeQ[{a,b,c},x] && RationalQ[m] && m>1 *)
780
781
782(* ::Code:: *)
783(* Int[x_^m_*Coth[a_.+b_.*x_+c_.*x_^2],x_Symbol] :=
784  x^(m-1)*Log[Sinh[a+b*x+c*x^2]]/(2*c) -
785  Dist[b/(2*c),Int[x^(m-1)*Coth[a+b*x+c*x^2],x]] -
786  Dist[(m-1)/(2*c),Int[x^(m-2)*Log[Sinh[a+b*x+c*x^2]],x]] /;
787FreeQ[{a,b,c},x] && RationalQ[m] && m>1 *)
788
789
790(* ::PageBreak:: *)
791(**)
792