1# ex:ts=8 sw=4:
2# $OpenBSD: AddCreateDelete.pm,v 1.25 2014/06/03 13:13:53 espie Exp $
3#
4# Copyright (c) 2007-2014 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17#
18
19use strict;
20use warnings;
21
22# common framework, let's place most everything in there
23
24package OpenBSD::AddCreateDelete::State;
25our @ISA = qw(OpenBSD::State);
26
27use OpenBSD::State;
28use OpenBSD::ProgressMeter;
29
30sub init
31{
32	my $self = shift;
33
34	$self->{progressmeter} = OpenBSD::ProgressMeter->new;
35	$self->{bad} = 0;
36	$self->SUPER::init(@_);
37	$self->{export_level}++;
38}
39
40sub progress
41{
42	my $self = shift;
43	return $self->{progressmeter};
44}
45
46sub not
47{
48	my $self = shift;
49	return $self->{not};
50}
51
52sub _print
53{
54	my $self = shift;
55	$self->progress->print(@_);
56}
57
58sub _errprint
59{
60	my $self = shift;
61	$self->progress->errprint(@_);
62}
63
64sub handle_options
65{
66	my ($state, $opt_string, @usage) = @_;
67
68	$state->SUPER::handle_options($opt_string.'L:mnx', @usage);
69
70	$state->progress->setup($state->opt('x'), $state->opt('m'), $state);
71	$state->{not} = $state->opt('n');
72}
73
74sub vsystem
75{
76	my $self = shift;
77	if ($self->verbose < 2) {
78		$self->system(@_);
79	} else {
80		$self->verbose_system(@_);
81	}
82}
83
84sub system
85{
86	my $self = shift;
87	$self->progress->clear;
88	$self->SUPER::system(@_);
89}
90
91sub run_makewhatis
92{
93	my ($state, $opts, $l) = @_;
94	my $braindead = sub { chdir('/'); };
95	while (@$l > 1000) {
96		my @b = splice(@$l, 0, 1000);
97		$state->vsystem($braindead,
98		    OpenBSD::Paths->makewhatis, @$opts, '--', @b);
99	}
100	$state->vsystem($braindead,
101	    OpenBSD::Paths->makewhatis, @$opts, '--', @$l);
102}
103
104sub ntogo
105{
106	my ($self, $offset) = @_;
107
108	return $self->{wantntogo} ?
109	    $self->progress->ntogo($self, $offset) :
110	    $self->f("ok");
111}
112
113sub ntogo_string
114{
115	my ($self, $offset) = @_;
116
117	return $self->todo($offset // 0);
118}
119
120OpenBSD::Auto::cache(signer_list,
121	sub {
122		my $self = shift;
123		if ($self->defines('SIGNER')) {
124			return [split /,/, $self->{subst}->value('SIGNER')];
125		} else {
126			if ($self->defines('FW_UPDATE')) {
127				return [qr{^.*fw$}];
128			} else {
129				return [qr{^.*pkg$}];
130			}
131		}
132	});
133
134package OpenBSD::AddCreateDelete;
135use OpenBSD::Error;
136
137sub handle_options
138{
139	my ($self, $opt_string, $state, @usage) = @_;
140	$state->handle_options($opt_string, $self, @usage);
141}
142
1431;
144