1#!/usr/bin/perl -w
2
3BEGIN {
4    unshift @INC, 't/lib';
5}
6chdir 't';
7
8use Test::More;
9use ExtUtils::MakeMaker;
10use File::Temp qw[tempfile];
11
12my $Has_Version = eval 'require version; "version"->import; 1';
13
14# "undef" - means we expect "undef", undef - eval should be never called for this string
15my %versions = (q[$VERSION = '1.00']            => '1.00',
16                q[*VERSION = \'1.01']           => '1.01',
17                q[($VERSION) = q$Revision: 32208 $ =~ /(\d+)/g;] => 32208,
18                q[$FOO::VERSION = '1.10';]      => '1.10',
19                q[*FOO::VERSION = \'1.11';]     => '1.11',
20                '$VERSION = 0.02'               => 0.02,
21                '$VERSION = 0.0'                => 0.0,
22                '$VERSION = -1.0'               => -1.0,
23                '$VERSION = undef'              => 'undef',
24                '$wibble  = 1.0'                => undef,
25                q[my $VERSION = '1.01']         => 'undef',
26                q[local $VERISON = '1.02']      => 'undef',
27                q[local $FOO::VERSION = '1.30'] => 'undef',
28                q[if( $Foo::VERSION >= 3.00 ) {]=> 'undef',
29                q[our $VERSION = '1.23';]       => '1.23',
30                q[$CGI::VERSION='3.63']         => '3.63',
31                q[$VERSION = "1.627"; # ==> ALSO update the version in the pod text below!] => '1.627',
32
33                '$Something::VERSION == 1.0'    => undef,
34                '$Something::VERSION <= 1.0'    => undef,
35                '$Something::VERSION >= 1.0'    => undef,
36                '$Something::VERSION != 1.0'    => undef,
37                'my $meta_coder = ($JSON::XS::VERSION >= 1.4) ?' => undef,
38
39                qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n]                     => '2.3',
40                qq[\$Something::VERSION == 1.0\n\$VERSION = 2.3\n\$VERSION = 4.5\n]    => '2.3',
41
42                '$VERSION = sprintf("%d.%03d", q$Revision: 3.74 $ =~ /(\d+)\.(\d+)/);' => '3.074',
43                '$VERSION = substr(q$Revision: 2.8 $, 10) + 2 . "";'                   => '4.8',
44                q[our $VERSION = do { my @r = ( q$Revision: 2.7 $ =~ /\d+/g ); sprintf "%d." . "%02d" x $#r, @r };] => '2.07', # Fucking seriously?
45                'elsif ( $Something::VERSION >= 1.99 )' => undef,
46
47               );
48
49if( $Has_Version ) {
50    $versions{q[use version; $VERSION = qv("1.2.3");]} = qv("1.2.3");
51    $versions{q[$VERSION = qv("1.2.3")]}               = qv("1.2.3");
52    $versions{q[$VERSION = v1.2.3]} = 'v1.2.3';
53}
54
55if( $] >= 5.011001 ) {
56    $versions{'package Foo 1.23;'         } = '1.23';
57    $versions{'package Foo::Bar 1.23;'    } = '1.23';
58    $versions{'package Foo v1.2.3;'       } = 'v1.2.3';
59    $versions{'package Foo::Bar v1.2.3;'  } = 'v1.2.3';
60    $versions{' package Foo::Bar 1.23 ;'  } = '1.23';
61    $versions{"package Foo'Bar 1.23;"     } = '1.23';
62    $versions{"package Foo::Bar 1.2.3;"   } = '1.2.3';
63    $versions{'package Foo 1.230;'        } = '1.230';
64    $versions{'package Foo 1.23_01;'      } = '1.23_01';
65    $versions{'package Foo v1.23_01;'     } = 'v1.23_01';
66    $versions{q["package Foo 1.23"]}        = 'undef';
67    $versions{<<'END'}                      = '1.23';
68package Foo 1.23;
69our $VERSION = 2.34;
70END
71
72    $versions{<<'END'}                      = '2.34';
73our $VERSION = 2.34;
74package Foo 1.23;
75END
76
77    $versions{<<'END'}                      = '2.34';
78package Foo::100;
79our $VERSION = 2.34;
80END
81}
82
83if ( $] > 5.009 && $] < 5.012 ) {
84  delete $versions{'$VERSION = -1.0'};
85}
86
87plan tests => (3 * keys %versions) + 4 + grep { !defined} (values %versions);
88
89for my $code ( sort keys %versions ) {
90    my $expect = $versions{$code};
91    (my $label = $code) =~ s/\n/\\n/g;
92    my $warnings = "";
93    local $SIG{__WARN__} = sub { $warnings .= "@_\n"; };
94	if (defined $expect) {
95		is( parse_version_string($code), $expect, $label );
96	} else {
97		my $is_called = 0;
98		no warnings qw[redefine once];
99		local *MM::get_version = sub {
100			$is_called = 1;
101		};
102		ok !$is_called;
103		is( parse_version_string($code), 'undef', $label );
104	}
105    is($warnings, '', "$label does not cause warnings");
106}
107
108
109sub parse_version_string {
110    my $code = shift;
111
112    my ($fh,$file) = tempfile( DIR => '.', UNLINK => 1 );
113    print $fh "$code\n";
114    close $fh;
115
116    $_ = 'foo';
117    my $version = MM->parse_version( $file );
118    is( $_, 'foo', '$_ not leaked by parse_version' );
119
120    return $version;
121}
122
123
124# This is a specific test to see if a version subroutine in the $VERSION
125# declaration confuses later calls to the version class.
126# [rt.cpan.org 30747]
127SKIP: {
128    skip "need version.pm", 4 unless $Has_Version;
129    is parse_version_string(q[ $VERSION = '1.00'; sub version { $VERSION } ]),
130       '1.00', "eval 'sub version {...} in version string";
131    is parse_version_string(q[ use version; $VERSION = version->new("1.2.3") ]),
132       qv("1.2.3"), "version.pm not confused by version sub";
133}
134