xref: /minix/tools/compat/configure.ac (revision 0a6a1f1d) 
1#	$NetBSD: configure.ac,v 1.84 2015/07/26 14:01:53 kamil Exp $
2#
3# Autoconf definition file for libnbcompat.
4#
5# When you edit configure.ac:
6# 0. Create the tools versions of autoconf and autoheader:
7#        cd ${SRCDIR} && build.sh -V MKMAINTAINERTOOLS=yes tools
8#    (This might not work if you try it after editing configure.ac.)
9# 1. edit configure.ac
10# 2. Regenerate "configure" and "nbtool_config.h.in" from "configure.ac":
11#        cd ${SRCDIR}/tools/compat && ${TOOLDIR}/bin/nbmake-${MACHINE} regen
12#    (Please don't use a non-tools version of autoconf or autoheader.)
13# 3. Test that the tools still build:
14#        mv ${TOOLDIR} ${TOOLDIR}.bak
15#        cd ${SRCDIR} && build.sh -V MKMAINTAINERTOOLS=yes tools
16# 4. cvs commit files that you edited.
17# 5. Regen again, to pick up changed RCS IDs from the above commit:
18#        cd ${SRCDIR}/tools/compat && ${TOOLDIR}/bin/nbmake-${MACHINE} regen
19# 6. cvs commit files that were generated.
20#
21
22AC_INIT([libnbcompat], [noversion], [lib-bug-people@NetBSD.org])
23AC_CONFIG_HEADERS(nbtool_config.h)
24AC_CONFIG_FILES(defs.mk)
25
26# Autoheader header and footer
27AH_TOP([/*      $][NetBSD$    */
28
29#ifndef __NETBSD_NBTOOL_CONFIG_H__
30#define __NETBSD_NBTOOL_CONFIG_H__])
31
32AH_BOTTOM([#include "compat_defs.h"
33#endif /* !__NETBSD_NBTOOL_CONFIG_H__ */])
34
35AC_DEFUN([AC_NETBSD],
36[AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
37      AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
38      AC_MSG_CHECKING([for NetBSD or MINIX3])
39      AC_EGREP_CPP(yes,
40      [#if defined(__NetBSD__) || defined(__minix)
41	yes
42	#endif
43	],
44	[AC_MSG_RESULT([yes])
45	 AC_DEFINE([_POSIX_SOURCE], 1, [Define for NetBSD headers.])
46	 AC_DEFINE([_POSIX_C_SOURCE], 200112L, [Define for NetBSD headers.])
47	 AC_DEFINE([_XOPEN_SOURCE], 600, [Define for NetBSD headers.])],
48	[AC_MSG_RESULT([no])])
49])# AC_NETBSD
50
51AC_NETBSD
52AC_PATH_PROG(BSHELL, sh, )
53if test x"$BSHELL" = x; then
54	AC_MSG_ERROR([sh must be somewhere on \$PATH])
55fi
56AC_DEFINE_UNQUOTED([PATH_BSHELL], "$BSHELL", [Path to sh(1).])
57
58AC_C_BIGENDIAN
59AC_HEADER_STDC
60
61# Confirm existence of zlib.  (This is available as a default install
62# option on many OS's; this could be added as a reachover build in the
63# future.)
64AC_CHECK_HEADER(zlib.h,,
65	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
66AC_CHECK_LIB(z, gzdopen,,
67	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
68
69# Make sure certain required headers are available.
70# These are not necessarily required by the code, but they are not
71# currently conditionalized.
72AC_CHECK_HEADERS(sys/ioctl.h sys/mman.h sys/param.h \
73	sys/socket.h sys/stat.h sys/time.h sys/types.h sys/utsname.h \
74	sys/wait.h assert.h ctype.h errno.h fcntl.h grp.h limits.h locale.h \
75	netdb.h pwd.h signal.h stdarg.h stdio.h stdlib.h string.h \
76	termios.h unistd.h,,
77	AC_MSG_ERROR([standard system header file not found]))
78
79# Find headers that may not be available.
80AC_HEADER_DIRENT
81AC_CHECK_HEADERS(sys/mtio.h sys/sysmacros.h sys/syslimits.h \
82	getopt.h features.h malloc.h sys/poll.h pthread.h stddef.h rpc/types.h)
83AC_CHECK_HEADERS(sys/bswap.h machine/bswap.h sys/cdefs.h machine/endian.h \
84	sys/endian.h sys/featuretest.h err.h inttypes.h libgen.h paths.h \
85	stdint.h util.h resolv.h arpa/nameser.h,,
86	[test -f include/$ac_header || touch include/$ac_header])
87AC_CHECK_HEADERS(rpc/types.h netconfig.h,,
88	[echo '#include "nbtool_config.h"' >include/$ac_header.new
89	echo '#include "'$srcdir/../../include/$ac_header'"' \
90		>>include/$ac_header.new
91	if cmp include/$ac_header.new include/$ac_header >/dev/null 2>&1; then
92		rm -f include/$ac_header.new
93	else
94		mv -f include/$ac_header.new include/$ac_header
95	fi])
96
97# Typedefs.
98AC_TYPE_SIZE_T
99AC_CHECK_TYPES([id_t, long long, u_long, u_char, u_short, u_int, u_quad_t])
100AC_CHECK_TYPE(socklen_t, [AC_DEFINE([HAVE_SOCKLEN_T], 1,
101			  [Define if you have the socklen_t type.])],,
102[#include <sys/types.h>
103#ifdef HAVE_RPC_TYPES_H
104#include <rpc/types.h>
105#endif
106#include <sys/socket.h>])
107
108dnl XXX - This is UGLY.  Need a better way to homogenize the bitsized types,
109dnl including use of compiler primitive types via AC_CHECK_SIZEOF.
110dnl
111define([NB_CHECK_INTTYPE], [
112	AC_CHECK_TYPE(uint][$1][_t,, [
113		AC_CHECK_TYPE(u_int][$1][_t,
114			AC_DEFINE(uint][$1][_t, u_int][$1][_t, \
115			          [Define if you have u_int][$1][_t, but not uint][$1][_t.]),
116			AC_MSG_ERROR([cannot find a suitable type for uint][$1][_t]))
117	])
118	AC_CHECK_TYPE(u_int][$1][_t,, [
119		AC_CHECK_TYPE(uint][$1][_t,
120			AC_DEFINE(u_int][$1][_t, uint][$1][_t, \
121				  [Define if you have uint][$1][_t, but not u_int][$1][_t.]),
122			AC_MSG_ERROR([cannot find a suitable type for u_int][$1][_t]))
123	])
124])
125
126NB_CHECK_INTTYPE(8)
127NB_CHECK_INTTYPE(16)
128NB_CHECK_INTTYPE(32)
129NB_CHECK_INTTYPE(64)
130
131# Struct members.
132AC_CHECK_MEMBERS([DIR.dd_fd, DIR.__dd_fd, struct dirent.d_namlen],,,
133[#include <sys/types.h>
134#include <dirent.h>])
135AC_CHECK_MEMBERS([struct stat.st_flags, struct stat.st_gen,
136	struct stat.st_birthtime, struct stat.st_birthtimensec,
137	struct stat.st_atim, struct stat.st_mtimensec],,,
138	[#include <sys/stat.h>])
139AC_CHECK_MEMBERS(struct statvfs.f_iosize,,, [#include <sys/statvfs.h>])
140AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
141
142# Global variable decls.
143AC_CHECK_DECLS([optind, optreset],,, [
144#include <stdio.h>
145#include <stdlib.h>
146#include <unistd.h>
147#ifdef HAVE_GETOPT_H
148#include <getopt.h>
149#endif
150])
151AC_CHECK_DECLS(sys_signame,,, [#include <signal.h>])
152
153# Library functions (where a .h check isn't enough).
154AC_FUNC_ALLOCA
155AC_CHECK_FUNCS(atoll asprintf asnprintf basename devname dirfd dirname \
156	dprintf esetfunc fgetln flock fpurge __fpurge futimes getline \
157	getopt getopt_long group_from_gid gid_from_group \
158	heapsort isblank issetugid lchflags lchmod lchown lutimes mkstemp \
159	mkdtemp poll pread putc_unlocked pwcache_userdb pwcache_groupdb \
160	pwrite raise_default_signal random reallocarr setenv \
161	setgroupent setprogname setpassent \
162	snprintb_m snprintf strlcat strlcpy strmode \
163	strndup strnlen strsep strsuftoll strtoi strtoll strtou \
164	user_from_uid uid_from_user vasprintf vasnprintf vsnprintf)
165
166AC_CHECK_DECLS([user_from_uid, uid_from_user, pwcache_userdb],,,[
167#include <pwd.h>
168])
169AC_CHECK_DECLS([group_from_gid, gid_from_group, pwcache_groupdb],,,[
170#include <grp.h>
171])
172AC_CHECK_DECLS([strndup, strnlen],,,[#include <string.h>])
173AC_CHECK_DECLS([strsuftoll],,,[#include <stdlib.h>])
174AC_CHECK_DECLS([lchflags, lchmod, lchown],,,[
175#include <sys/stat.h>
176#include <unistd.h>
177])
178
179AC_CHECK_DECLS([errc, verrc, warnc, vwarnc],,, [
180#ifdef HAVE_ERR_H
181#include <err.h>
182#endif
183])
184
185AC_CHECK_DECLS([htobe16, htobe32, htobe64, htole16, htole32, htole64,
186		be16toh, be32toh, be64toh, le16toh, le32toh, le64toh],,,
187		[#include <sys/types.h>])
188
189AC_CHECK_DECLS([bswap16, bswap32, bswap64],,, [#include <machine/bswap.h>])
190
191AC_CHECK_DECLS([be16enc, le16enc, be16dec, le16dec, be32enc, le32enc,
192		be32dec, le32dec, be64enc, le64enc, be64dec, le64dec],,,
193		[#include <sys/endian.h>])
194
195AC_CHECK_DECLS([fstatvfs],,, [#include <sys/statvfs.h>])
196
197AC_CHECK_DECLS([setgroupent, setpassent],,, [
198#include <sys/types.h>
199#include <grp.h>
200#include <pwd.h>
201])
202
203# regcomp() and regexec() are also names of functions in the old V8
204# regexp package.  To avoid them, we need to find out who has regfree().
205
206dnl # Cygwin: We *MUST* look at -lregex *before* the "no libs" condition.
207dnl # Thus AC_CHECK_LIB(regex...) comes first, and AC_SEARCHLIBS next.
208AC_CHECK_LIB(regex, regfree)
209AC_SEARCH_LIBS(regfree, rx posix)
210
211AC_CHECK_LIB(rt, clock_gettime)
212
213AC_CHECK_FUNCS(fparseln, [
214    AC_MSG_CHECKING(if fparseln seems to work)
215    AC_RUN_IFELSE(
216        [AC_LANG_SOURCE([[
217#define _NETBSD_SOURCE
218#include <stdio.h>
219#include <stdlib.h>
220#define CONFTEST	"conftest.fparseln"
221#define COMMENT		'#'
222int
223main(void)
224{
225	static const char delim[3] = { '\0', '\0', COMMENT };
226	FILE *fp;
227	char *ptr;
228	fp = fopen(CONFTEST, "w+");
229	if (fp != NULL) {
230		unlink(CONFTEST);
231		ungetc(COMMENT, fp);
232		ptr = fparseln(fp, NULL, NULL, delim,
233		    FPARSELN_UNESCALL);
234		fclose(fp);
235		if (ptr == NULL)
236			exit(0);
237	}
238	exit(1);
239}
240        ]])],
241        [AC_MSG_RESULT(yes)],
242        [AC_MSG_RESULT(no)
243         AC_DEFINE(BROKEN_FPARSELN, 1,
244            [Define to 1 if your `fparseln' function is broken.])],
245        [AC_MSG_WARN([cross compiling: not checking farseln])]
246    )
247])
248
249# Variables substituted via @VARNAME@ in defs.mk.in
250AC_SUBST(HAVE_PTHREAD_H, $ac_cv_header_pthread_h)
251
252AC_OUTPUT
253