xref: /openbsd/gnu/usr.bin/perl/win32/config_h.PL (revision f6aab3d8) 
1#!perl -w
2use strict;
3
4BEGIN { warn "Running ".__FILE__."\n" };
5BEGIN
6 {
7  require "Config.pm";
8  die "Config.pm:$@" if $@;
9  Config->import;
10 }
11use File::Compare qw(compare);
12use File::Copy qw(copy);
13use File::Basename qw(fileparse);
14
15my ($name, $dir) = fileparse($0);
16$name =~ s#^(.*)\.PL$#../$1.SH#;
17my %opt;
18while (@ARGV && $ARGV[0] =~ /^([\w_]+)=(.*)$/)
19 {
20  $opt{$1}=$2;
21  shift(@ARGV);
22 }
23
24$opt{CONFIG_H} ||= 'config.h';
25$opt{CORE_DIR} ||= '../lib/CORE';
26
27warn "Writing $opt{CONFIG_H}\n";
28
29open(SH, "<", $name) || die "Cannot open $name:$!";
30while (<SH>)
31 {
32  last if /^\s*sed/;
33 }
34my($term,$file,$pat) = /^\s*sed\s+<<(\S+)\s+>(\S+)\s+(.*)$/;
35
36$file =~ s/^\$(\w+)$/$opt{$1}/g;
37
38my $str = "sub munge\n{\n";
39
40while ($pat =~ s/-e\s+'([^']*)'\s*//)
41 {
42  my $e = $1;
43  $e =~ s/\\([\(\)])/$1/g;
44  $e =~ s/\\(\d)/\$$1/g;
45  $str .= "$e;\n";
46 }
47$str .= "}\n";
48
49eval $str;
50
51die "$str:$@" if $@;
52
53open(H, ">", "$file.new") || die "Cannot open $file.new:$!";
54binmode(H);
55while (<SH>)
56 {
57  last if /^$term$/o;
58  s/\$([\w_]+)/Config($1)/eg;
59  s/`([^\`]*)`/BackTick($1)/eg;
60  munge();
61  s/\\\$/\$/g;
62  s#/[ *\*]*\*/#/**/#;
63  s#(.)/\*\*/#$1/ **/# if(/^\/\*/); #avoid "/*" inside comments
64  if (/^\s*#define\s+(PRIVLIB|SITELIB|VENDORLIB)_EXP/)
65   {
66     $_ = '#define '. $1 . '_EXP ('.(
67       $1 eq 'PRIVLIB' ? 'PerlEnv_lib_path' :
68       $1 eq 'SITELIB' ? 'PerlEnv_sitelib_path' :
69       $1 eq 'VENDORLIB' ? 'PerlEnv_vendorlib_path' :
70       die "unknown *LIB_EXP define \"$1\""
71       ). "(PERL_VERSION_STRING, NULL))\t/**/\n";
72   }
73  # incpush() handles archlibs, so disable them
74  elsif (/^\s*#define\s+(ARCHLIB|SITEARCH|VENDORARCH)_EXP/)
75   {
76     $_ = "/*#define ". $1 . "_EXP \"\"\t/ **/\n";
77   }
78  elsif (/^\s*#define\s+CPP(STDIN|RUN)\s+"gcc(.*)"\s*$/)
79   {
80     $_ = "#define CPP" . $1 . " \"" . $opt{ARCHPREFIX} . "gcc" . $2 . "\"\n";
81   }
82  print H;
83 }
84close(H);
85close(SH);
86
87my $core_config_h = "$opt{CORE_DIR}/$opt{CONFIG_H}";
88if (compare("$file.new", $core_config_h)) {
89    mkdir $opt{CORE_DIR} unless -d $opt{CORE_DIR};
90    chmod(0666,$core_config_h);
91    copy("$file.new",$core_config_h) || die "Cannot copy:$!";
92    chmod(0444,$core_config_h);
93}
94
95if (compare("$file.new",$file))
96 {
97  warn "$file has changed\n";
98  chmod(0666,$file);
99  unlink($file);
100  rename("$file.new",$file) || die "Cannot rename:$!";
101 }
102else
103 {
104  unlink ("$file.new");
105 }
106
107sub Config
108{
109 my $var = shift;
110 my $val = $Config{$var};
111 $val = 'undef' unless defined $val;
112 $val =~ s/\\/\\\\/g;
113 return $val;
114}
115
116sub BackTick
117{
118 my $cmd = shift;
119 if ($cmd =~ /^echo\s+(.*?)\s*\|\s+sed\s+'(.*)'\s*$/)
120  {
121   my($data,$pat) = ($1,$2);
122   $data =~ s/\s+/ /g;
123   eval "\$data =~ $pat";
124   return $data;
125  }
126 else
127  {
128   die "Cannot handle \`$cmd\`";
129  }
130 return $cmd;
131}
132