xref: /openbsd/sys/arch/hppa/conf/ld.script (revision 771fbea0) 
1/* 	$OpenBSD: ld.script,v 1.19 2017/06/21 23:21:35 deraadt Exp $	*/
2
3/*
4 * Copyright (c) 2003 Michael Shalayeff
5 * All rights reserved.
6 *
7 * Redistribution and use in source and binary forms, with or without
8 * modification, are permitted provided that the following conditions
9 * are met:
10 * 1. Redistributions of source code must retain the above copyright
11 *    notice, this list of conditions and the following disclaimer.
12 * 2. Redistributions in binary form must reproduce the above copyright
13 *    notice, this list of conditions and the following disclaimer in the
14 *    documentation and/or other materials provided with the distribution.
15 *
16 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
17 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
18 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
19 * IN NO EVENT SHALL THE AUTHOR OR HIS RELATIVES BE LIABLE FOR ANY DIRECT,
20 * INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
21 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
22 * SERVICES; LOSS OF MIND, USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
23 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
24 * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
25 * IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
26 * THE POSSIBILITY OF SUCH DAMAGE.
27 */
28
29
30OUTPUT_FORMAT("elf32-hppa")
31OUTPUT_ARCH(hppa)
32ENTRY($start)
33SECTIONS
34{
35	. = + SIZEOF_HEADERS;
36	.text :
37	{
38		kernel_text = . ;
39		*(.text) *(.text.*)
40		*(.reginfo)
41		*(.init)
42		*(.stub)
43		/* .gnu.warning sections are handled specially by elf32.em.  */
44		*(.gnu.warning)
45		. = ALIGN(4096);
46		etext = ABSOLUTE(.);
47	} =0x00000000
48
49	. = 0x600000;
50
51	.rodata :
52	{
53		__rodata_start = .;
54		*(.rodata) *(.rodata1)
55		. = ALIGN(8);
56		__unwind_start = .;
57		*(.PARISC.unwind)
58		__unwind_end = .;
59		. = ALIGN(4096);
60		__rodata_end = .;
61	} =0x00000000
62	__data_start = ABSOLUTE(.);
63
64	.data  :
65	{
66		$global$ = . ;
67		. += 4;
68		*(.data)
69		CONSTRUCTORS
70		. = ALIGN(4096);
71		edata = ABSOLUTE(.);
72	} =0x00000000
73	.ctors	: { *(.ctors) }
74	.dtors	: { *(.dtors) }
75
76	__bss_start = .;
77	/* .sbss	: { *(.sbss) *(.scommon) } */
78	.bss :
79	{
80		*(.dynbss) *(.bss)
81		*(COMMON) *($COMMON$)
82		. = ALIGN(4096);
83	}
84	end = ABSOLUTE(.);
85}
86