1# ex:ts=8 sw=4:
2# $OpenBSD: SharedItems.pm,v 1.28 2010/08/03 14:10:12 espie Exp $
3#
4# Copyright (c) 2004-2006 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17
18use strict;
19use warnings;
20
21package OpenBSD::SharedItems;
22
23use OpenBSD::Error;
24use OpenBSD::PackageInfo;
25use OpenBSD::PackingList;
26use OpenBSD::Paths;
27
28sub find_items_in_installed_packages
29{
30	my $state = shift;
31	my $db = OpenBSD::SharedItemsRecorder->new;
32	$state->status->what("Read")->object("shared items");
33	$state->progress->for_list("Read shared items", [installed_packages()],
34	    sub {
35		my $e = shift;
36		my $plist = OpenBSD::PackingList->from_installation($e,
37		    \&OpenBSD::PackingList::SharedItemsOnly) or return;
38		return if !defined $plist;
39		$plist->record_shared($db, $e);
40	    });
41	return $db;
42}
43
44sub check_shared
45{
46	my ($set, $o) = @_;
47	if (!defined $set->{db}) {
48		$set->{db} = OpenBSD::SharedItemsRecorder->new;
49		for my $pkg (installed_packages()) {
50			next if $set->{older}{$pkg};
51			my $plist = OpenBSD::PackingList->from_installation($pkg,
52			    \&OpenBSD::PackingList::SharedItemsOnly) or next;
53			next if !defined $plist;
54			$plist->record_shared($set->{db}, $pkg);
55		}
56	}
57	if (defined $set->{db}{dirs}{$o->fullname}) {
58		return 1;
59	} else {
60		push(@{$set->{old_shared}{$o->fullname}}, $o);
61		return 0;
62	}
63}
64
65sub wipe_directory
66{
67	my ($state, $h, $d) = @_;
68
69	my $realname = $state->{destdir}.$d;
70
71	for my $i (@{$h->{$d}}) {
72		$state->log->set_context('-'.$i->{pkgname});
73		$i->cleanup($state);
74	}
75	if (!rmdir $realname) {
76		$state->log("Error deleting directory #1: #2",
77		    $realname, $!)
78			unless $state->{dirs_okay}->{$d};
79		return 0;
80	}
81	return 1;
82}
83
84sub cleanup
85{
86	my ($recorder, $state) = @_;
87
88	my $remaining = find_items_in_installed_packages($state);
89
90	$state->progress->clear;
91	$state->status->what("Clean");
92	$state->progress->set_header("Clean shared items");
93	my $h = $recorder->{dirs};
94	my $u = $recorder->{users};
95	my $g = $recorder->{groups};
96	my $total = 0;
97	$total += keys %$h if defined $h;
98	$total += keys %$u if defined $u;
99	$total += keys %$g if defined $g;
100	my $done = 0;
101
102	for my $d (sort {$b cmp $a} keys %$h) {
103		$state->progress->show($done, $total);
104		my $realname = $state->{destdir}.$d;
105		if ($remaining->{dirs}->{$realname}) {
106			for my $i (@{$h->{$d}}) {
107				$state->log->set_context('-'.$i->{pkgname});
108				$i->reload($state);
109			}
110		} else {
111			wipe_directory($state, $h, $d);
112		}
113		$done++;
114	}
115	while (my ($user, $pkgname) = each %$u) {
116		$state->progress->show($done, $total);
117		next if $remaining->{users}->{$user};
118		if ($state->{extra}) {
119			$state->system(OpenBSD::Paths->userdel, '--',
120			    $user);
121		} else {
122			$state->log->set_context('-'.$pkgname);
123			$state->log("You should also run /usr/sbin/userdel #1", $user);
124		}
125		$done++;
126	}
127	while (my ($group, $pkgname) = each %$g) {
128		$state->progress->show($done, $total);
129		next if $remaining->{groups}->{$group};
130		if ($state->{extra}) {
131			$state->system(OpenBSD::Paths->groupdel, '--',
132			    $group);
133		} else {
134			$state->log->set_context('-'.$pkgname);
135			$state->log("You should also run /usr/sbin/groupdel #1", $group);
136		}
137		$done++;
138	}
139	if ($state->verbose >= 2) {
140		$state->progress->next;
141	} else {
142		$state->progress->clear;
143	}
144}
145
146package OpenBSD::PackingElement;
147sub cleanup
148{
149}
150
151sub reload
152{
153}
154
155package OpenBSD::PackingElement::Mandir;
156sub cleanup
157{
158	my ($self, $state) = @_;
159	my $fullname = $state->{destdir}.$self->fullname;
160	$state->log("You may wish to remove #1 from man.conf", $fullname);
161	for my $f (OpenBSD::Paths->man_cruft) {
162		unlink("$fullname/$f");
163	}
164}
165
166package OpenBSD::PackingElement::Fontdir;
167sub cleanup
168{
169	my ($self, $state) = @_;
170	my $fullname = $state->{destdir}.$self->fullname;
171	$state->log("You may wish to remove #1 from your font path", $fullname);
172	for my $f (OpenBSD::Paths->font_cruft) {
173		unlink("$fullname/$f");
174	}
175}
176
177package OpenBSD::PackingElement::Infodir;
178sub cleanup
179{
180	my ($self, $state) = @_;
181	my $fullname = $state->{destdir}.$self->fullname;
182	for my $f (OpenBSD::Paths->info_cruft) {
183		unlink("$fullname/$f");
184	}
185}
186
1871;
188