1# ex:ts=8 sw=4:
2# $OpenBSD: PackageLocator.pm,v 1.98 2010/12/24 09:04:14 espie Exp $
3#
4# Copyright (c) 2003-2010 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17
18use strict;
19use warnings;
20
21package OpenBSD::PackageLocator;
22
23use OpenBSD::PackageRepositoryList;
24use OpenBSD::PackageRepository;
25
26my $default_path;
27
28sub build_default_path
29{
30	my ($self, $state) = @_;
31	$default_path = OpenBSD::PackageRepositoryList->new($state);
32
33	if (defined $ENV{PKG_PATH}) {
34		my $v = $ENV{PKG_PATH};
35		$v =~ s/^\:+//o;
36		$v =~ s/\:+$//o;
37		while (my $o = OpenBSD::PackageRepository->parse(\$v, $state)) {
38			$default_path->add($o);
39		}
40		return;
41	}
42	$default_path->add(OpenBSD::PackageRepository->new("./", $state)->can_be_empty);
43	if (my $i = $state->config->value("installpath")) {
44		$default_path->add(OpenBSD::PackageRepository->new($i, $state));
45	}
46}
47
48sub default_path
49{
50	if (!defined $default_path) {
51		&build_default_path;
52	}
53	return $default_path;
54}
55
56sub path_parse
57{
58	my ($self, $pkgname, $state, $path) = (@_, './');
59	if ($pkgname =~ m/^(.*[\/\:])(.*)/) {
60		($pkgname, $path) = ($2, $1);
61	}
62
63	return (OpenBSD::PackageRepository->new($path, $state), $pkgname);
64}
65
66sub find
67{
68	my ($self, $_, $arch, $state) = @_;
69
70	my $package;
71	if (m/[\/\:]/o) {
72		my ($repository, $pkgname) = $self->path_parse($_, $state);
73		$package = $repository->find($pkgname, $arch);
74		if (defined $package) {
75			$self->default_path($state)->add($repository);
76		}
77	} else {
78		$package = $self->default_path($state)->find($_, $arch);
79	}
80	return $package;
81}
82
83sub grabPlist
84{
85	my ($self, $_, $arch, $code, $state) = @_;
86
87	my $plist;
88	if (m/[\/\:]/o) {
89		my ($repository, $pkgname) = $self->path_parse($_, $state);
90		$plist = $repository->grabPlist($pkgname, $arch, $code);
91		if (defined $plist) {
92			$self->default_path($state)->add($repository);
93		}
94	} else {
95		$plist = $self->default_path($state)->grabPlist($_, $arch, $code);
96	}
97	return $plist;
98}
99
100sub match_locations
101{
102	my ($self, @search) = @_;
103	my $state = pop @search;
104	return $self->default_path($state)->match_locations(@search);
105}
106
1071;
108