xref: /openbsd/sys/arch/amd64/conf/ld.script (revision fc61954a) 
1/*	$OpenBSD: ld.script,v 1.4 2016/09/03 13:13:07 deraadt Exp $	*/
2
3/*
4 * Copyright (c) 2009 Tobias Weingartner <weingart@tepid.org>
5 *
6 * Permission to use, copy, modify, and distribute this software for any
7 * purpose with or without fee is hereby granted, provided that the above
8 * copyright notice and this permission notice appear in all copies.
9 *
10 * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11 * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12 * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13 * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14 * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15 * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16 * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17 */
18
19OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
20OUTPUT_ARCH(i386:x86-64)
21
22/* Define how we want out ELF binary to look like. */
23PHDRS
24{
25	text PT_LOAD FILEHDR PHDRS;
26	rodata PT_LOAD;
27	data PT_LOAD;
28	bss PT_LOAD;
29	openbsd_randomize PT_OPENBSD_RANDOMIZE;
30}
31
32/*
33 * If we want the text/rodata/data sections aligned on 2M boundaries,
34 * we could use the following instead.  Note, file size would increase
35 * due to necessary padding.
36 *
37 *__ALIGN_SIZE = 0x200000;
38 */
39__ALIGN_SIZE = 0x1000;
40__kernel_base_virt = 0xffffffff81000000 + SIZEOF_HEADERS;
41__kernel_base_phys = __kernel_base_virt & 0x7fffffff;
42
43/* We use physical address to jump to kernel */
44start_phys = LOADADDR(.text) + (start - __kernel_base_virt);
45ENTRY(start_phys)
46SECTIONS
47{
48	__kernel_text_virt = __kernel_base_virt;
49	__kernel_text_phys = __kernel_base_phys;
50	.text (__kernel_text_virt) : AT (__kernel_text_phys)
51	{
52		__text_start = ABSOLUTE(.) & 0xfffffffffffff000;
53		__text_size = SIZEOF(.text);
54		__text_load = LOADADDR(.text);
55		locore.o(.text)
56		*(.text .text.*)
57	} :text
58	PROVIDE (__etext = .);
59	PROVIDE (etext = .);
60	_etext = .;
61
62	/* Move rodata to the next page, so we can nuke X and W bit on them */
63	. = ALIGN(__ALIGN_SIZE);
64	__kernel_rodata_virt = .;
65	__kernel_rodata_phys = . & 0x7fffffff;
66	.rodata (__kernel_rodata_virt) : AT (__kernel_rodata_phys)
67	{
68		__rodata_start = ABSOLUTE(.);
69		__rodata_size = SIZEOF(.rodata);
70		__rodata_load = LOADADDR(.rodata);
71		*(.rodata .rodata.*)
72		*(.codepatch)
73		*(.codepatchend)
74	} :rodata
75	. = ALIGN(0x1000);
76	__kernel_randomdata_phys = . & 0x7fffffff;
77	.openbsd.randomdata : AT (__kernel_randomdata_phys)
78	{
79		*(.openbsd.randomdata)
80	} :rodata :openbsd_randomize
81	. = ALIGN(0x1000);
82	PROVIDE (erodata = .);
83	_erodata = .;
84
85	/* Move data to the next page, so we can add W bit on them */
86	. = ALIGN(__ALIGN_SIZE);
87	__kernel_data_virt = .;
88	__kernel_data_phys = . & 0x7fffffff;
89	.data (__kernel_data_virt) : AT (__kernel_data_phys)
90	{
91		__data_start = ABSOLUTE(.);
92		__data_size = SIZEOF(.data);
93		__data_load = LOADADDR(.data);
94		*(.data .data.*)
95	} :data
96	. = ALIGN(0x1000);
97	PROVIDE (edata = .);
98	_edata = .;
99
100	/* BSS starts right after padded data */
101	__kernel_bss_virt = .;
102	__kernel_bss_phys = . & 0x7fffffff;
103	.bss (__kernel_bss_virt) : AT (__kernel_bss_phys)
104	{
105		__bss_start = ABSOLUTE(.);
106		__bss_size = SIZEOF(.bss);
107		__bss_load = LOADADDR(.bss);
108		*(.bss .bss.*)
109		*(COMMON)
110		/* Align after .bss to ensure correct alignment even if the
111		 * .bss section disappears because there are no input sections.
112		 */
113		. = ALIGN(0x1000);
114	} :bss
115	__kernel_bss_end = .;
116	. = ALIGN(0x200000);
117	_end = .;
118	PROVIDE (end = .);
119	__kernel_end_phys = . & 0x7fffffff;
120
121	/* XXX - hack alert, since we are not C++, nuke these */
122	/DISCARD/ :
123	{
124		*(.note.GNU-stack)
125		*(.eh_frame)
126	}
127}
128