1#compdef locale
2
3local curcontext="$curcontext" state state_descr line expl ret=1
4typeset -A opt_args; local -a specs aopts
5
6if _pick_variant gnu='(Free Soft|GNU|GLIBC)' unix --version; then
7
8  local exargs="-? --help --usage -V --version"
9
10  aopts=( -A "-*" -C -S -s )
11  specs=(
12    '(- *)'{-\?,--help}'[display help information]'
13    '(- *)--usage[display a short usage message]'
14    '(- *)'{-V,--version}'[print program version]'
15    - set1
16    "(-a --all-locales $exargs)"{-a,--all-locales}'[list all available locales]'
17    "(-v --verbose $exargs)"{-v,--verbose}'[display additional information]'
18    - set2
19    "(-m --charmaps $exargs)"{-m,--charmaps}'[list all available charmaps]'
20    - set3
21    "(-c --category-name $exargs)"{-c,--category-name}'[print also locale category]'
22    "(-k --keyword-name $exargs)"{-k,--keyword-name}'[print also keyword of each value]'
23    '*:name:->catkey'
24  )
25
26elif [[ $OSTYPE == openbsd* ]]; then
27
28  specs=(
29    '(-m)-a[list all available locales]'
30    '(-a)-m[list all available charmaps]'
31  )
32
33else
34
35  aopts=( -C -A "-*" )
36  specs=(
37    - set1
38    '-a[list all available locales]'
39    - set2
40    '-m[list all available charmaps]'
41    - set3
42    '-c[print also locale category]'
43    '-k[print also keyword of each value]'
44    '*:name:->catkey'
45  )
46fi
47
48_arguments $aopts : $specs && ret=0
49
50if [[ $state == catkey ]]; then
51  typeset -aU cats keys
52
53  case $OSTYPE in
54    *bsd*)
55      # keywords from comparing locale -k list on netbsd and freebsd
56      # the additional keywords freebsd supports will be added via
57      # the reassignment of keys
58      keys+=(
59        charmap decimal_point thousands_sep grouping radixchar thousep int_curr_symbol
60        currency_symbol mon_decimal_point mon_thousands_sep mon_grouping positive_sign
61        negative_sign int_frac_digits frac_digits p_cs_precedes p_sep_by_space n_cs_precedes
62        n_sep_by_space p_sign_posn n_sign_posn int_p_cs_precedes int_p_sep_by_space
63        int_n_cs_precedes int_n_sep_by_space int_p_sign_posn int_n_sign_posn d_t_fmt d_fmt
64        t_fmt am_str pm_str t_fmt_ampm day_1 day_2 day_3 day_4 day_5 day_6 day_7 abday_1
65        abday_2 abday_3 abday_4 abday_5 abday_6 abday_7 mon_1 mon_2 mon_3 mon_4 mon_5 mon_6
66        mon_7 mon_8 mon_9 mon_10 mon_11 mon_12 abmon_1 abmon_2 abmon_3 abmon_4 abmon_5
67        abmon_6 abmon_7 abmon_8 abmon_9 abmon_10 abmon_11 abmon_12 era era_d_fmt era_d_t_fmt
68        era_t_fmt alt_digits yesexpr noexpr yesstr nostr
69      );|
70    (free|net|dragonfly)bsd*) (( words[(I)-k] )) && keys+=(list);;
71    *)
72      cats=( ${${${(f)"$(locale)"}%=*}%(LANG|LANGUAGE|LC_ALL)} )
73    ;;
74  esac
75
76  keys=( $keys ${${(f)"$(locale -k $cats 2>/dev/null)"}%=*} )
77  if [[ $OSTYPE == freebsd* ]] && (( words[(I)list] )); then
78    _message -e values prefix && ret=0
79  else
80    _wanted values expl name compadd "$@" -a - cats keys && ret=0
81  fi
82fi
83
84return ret
85