1# ex:ts=8 sw=4:
2# $OpenBSD: SharedLibs.pm,v 1.57 2010/12/24 10:31:59 espie Exp $
3#
4# Copyright (c) 2003-2010 Marc Espie <espie@openbsd.org>
5#
6# Permission to use, copy, modify, and distribute this software for any
7# purpose with or without fee is hereby granted, provided that the above
8# copyright notice and this permission notice appear in all copies.
9#
10# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
11# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
12# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
13# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
14# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
15# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
16# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
17
18use strict;
19use warnings;
20
21use OpenBSD::Paths;
22use OpenBSD::LibSpec;
23
24package OpenBSD::PackingElement;
25
26sub mark_available_lib
27{
28}
29
30package OpenBSD::PackingElement::Lib;
31
32sub mark_available_lib
33{
34	my ($self, $pkgname, $state) = @_;
35	OpenBSD::SharedLibs::register_libname($self->fullname,
36	    $pkgname, $state);
37}
38
39package OpenBSD::SharedLibs;
40use File::Basename;
41use OpenBSD::Error;
42
43our $repo = OpenBSD::LibRepo->new;
44
45sub register_library
46{
47	my ($lib, $pkgname) = @_;
48	$repo->register($lib, $pkgname);
49}
50
51sub register_libname
52{
53	my ($name, $pkgname, $state) = @_;
54	my $lib = OpenBSD::Library->from_string($name);
55	if ($lib->is_valid) {
56		register_library($lib, $pkgname);
57	} else {
58		$state->errsay("Bogus library in #1: #2", $pkgname, $name)
59		    unless $pkgname eq 'system';
60	}
61
62}
63
64my $done_plist = {};
65
66sub system_dirs
67{
68	return OpenBSD::Paths->library_dirs;
69}
70
71sub add_libs_from_system
72{
73	my ($destdir, $state) = @_;
74	return if $done_plist->{'system'};
75	$done_plist->{'system'} = 1;
76	for my $dirname (system_dirs()) {
77		opendir(my $dir, $destdir.$dirname."/lib") or next;
78		while (my $d = readdir($dir)) {
79			next unless $d =~ m/\.so/;
80			register_libname("$dirname/lib/$d", 'system', $state);
81		}
82		closedir($dir);
83	}
84}
85
86sub add_libs_from_installed_package
87{
88	my ($pkgname, $state) = @_;
89	return if $done_plist->{$pkgname};
90	$done_plist->{$pkgname} = 1;
91	my $plist = OpenBSD::PackingList->from_installation($pkgname,
92	    \&OpenBSD::PackingList::LibraryOnly);
93	return if !defined $plist;
94
95	$plist->mark_available_lib($pkgname, $state);
96}
97
98sub add_libs_from_plist
99{
100	my ($plist, $state) = @_;
101	my $pkgname = $plist->pkgname;
102	return if $done_plist->{$pkgname};
103	$done_plist->{$pkgname} = 1;
104	$plist->mark_available_lib($pkgname, $state);
105}
106
107sub lookup_libspec
108{
109	my ($base, $spec) = @_;
110	return $spec->lookup($repo, $base);
111}
112
113my $printed = {};
114
115sub report_problem
116{
117	my ($state, $spec) = @_;
118	my $name = $spec->to_string;
119	my $base = $state->{localbase};
120	my $approx = $spec->lookup_stem($repo);
121
122	my $r = "";
123	if (!$spec->is_valid) {
124		$r = "| bad library specification\n";
125	} elsif (!defined $approx) {
126 		$r = "| not found anywhere\n";
127	} else {
128		for my $bad (@$approx) {
129			my $ouch = $spec->no_match($bad, $base);
130			$ouch //= "not reachable";
131			$r .= "| ".$bad->to_string." (".$bad->origin."): ".
132			    $ouch."\n";
133		}
134	}
135	if (!defined $printed->{$name} || $printed->{$name} ne $r) {
136		$printed->{$name} = $r;
137		$state->errsay("|library #1 not found", $name);
138		$state->print("#1", $r);
139	}
140}
141
1421;
143