1# ex:ts=8 sw=4:
2# $OpenBSD: PackageLocator.pm,v 1.104 2016/01/27 20:49:45 sthen Exp $
3#
4# Copyright (c) 2003-2010 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17
18use strict;
19use warnings;
20
21package OpenBSD::PackageLocator;
22
23use OpenBSD::PackageRepositoryList;
24use OpenBSD::PackageRepository;
25
26my $default_path;
27
28sub build_default_path
29{
30	my ($self, $state) = @_;
31	$default_path = OpenBSD::PackageRepositoryList->new($state);
32
33	if (defined $ENV{PKG_PATH}) {
34		my $v = $ENV{PKG_PATH};
35		$v =~ s/^\:+//o;
36		$v =~ s/\:+$//o;
37		while (my $o = OpenBSD::PackageRepository->parse(\$v, $state)) {
38			$default_path->add($o);
39		}
40		return;
41	}
42	$default_path->add(OpenBSD::PackageRepository->new("./", $state)->can_be_empty);
43	return if $state->defines('NOINSTALLPATH');
44
45	return unless defined $state->config->value('installpath');
46	for my $i ($state->config->value("installpath")) {
47	    	$i =~ s/(^[a-z0-9][a-z0-9.]+\.[a-z0-9.]+$)/http:\/\/$1\/%m/;
48		$default_path->add(OpenBSD::PackageRepository->new($i, $state));
49	}
50}
51
52sub default_path
53{
54	if (!defined $default_path) {
55		&build_default_path;
56	}
57	return $default_path;
58}
59
60sub path_parse
61{
62	my ($self, $pkgname, $state, $path) = (@_, './');
63	if ($pkgname =~ m/^(.*[\/\:])(.*)/) {
64		($pkgname, $path) = ($2, $1);
65	}
66
67	return (OpenBSD::PackageRepository->new($path, $state), $pkgname);
68}
69
70sub find
71{
72	my ($self, $url, $state) = @_;
73
74	my $package;
75	if ($url =~ m/[\/\:]/o) {
76		my ($repository, $pkgname) = $self->path_parse($url, $state);
77		$package = $repository->find($pkgname);
78		if (defined $package) {
79			$self->default_path($state)->add($repository);
80		}
81	} else {
82		$package = $self->default_path($state)->find($url);
83	}
84	return $package;
85}
86
87sub grabPlist
88{
89	my ($self, $url, $code, $state) = @_;
90
91	my $plist;
92	if ($url =~ m/[\/\:]/o) {
93		my ($repository, $pkgname) = $self->path_parse($url, $state);
94		$plist = $repository->grabPlist($pkgname, $code);
95		if (defined $plist) {
96			$self->default_path($state)->add($repository);
97		}
98	} else {
99		$plist = $self->default_path($state)->grabPlist($url, $code);
100	}
101	return $plist;
102}
103
104sub match_locations
105{
106	my ($self, @search) = @_;
107	my $state = pop @search;
108	return $self->default_path($state)->match_locations(@search);
109}
110
1111;
112