1# Test target to run Python test suite from main build.
2
3add_custom_target(check-clang-python
4    COMMAND ${CMAKE_COMMAND} -E env
5            CLANG_LIBRARY_PATH=$<TARGET_FILE_DIR:libclang>
6            "${Python3_EXECUTABLE}" -m unittest discover
7    DEPENDS libclang
8    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/..)
9
10set(RUN_PYTHON_TESTS TRUE)
11set_target_properties(check-clang-python PROPERTIES FOLDER "Clang tests")
12
13# Tests require libclang.so which is only built with LLVM_ENABLE_PIC=ON
14if(NOT LLVM_ENABLE_PIC)
15  set(RUN_PYTHON_TESTS FALSE)
16endif()
17
18# Do not try to run if libclang was built with ASan because
19# the sanitizer library will likely be loaded too late to perform
20# interception and will then fail.
21# We could use LD_PRELOAD/DYLD_INSERT_LIBRARIES but this isn't
22# portable so its easier just to not run the tests when building
23# with ASan.
24list(FIND LLVM_USE_SANITIZER "Address" LLVM_USE_ASAN_INDEX)
25if(NOT LLVM_USE_ASAN_INDEX EQUAL -1)
26  set(RUN_PYTHON_TESTS FALSE)
27endif()
28
29# Tests fail on Windows, and need someone knowledgeable to fix.
30# It's not clear whether it's a test or a valid binding problem.
31if(WIN32)
32  set(RUN_PYTHON_TESTS FALSE)
33endif()
34
35# The Python FFI interface is broken on AIX: https://bugs.python.org/issue38628.
36if(${CMAKE_SYSTEM_NAME} MATCHES "AIX")
37  set(RUN_PYTHON_TESTS FALSE)
38endif()
39
40# AArch64, Hexagon, and Sparc have known test failures that need to be
41# addressed.
42# SystemZ has broken Python/FFI interface:
43# https://reviews.llvm.org/D52840#1265716
44if(${LLVM_NATIVE_ARCH} MATCHES "^(AArch64|Hexagon|Sparc|SystemZ)$")
45  set(RUN_PYTHON_TESTS FALSE)
46endif()
47
48if(RUN_PYTHON_TESTS)
49    set_property(GLOBAL APPEND PROPERTY
50                 LLVM_ADDITIONAL_TEST_TARGETS check-clang-python)
51endif()
52