xref: /reactos/sdk/cmake/msvc.cmake (revision 0f92924a) 
1
2#if(${CMAKE_BUILD_TYPE} STREQUAL "Debug")
3if(CMAKE_BUILD_TYPE STREQUAL "Debug")
4    # no optimization
5    add_compile_flags("/Ob0 /Od")
6elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
7    add_compile_flags("/Ox /Ob2 /Ot /Oy /GT")
8    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /OPT:REF /OPT:ICF")
9elseif(OPTIMIZE STREQUAL "1")
10    add_compile_flags("/O1")
11elseif(OPTIMIZE STREQUAL "2")
12    add_compile_flags("/O2")
13elseif(OPTIMIZE STREQUAL "3")
14    add_compile_flags("/Ot /Ox /GS-")
15elseif(OPTIMIZE STREQUAL "4")
16    add_compile_flags("/Os /Ox /GS-")
17elseif(OPTIMIZE STREQUAL "5")
18    add_compile_flags("/Gy /Ob2 /Os /Ox /GS-")
19endif()
20
21# Always use string pooling: this helps reducing the binaries size since a lot
22# of redundancy come from the usage of __FILE__ / __RELFILE__ in the debugging
23# helper macros. Note also that GCC builds use string pooling by default.
24add_compile_flags("/GF")
25
26# Enable function level linking and comdat folding
27add_compile_flags("/Gy")
28set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /OPT:REF /OPT:ICF")
29set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} /OPT:REF /OPT:ICF")
30set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /OPT:REF /OPT:ICF")
31
32if(ARCH STREQUAL "i386")
33    add_definitions(/DWIN32 /D_WINDOWS)
34endif()
35
36add_definitions(/Dinline=__inline /D__STDC__=1)
37
38# Ignore any "standard" include paths, and do not use any default CRT library.
39if(NOT USE_CLANG_CL)
40    add_compile_flags("/X /Zl")
41endif()
42
43# Disable RTTI, exception handling and buffer security checks by default.
44# These require run-time support that may not always be available.
45add_compile_flags("/GR- /EHs-c- /GS-")
46
47if(USE_CLANG_CL)
48    set(CMAKE_CL_SHOWINCLUDES_PREFIX "Note: including file: ")
49endif()
50
51# HACK: for VS 11+ we need to explicitly disable SSE, which is off by
52# default for older compilers. See CORE-6507
53if(MSVC_VERSION GREATER 1699 AND ARCH STREQUAL "i386")
54    add_compile_flags("/arch:IA32")
55endif ()
56
57# VS 12+ requires /FS when used in parallel compilations
58if(MSVC_VERSION GREATER 1799 AND NOT MSVC_IDE)
59    add_compile_flags("/FS")
60endif ()
61
62# VS14+ tries to use thread-safe initialization
63if(MSVC_VERSION GREATER 1899)
64    add_compile_flags("/Zc:threadSafeInit-")
65endif ()
66
67# Generate Warnings Level 3
68add_compile_flags("/W3")
69
70# Disable overly sensitive warnings as well as those that generally aren't
71# useful to us.
72# - C4244: implicit integer truncation
73# - C4290: C++ exception specification ignored
74# - C4800: forcing value to bool 'true' or 'false' (performance warning)
75# - C4200: nonstandard extension used : zero-sized array in struct/union
76# - C4214: nonstandard extension used : bit field types other than int
77add_compile_flags("/wd4244 /wd4290 /wd4800 /wd4200 /wd4214")
78
79# FIXME: Temporarily disable C4018 until we fix more of the others. CORE-10113
80add_compile_flags("/wd4018")
81
82# The following warnings are treated as errors:
83# - C4013: implicit function declaration
84# - C4020: too many actual parameters
85# - C4022: pointer type mismatch for parameter
86# - C4028: formal parameter different from declaration
87# - C4047: different level of indirection
88# - TODO: C4090: different 'modifier' qualifiers (for C programs only;
89#          for C++ programs, the compiler error C2440 is issued)
90# - C4098: void function returning a value
91# - C4113: parameter lists differ
92# - C4129: unrecognized escape sequence
93# - C4133: incompatible types - from '<x> *' to '<y> *'
94# - C4163: 'identifier': not available as an intrinsic function
95# - C4229: modifiers on data are ignored
96# - C4311: pointer truncation from '<pointer>' to '<integer>'
97# - C4312: conversion from '<integer>' to '<pointer>' of greater size
98# - C4603: macro is not defined or definition is different after precompiled header use
99# - C4700: uninitialized variable usage
100# - C4715: 'function': not all control paths return a value
101# - C4716: function must return a value
102add_compile_flags("/we4013 /we4020 /we4022 /we4028 /we4047 /we4098 /we4113 /we4129 /we4133 /we4163 /we4229 /we4311 /we4312 /we4603 /we4700 /we4715 /we4716")
103
104# - C4189: local variable initialized but not referenced
105# Not in Release mode and not with MSVC 2010
106if((NOT CMAKE_BUILD_TYPE STREQUAL "Release") AND (NOT MSVC_VERSION LESS 1700))
107    add_compile_flags("/we4189")
108endif()
109
110# Enable warnings above the default level, but don't treat them as errors:
111# - C4115: named type definition in parentheses
112add_compile_flags("/w14115")
113
114if(USE_CLANG_CL)
115    add_compile_flags_language("-nostdinc -Wno-multichar -Wno-char-subscripts -Wno-microsoft-enum-forward-reference -Wno-pragma-pack -Wno-microsoft-anon-tag -Wno-parentheses-equality -Wno-unknown-pragmas" "C")
116    add_compile_flags_language("-nostdinc -Wno-multichar -Wno-char-subscripts -Wno-microsoft-enum-forward-reference -Wno-pragma-pack -Wno-microsoft-anon-tag -Wno-parentheses-equality -Wno-unknown-pragmas" "CXX")
117endif()
118
119# Debugging
120#if(${CMAKE_BUILD_TYPE} STREQUAL "Debug")
121if(CMAKE_BUILD_TYPE STREQUAL "Debug")
122    if(NOT (_PREFAST_ OR _VS_ANALYZE_))
123        add_compile_flags("/Zi")
124    endif()
125#elseif(${CMAKE_BUILD_TYPE} STREQUAL "Release")
126elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
127    add_definitions("/D NDEBUG")
128endif()
129
130# Hotpatchable images
131if(ARCH STREQUAL "i386")
132    if(NOT USE_CLANG_CL)
133        add_compile_flags("/hotpatch")
134    endif()
135    set(_hotpatch_link_flag "/FUNCTIONPADMIN:5")
136elseif(ARCH STREQUAL "amd64")
137    set(_hotpatch_link_flag "/FUNCTIONPADMIN:6")
138endif()
139
140if(MSVC_IDE AND (NOT DEFINED USE_FOLDER_STRUCTURE))
141    set(USE_FOLDER_STRUCTURE TRUE)
142endif()
143
144if(NOT DEFINED RUNTIME_CHECKS)
145    set(RUNTIME_CHECKS FALSE)
146endif()
147
148if(RUNTIME_CHECKS)
149    add_definitions(-D__RUNTIME_CHECKS__)
150    add_compile_flags("/RTC1")
151endif()
152
153set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /MANIFEST:NO /INCREMENTAL:NO /SAFESEH:NO /NODEFAULTLIB /RELEASE ${_hotpatch_link_flag} /IGNORE:4039")
154set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /MANIFEST:NO /INCREMENTAL:NO /SAFESEH:NO /NODEFAULTLIB /RELEASE ${_hotpatch_link_flag} /IGNORE:4104 /IGNORE:4039")
155set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} /MANIFEST:NO /INCREMENTAL:NO /SAFESEH:NO /NODEFAULTLIB /RELEASE ${_hotpatch_link_flag} /IGNORE:4039")
156
157# HACK: Remove the /implib argument, implibs are generated separately
158string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
159string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
160string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_C_CREATE_SHARED_LIBRARY "${CMAKE_C_CREATE_SHARED_LIBRARY}")
161string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_CXX_CREATE_SHARED_LIBRARY "${CMAKE_CXX_CREATE_SHARED_LIBRARY}")
162string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_C_CREATE_SHARED_MODULE "${CMAKE_C_CREATE_SHARED_MODULE}")
163string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_CXX_CREATE_SHARED_MODULE "${CMAKE_CXX_CREATE_SHARED_MODULE}")
164
165if(CMAKE_DISABLE_NINJA_DEPSLOG)
166    set(cl_includes_flag "")
167else()
168    set(cl_includes_flag "/showIncludes")
169endif()
170
171if(MSVC_IDE AND (CMAKE_VERSION MATCHES "ReactOS"))
172    # For VS builds we'll only have en-US in resource files
173    add_definitions(/DLANGUAGE_EN_US)
174else()
175    if(CMAKE_VERSION VERSION_LESS 3.4.0)
176        set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_RC_COMPILER> /nologo <FLAGS> <DEFINES> ${I18N_DEFS} /fo<OBJECT> <SOURCE>")
177        if(ARCH STREQUAL "arm")
178            set(CMAKE_ASM_COMPILE_OBJECT
179                "cl ${cl_includes_flag} /nologo /X /I${REACTOS_SOURCE_DIR}/sdk/include/asm /I${REACTOS_BINARY_DIR}/sdk/include/asm <FLAGS> <DEFINES> /D__ASM__ /D_USE_ML /EP /c <SOURCE> > <OBJECT>.tmp"
180                "<CMAKE_ASM_COMPILER> -nologo -o <OBJECT> <OBJECT>.tmp")
181        else()
182            set(CMAKE_ASM_COMPILE_OBJECT
183                "cl ${cl_includes_flag} /nologo /X /I${REACTOS_SOURCE_DIR}/sdk/include/asm /I${REACTOS_BINARY_DIR}/sdk/include/asm <FLAGS> <DEFINES> /D__ASM__ /D_USE_ML /EP /c <SOURCE> > <OBJECT>.tmp"
184                "<CMAKE_ASM_COMPILER> /nologo /Cp /Fo<OBJECT> /c /Ta <OBJECT>.tmp")
185        endif()
186    else()
187        set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_RC_COMPILER> /nologo <INCLUDES> <FLAGS> <DEFINES> ${I18N_DEFS} /fo<OBJECT> <SOURCE>")
188        if(ARCH STREQUAL "arm")
189            set(CMAKE_ASM_COMPILE_OBJECT
190                "cl ${cl_includes_flag} /nologo /X /I${REACTOS_SOURCE_DIR}/sdk/include/asm /I${REACTOS_BINARY_DIR}/sdk/include/asm <INCLUDES> <FLAGS> <DEFINES> /D__ASM__ /D_USE_ML /EP /c <SOURCE> > <OBJECT>.tmp"
191                "<CMAKE_ASM_COMPILER> -nologo -o <OBJECT> <OBJECT>.tmp")
192        else()
193            set(CMAKE_ASM_COMPILE_OBJECT
194                "cl ${cl_includes_flag} /nologo /X /I${REACTOS_SOURCE_DIR}/sdk/include/asm /I${REACTOS_BINARY_DIR}/sdk/include/asm <INCLUDES> <FLAGS> <DEFINES> /D__ASM__ /D_USE_ML /EP /c <SOURCE> > <OBJECT>.tmp"
195                "<CMAKE_ASM_COMPILER> /nologo /Cp /Fo<OBJECT> /c /Ta <OBJECT>.tmp")
196        endif()
197    endif()
198endif()
199
200if(_VS_ANALYZE_)
201    message("VS static analysis enabled!")
202    add_compile_flags("/analyze")
203elseif(_PREFAST_)
204    message("PREFAST enabled!")
205    if(CMAKE_VERSION VERSION_LESS 3.4.0)
206        set(CMAKE_C_COMPILE_OBJECT "prefast <CMAKE_C_COMPILER> ${CMAKE_START_TEMP_FILE} ${CMAKE_CL_NOLOGO} <FLAGS> <DEFINES> /Fo<OBJECT> -c <SOURCE>${CMAKE_END_TEMP_FILE}"
207        "prefast LIST")
208        set(CMAKE_CXX_COMPILE_OBJECT "prefast <CMAKE_CXX_COMPILER> ${CMAKE_START_TEMP_FILE} ${CMAKE_CL_NOLOGO} <FLAGS> <DEFINES> /TP /Fo<OBJECT> -c <SOURCE>${CMAKE_END_TEMP_FILE}"
209        "prefast LIST")
210        set(CMAKE_C_LINK_EXECUTABLE
211        "<CMAKE_C_COMPILER> ${CMAKE_CL_NOLOGO} <OBJECTS> ${CMAKE_START_TEMP_FILE} <FLAGS> /Fe<TARGET> -link /implib:<TARGET_IMPLIB> /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES>${CMAKE_END_TEMP_FILE}")
212        set(CMAKE_CXX_LINK_EXECUTABLE
213        "<CMAKE_CXX_COMPILER> ${CMAKE_CL_NOLOGO} <OBJECTS> ${CMAKE_START_TEMP_FILE} <FLAGS> /Fe<TARGET> -link /implib:<TARGET_IMPLIB> /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES>${CMAKE_END_TEMP_FILE}")
214    else()
215        set(CMAKE_C_COMPILE_OBJECT "prefast <CMAKE_C_COMPILER> ${CMAKE_START_TEMP_FILE} ${CMAKE_CL_NOLOGO} <INCLUDES> <FLAGS> <DEFINES> /Fo<OBJECT> -c <SOURCE>${CMAKE_END_TEMP_FILE}"
216        "prefast LIST")
217        set(CMAKE_CXX_COMPILE_OBJECT "prefast <CMAKE_CXX_COMPILER> ${CMAKE_START_TEMP_FILE} ${CMAKE_CL_NOLOGO} <INCLUDES> <FLAGS> <DEFINES> /TP /Fo<OBJECT> -c <SOURCE>${CMAKE_END_TEMP_FILE}"
218        "prefast LIST")
219        set(CMAKE_C_LINK_EXECUTABLE
220        "<CMAKE_C_COMPILER> ${CMAKE_CL_NOLOGO} <OBJECTS> ${CMAKE_START_TEMP_FILE} <INCLUDES> <FLAGS> /Fe<TARGET> -link /implib:<TARGET_IMPLIB> /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES>${CMAKE_END_TEMP_FILE}")
221        set(CMAKE_CXX_LINK_EXECUTABLE
222        "<CMAKE_CXX_COMPILER> ${CMAKE_CL_NOLOGO} <OBJECTS> ${CMAKE_START_TEMP_FILE} <INCLUDES> <FLAGS> /Fe<TARGET> -link /implib:<TARGET_IMPLIB> /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES>${CMAKE_END_TEMP_FILE}")
223    endif()
224endif()
225
226set(CMAKE_RC_CREATE_SHARED_LIBRARY ${CMAKE_C_CREATE_SHARED_LIBRARY})
227set(CMAKE_ASM_CREATE_SHARED_LIBRARY ${CMAKE_C_CREATE_SHARED_LIBRARY})
228set(CMAKE_RC_CREATE_SHARED_MODULE ${CMAKE_C_CREATE_SHARED_MODULE})
229set(CMAKE_ASM_CREATE_SHARED_MODULE ${CMAKE_C_CREATE_SHARED_MODULE})
230set(CMAKE_ASM_CREATE_STATIC_LIBRARY ${CMAKE_C_CREATE_STATIC_LIBRARY})
231
232if(PCH)
233    macro(add_pch _target _pch _sources)
234
235        # Workaround for the MSVC toolchain (MSBUILD) /MP bug
236        set(_temp_gch ${CMAKE_CURRENT_BINARY_DIR}/${_target}.pch)
237        if(MSVC_IDE)
238            file(TO_NATIVE_PATH ${_temp_gch} _gch)
239        else()
240            set(_gch ${_temp_gch})
241        endif()
242
243        if(IS_CPP)
244            set(_pch_language CXX)
245            if(NOT USE_CLANG_CL)
246                set(_cl_lang_flag "/TP")
247            endif()
248        else()
249            set(_pch_language C)
250            set(_cl_lang_flag "/TC")
251        endif()
252
253        if(MSVC_IDE)
254            set(_pch_path_name_flag "/Fp${_gch}")
255        endif()
256
257        if(USE_CLANG_CL)
258            set(_pch_compile_flags "${_cl_lang_flag} /Yc${_pch} /FI${_pch} /Fp${_gch}")
259        else()
260            set(_pch_compile_flags "${_cl_lang_flag} /Yc /Fp${_gch}")
261        endif()
262
263        # Build the precompiled header
264        # HEADER_FILE_ONLY FALSE: force compiling the header
265        set_source_files_properties(${_pch} PROPERTIES
266            HEADER_FILE_ONLY FALSE
267            LANGUAGE ${_pch_language}
268            COMPILE_FLAGS ${_pch_compile_flags}
269            OBJECT_OUTPUTS ${_gch})
270
271        # Prevent a race condition related to writing to the PDB files between the PCH and the excluded list of source files
272        get_target_property(_target_sources ${_target} SOURCES)
273        list(REMOVE_ITEM _target_sources ${_pch})
274        foreach(_target_src ${_target_sources})
275            set_property(SOURCE ${_target_src} APPEND PROPERTY OBJECT_DEPENDS ${_gch})
276        endforeach()
277
278        # Use the precompiled header with the specified source files, skipping the pch itself
279        list(REMOVE_ITEM ${_sources} ${_pch})
280        foreach(_src ${${_sources}})
281            set_property(SOURCE ${_src} APPEND_STRING PROPERTY COMPILE_FLAGS " /FI${_gch} /Yu${_gch} ${_pch_path_name_flag}")
282        endforeach()
283    endmacro()
284else()
285    macro(add_pch _target _pch _sources)
286    endmacro()
287endif()
288
289function(set_entrypoint _module _entrypoint)
290    if(${_entrypoint} STREQUAL "0")
291        add_target_link_flags(${_module} "/NOENTRY")
292    elseif(ARCH STREQUAL "i386")
293        set(_entrysymbol ${_entrypoint})
294        if(${ARGC} GREATER 2)
295            set(_entrysymbol ${_entrysymbol}@${ARGV2})
296        endif()
297        add_target_link_flags(${_module} "/ENTRY:${_entrysymbol}")
298    else()
299        add_target_link_flags(${_module} "/ENTRY:${_entrypoint}")
300    endif()
301endfunction()
302
303function(set_subsystem MODULE SUBSYSTEM)
304    string(TOUPPER ${SUBSYSTEM} _subsystem)
305    if(ARCH STREQUAL "amd64")
306        add_target_link_flags(${MODULE} "/SUBSYSTEM:${_subsystem},5.02")
307    elseif(ARCH STREQUAL "arm")
308        add_target_link_flags(${MODULE} "/SUBSYSTEM:${_subsystem},6.02")
309    else()
310        add_target_link_flags(${MODULE} "/SUBSYSTEM:${_subsystem},5.01")
311    endif()
312endfunction()
313
314function(set_image_base MODULE IMAGE_BASE)
315    add_target_link_flags(${MODULE} "/BASE:${IMAGE_BASE}")
316endfunction()
317
318function(set_module_type_toolchain MODULE TYPE)
319    if(CPP_USE_STL)
320        if((${TYPE} STREQUAL "kernelmodedriver") OR (${TYPE} STREQUAL "wdmdriver"))
321            message(FATAL_ERROR "Use of STL in kernelmodedriver or wdmdriver type module prohibited")
322        endif()
323        target_link_libraries(${MODULE} cpprt stlport oldnames)
324    elseif(CPP_USE_RT)
325        target_link_libraries(${MODULE} cpprt)
326    endif()
327    if((${TYPE} STREQUAL "win32dll") OR (${TYPE} STREQUAL "win32ocx") OR (${TYPE} STREQUAL "cpl"))
328        add_target_link_flags(${MODULE} "/DLL")
329    elseif(${TYPE} STREQUAL "kernelmodedriver")
330        # Disable linker warning 4078 (multiple sections found with different attributes) for INIT section use
331        add_target_link_flags(${MODULE} "/DRIVER /IGNORE:4078 /SECTION:INIT,D")
332    elseif(${TYPE} STREQUAL "wdmdriver")
333        add_target_link_flags(${MODULE} "/DRIVER:WDM /IGNORE:4078 /SECTION:INIT,D")
334    endif()
335
336    if(RUNTIME_CHECKS)
337        target_link_libraries(${MODULE} runtmchk)
338    endif()
339
340endfunction()
341
342# Define those for having real libraries
343set(CMAKE_IMPLIB_CREATE_STATIC_LIBRARY "LINK /LIB /NOLOGO <LINK_FLAGS> /OUT:<TARGET> <OBJECTS>")
344
345if(ARCH STREQUAL "arm")
346    set(CMAKE_STUB_ASM_COMPILE_OBJECT "<CMAKE_ASM_COMPILER> -nologo -o <OBJECT> <SOURCE>")
347else()
348    set(CMAKE_STUB_ASM_COMPILE_OBJECT "<CMAKE_ASM_COMPILER> /nologo /Cp /Fo<OBJECT> /c /Ta <SOURCE>")
349endif()
350
351function(add_delay_importlibs _module)
352    get_target_property(_module_type ${_module} TYPE)
353    if(_module_type STREQUAL "STATIC_LIBRARY")
354        message(FATAL_ERROR "Cannot add delay imports to a static library")
355    endif()
356    foreach(_lib ${ARGN})
357        get_filename_component(_basename "${_lib}" NAME_WE)
358        get_filename_component(_ext "${_lib}" EXT)
359        if(NOT _ext)
360            set(_ext ".dll")
361        endif()
362        add_target_link_flags(${_module} "/DELAYLOAD:${_basename}${_ext}")
363        target_link_libraries(${_module} "lib${_basename}")
364    endforeach()
365    target_link_libraries(${_module} delayimp)
366endfunction()
367
368function(generate_import_lib _libname _dllname _spec_file)
369
370    set(_def_file ${CMAKE_CURRENT_BINARY_DIR}/${_libname}_exp.def)
371    set(_asm_stubs_file ${CMAKE_CURRENT_BINARY_DIR}/${_libname}_stubs.asm)
372
373    # Generate the asm stub file and the def file for import library
374    add_custom_command(
375        OUTPUT ${_asm_stubs_file} ${_def_file}
376        COMMAND native-spec2def --ms -a=${SPEC2DEF_ARCH} --implib -n=${_dllname} -d=${_def_file} -l=${_asm_stubs_file} ${CMAKE_CURRENT_SOURCE_DIR}/${_spec_file}
377        DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${_spec_file} native-spec2def)
378
379    if(MSVC_IDE)
380        # Compile the generated asm stub file
381        if(ARCH STREQUAL "arm")
382            set(_asm_stub_command ${CMAKE_ASM_COMPILER} -nologo -o ${_asm_stubs_file}.obj ${_asm_stubs_file})
383        else()
384            set(_asm_stub_command ${CMAKE_ASM_COMPILER} /Cp /Fo${_asm_stubs_file}.obj /c /Ta ${_asm_stubs_file})
385        endif()
386        add_custom_command(
387            OUTPUT ${_asm_stubs_file}.obj
388            COMMAND ${_asm_stub_command}
389            DEPENDS ${_asm_stubs_file})
390    else()
391        # Be clear about the "language"
392        # Thanks MS for creating a stupid linker
393        set_source_files_properties(${_asm_stubs_file} PROPERTIES LANGUAGE "STUB_ASM")
394    endif()
395
396    # Add our library
397    if(MSVC_IDE)
398        add_library(${_libname} STATIC EXCLUDE_FROM_ALL ${_asm_stubs_file}.obj)
399        set_source_files_properties(${_asm_stubs_file}.obj PROPERTIES EXTERNAL_OBJECT TRUE)
400        set_target_properties(${_libname} PROPERTIES LINKER_LANGUAGE "C")
401    else()
402        # NOTE: as stub file and def file are generated in one pass, depending on one is like depending on the other
403        add_library(${_libname} STATIC EXCLUDE_FROM_ALL ${_asm_stubs_file})
404        # set correct "link rule"
405        set_target_properties(${_libname} PROPERTIES LINKER_LANGUAGE "IMPLIB")
406    endif()
407    set_target_properties(${_libname} PROPERTIES STATIC_LIBRARY_FLAGS "/DEF:${_def_file}")
408endfunction()
409
410if(ARCH STREQUAL "amd64")
411    # This is NOT a typo.
412    # See https://software.intel.com/en-us/forums/topic/404643
413    add_definitions(/D__x86_64)
414    set(SPEC2DEF_ARCH x86_64)
415elseif(ARCH STREQUAL "arm")
416    add_definitions(/D__arm__)
417    set(SPEC2DEF_ARCH arm)
418else()
419    set(SPEC2DEF_ARCH i386)
420endif()
421function(spec2def _dllname _spec_file)
422
423    cmake_parse_arguments(__spec2def "ADD_IMPORTLIB;NO_PRIVATE_WARNINGS;WITH_RELAY" "VERSION" "" ${ARGN})
424
425    # Get library basename
426    get_filename_component(_file ${_dllname} NAME_WE)
427
428    # Error out on anything else than spec
429    if(NOT ${_spec_file} MATCHES ".*\\.spec")
430        message(FATAL_ERROR "spec2def only takes spec files as input.")
431    endif()
432
433    if (__spec2def_WITH_RELAY)
434        set(__with_relay_arg "--with-tracing")
435    endif()
436
437    if(__spec2def_VERSION)
438        set(__version_arg "--version=0x${__spec2def_VERSION}")
439    endif()
440
441    # Generate exports def and C stubs file for the DLL
442    add_custom_command(
443        OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}.def ${CMAKE_CURRENT_BINARY_DIR}/${_file}_stubs.c
444        COMMAND native-spec2def --ms -a=${SPEC2DEF_ARCH} -n=${_dllname} -d=${CMAKE_CURRENT_BINARY_DIR}/${_file}.def -s=${CMAKE_CURRENT_BINARY_DIR}/${_file}_stubs.c ${__with_relay_arg} ${__version_arg} ${CMAKE_CURRENT_SOURCE_DIR}/${_spec_file}
445        DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${_spec_file} native-spec2def)
446
447    if(__spec2def_ADD_IMPORTLIB)
448        generate_import_lib(lib${_file} ${_dllname} ${_spec_file})
449        if(__spec2def_NO_PRIVATE_WARNINGS)
450            add_target_property(lib${_file} STATIC_LIBRARY_FLAGS "/ignore:4104")
451        endif()
452    endif()
453endfunction()
454
455macro(macro_mc FLAG FILE)
456    set(COMMAND_MC ${CMAKE_MC_COMPILER} -u ${FLAG} -b -h ${CMAKE_CURRENT_BINARY_DIR}/ -r ${CMAKE_CURRENT_BINARY_DIR}/ ${FILE})
457endmacro()
458
459# PSEH workaround
460set(PSEH_LIB "pseh")
461
462# Use a full path for the x86 version of ml when using x64 VS.
463# It's not a problem when using the DDK/WDK because, in x64 mode,
464# both the x86 and x64 versions of ml are available.
465if((ARCH STREQUAL "amd64") AND (DEFINED ENV{VCToolsInstallDir}))
466    set(CMAKE_ASM16_COMPILER $ENV{VCToolsInstallDir}/bin/HostX86/x86/ml.exe)
467elseif((ARCH STREQUAL "amd64") AND (DEFINED ENV{VCINSTALLDIR}))
468    set(CMAKE_ASM16_COMPILER $ENV{VCINSTALLDIR}/bin/ml.exe)
469elseif(ARCH STREQUAL "arm")
470    set(CMAKE_ASM16_COMPILER armasm.exe)
471else()
472    set(CMAKE_ASM16_COMPILER ml.exe)
473endif()
474
475function(CreateBootSectorTarget _target_name _asm_file _binary_file _base_address)
476    set(_object_file ${_binary_file}.obj)
477    set(_temp_file ${_binary_file}.tmp)
478
479    if(USE_CLANG_CL)
480        set(_no_std_includes_flag "-nostdinc")
481    else()
482        set(_no_std_includes_flag "/X")
483    endif()
484
485    add_custom_command(
486        OUTPUT ${_temp_file}
487        COMMAND ${CMAKE_C_COMPILER} /nologo ${_no_std_includes_flag} /I${REACTOS_SOURCE_DIR}/sdk/include/asm /I${REACTOS_BINARY_DIR}/sdk/include/asm /I${REACTOS_SOURCE_DIR}/boot/freeldr /D__ASM__ /D_USE_ML /EP /c ${_asm_file} > ${_temp_file}
488        DEPENDS ${_asm_file})
489
490    if(ARCH STREQUAL "arm")
491        set(_asm16_command ${CMAKE_ASM16_COMPILER} -nologo -o ${_object_file} ${_temp_file})
492    else()
493        set(_asm16_command ${CMAKE_ASM16_COMPILER} /nologo /Cp /Fo${_object_file} /c /Ta ${_temp_file})
494    endif()
495
496    add_custom_command(
497        OUTPUT ${_object_file}
498        COMMAND ${_asm16_command}
499        DEPENDS ${_temp_file})
500
501    add_custom_command(
502        OUTPUT ${_binary_file}
503        COMMAND native-obj2bin ${_object_file} ${_binary_file} ${_base_address}
504        DEPENDS ${_object_file} native-obj2bin)
505
506    set_source_files_properties(${_object_file} ${_temp_file} ${_binary_file} PROPERTIES GENERATED TRUE)
507
508    add_custom_target(${_target_name} ALL DEPENDS ${_binary_file})
509endfunction()
510
511function(allow_warnings __module)
512endfunction()
513
514macro(add_asm_files _target)
515    if(MSVC_IDE AND (CMAKE_VERSION MATCHES "ReactOS"))
516        get_defines(_directory_defines)
517        get_includes(_directory_includes)
518        get_directory_property(_defines COMPILE_DEFINITIONS)
519        foreach(_source_file ${ARGN})
520            get_filename_component(_source_file_base_name ${_source_file} NAME_WE)
521            get_filename_component(_source_file_full_path ${_source_file} ABSOLUTE)
522            set(_preprocessed_asm_file ${CMAKE_CURRENT_BINARY_DIR}/asm/${_source_file_base_name}_${_target}.tmp)
523            set(_object_file ${CMAKE_CURRENT_BINARY_DIR}/asm/${_source_file_base_name}_${_target}.obj)
524            get_source_file_property(_defines_semicolon_list ${_source_file_full_path} COMPILE_DEFINITIONS)
525            unset(_source_file_defines)
526            foreach(_define ${_defines_semicolon_list})
527                if(NOT ${_define} STREQUAL "NOTFOUND")
528                    list(APPEND _source_file_defines -D${_define})
529                endif()
530            endforeach()
531            if(ARCH STREQUAL "arm")
532                set(_pp_asm_compile_command ${CMAKE_ASM_COMPILER} -nologo -o ${_object_file} ${_preprocessed_asm_file})
533            else()
534                set(_pp_asm_compile_command ${CMAKE_ASM_COMPILER} /nologo /Cp /Fo${_object_file} /c /Ta ${_preprocessed_asm_file})
535            endif()
536            add_custom_command(
537                OUTPUT ${_preprocessed_asm_file} ${_object_file}
538                COMMAND cl /nologo /X /I${REACTOS_SOURCE_DIR}/sdk/include/asm /I${REACTOS_BINARY_DIR}/sdk/include/asm ${_directory_includes} ${_source_file_defines} ${_directory_defines} /D__ASM__ /D_USE_ML /EP /c ${_source_file_full_path} > ${_preprocessed_asm_file} && ${_pp_asm_compile_command}
539                DEPENDS ${_source_file_full_path})
540            set_source_files_properties(${_object_file} PROPERTIES EXTERNAL_OBJECT TRUE)
541            list(APPEND ${_target} ${_object_file})
542        endforeach()
543    else()
544        list(APPEND ${_target} ${ARGN})
545    endif()
546endmacro()
547
548function(add_linker_script _target _linker_script_file)
549    get_filename_component(_file_full_path ${_linker_script_file} ABSOLUTE)
550    get_filename_component(_file_name ${_linker_script_file} NAME)
551    set(_generated_file_path_prefix "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${_target}.dir/${_file_name}")
552
553    # Generate the ASM module containing sections specifications and layout.
554    set(_generated_file "${_generated_file_path_prefix}.S")
555    add_custom_command(
556        OUTPUT ${_generated_file}
557        COMMAND "${CMAKE_COMMAND}" -E copy_if_different "${_file_full_path}" "${_generated_file}"
558        DEPENDS ${_file_full_path})
559    set_source_files_properties(${_generated_file} PROPERTIES LANGUAGE "ASM" GENERATED TRUE)
560    add_asm_files(${_target}_linker_file ${_generated_file})
561
562    # Generate the C module containing extra sections specifications and layout,
563    # as well as comment-type linker #pragma directives.
564    set(_generated_file "${_generated_file_path_prefix}.c")
565    add_custom_command(
566        OUTPUT ${_generated_file}
567        COMMAND "${CMAKE_COMMAND}" -E copy_if_different "${_file_full_path}" "${_generated_file}"
568        DEPENDS ${_file_full_path})
569    set_source_files_properties(${_generated_file} PROPERTIES LANGUAGE "C" GENERATED TRUE)
570    list(APPEND ${_target}_linker_file ${_generated_file})
571
572    # Add both files to the sources of the target.
573    target_sources(${_target} PRIVATE "${${_target}_linker_file}")
574
575    # Create the additional linker response file.
576    set(_generated_file "${_generated_file_path_prefix}.rsp")
577    if(USE_CLANG_CL)
578        set(_no_std_includes_flag "-nostdinc")
579    else()
580        set(_no_std_includes_flag "/X")
581    endif()
582    if(MSVC_IDE AND (CMAKE_VERSION MATCHES "ReactOS"))
583        # MSBuild, via the VS IDE, uses response files when calling CL or LINK.
584        # We cannot specify a custom response file on the linker command-line,
585        # since specifying response files from within response files is forbidden.
586        # We therefore have to pre-process, at configuration time, the linker
587        # script so as to retrieve the custom linker options to be appended
588        # to the linker command-line.
589        execute_process(
590            COMMAND ${CMAKE_C_COMPILER} /nologo ${_no_std_includes_flag} /D__LINKER__ /EP /c "${_file_full_path}"
591            # OUTPUT_FILE "${_generated_file}"
592            OUTPUT_VARIABLE linker_options
593            ERROR_QUIET
594            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
595            RESULT_VARIABLE linker_rsp_result
596            OUTPUT_STRIP_TRAILING_WHITESPACE)
597        if(NOT linker_rsp_result EQUAL 0)
598            message(FATAL_ERROR "Generating pre-processed linker options for target '${_target}' failed with error ${linker_rsp_result}.")
599        endif()
600        # file(STRINGS ${_generated_file} linker_options NEWLINE_CONSUME)
601        string(REGEX REPLACE "[\r\n]+" " " linker_options "${linker_options}")
602        add_target_link_flags(${_target} ${linker_options})
603    else()
604        # Generate at compile-time a linker response file and append it
605        # to the linker command-line.
606        add_custom_command(
607            # OUTPUT ${_generated_file}
608            TARGET ${_target} PRE_LINK # PRE_BUILD
609            COMMAND ${CMAKE_C_COMPILER} /nologo ${_no_std_includes_flag} /D__LINKER__ /EP /c "${_file_full_path}" > "${_generated_file}"
610            DEPENDS ${_file_full_path}
611            VERBATIM)
612        set_source_files_properties(${_generated_file} PROPERTIES GENERATED TRUE)
613        # add_custom_target("${_target}_${_file_name}" ALL DEPENDS ${_generated_file})
614        # add_dependencies(${_target} "${_target}_${_file_name}")
615        add_target_link_flags(${_target} "@${_generated_file}")
616        add_target_property(${_target} LINK_DEPENDS ${_file_full_path})
617    endif()
618endfunction()
619