xref: /reactos/sdk/cmake/msvc.cmake (revision a6a07059) 
1
2if(CMAKE_BUILD_TYPE STREQUAL "Release")
3    add_compile_options(/Ox /Ob2 /Ot /Oy)
4    # Avoid spam in clang-cl as it doesn't support /GT
5    if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
6        add_compile_options(/GT)
7    endif()
8elseif(OPTIMIZE STREQUAL "1")
9    add_compile_options(/O1)
10elseif(OPTIMIZE STREQUAL "2")
11    add_compile_options(/O2)
12elseif(OPTIMIZE STREQUAL "3")
13    add_compile_options(/Ot /Ox /GS-)
14elseif(OPTIMIZE STREQUAL "4")
15    add_compile_options(/Ob0 /Od)
16elseif(OPTIMIZE STREQUAL "5")
17    add_compile_options(/Ob2 /Os /Ox /GS-)
18endif()
19
20# Always use string pooling: this helps reducing the binaries size since a lot
21# of redundancy come from the usage of __FILE__ / __RELFILE__ in the debugging
22# helper macros. Note also that GCC builds use string pooling by default.
23add_compile_options(/GF)
24
25# Enable function level linking and comdat folding (only C/C++, not ASM!)
26add_compile_options($<$<COMPILE_LANGUAGE:C,CXX>:/Gy>)
27add_link_options(/OPT:REF /OPT:ICF)
28
29if(ARCH STREQUAL "i386")
30    add_definitions(/DWIN32 /D_WINDOWS)
31endif()
32
33add_definitions(/D__STDC__=1)
34
35# Enable correct values of __cplusplus macro for newer standards
36add_compile_options($<$<COMPILE_LANGUAGE:CXX>:/Zc:__cplusplus>)
37
38# Ignore any "standard" include paths, and do not use any default CRT library.
39if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
40    add_compile_options(/X /Zl)
41endif()
42
43# Disable buffer security checks by default.
44add_compile_options(/GS-)
45
46if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
47    if(ARCH STREQUAL "amd64")
48        add_compile_options(-mcx16) # Generate CMPXCHG16B
49    endif()
50    set(CMAKE_CL_SHOWINCLUDES_PREFIX "Note: including file: ")
51endif()
52
53# HACK: for VS 11+ we need to explicitly disable SSE, which is off by
54# default for older compilers. See CORE-6507
55if(ARCH STREQUAL "i386")
56    # Clang's IA32 means i386, which doesn't have cmpxchg8b
57    if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
58        add_compile_options(-march=${OARCH})
59    else()
60        add_compile_options(/arch:IA32)
61    endif()
62endif()
63
64# VS 12+ requires /FS when used in parallel compilations
65if(NOT MSVC_IDE)
66    add_compile_options(/FS)
67endif()
68
69# VS14+ tries to use thread-safe initialization
70add_compile_options(/Zc:threadSafeInit-)
71
72# HACK: Disable use of __CxxFrameHandler4 on VS 16.3+ (x64 only)
73# See https://developercommunity.visualstudio.com/content/problem/746534/visual-c-163-runtime-uses-an-unsupported-api-for-u.html
74if(ARCH STREQUAL "amd64" AND MSVC_VERSION GREATER 1922)
75    if (NOT CMAKE_C_COMPILER_ID STREQUAL "Clang")
76        add_compile_options(/d2FH4-)
77    endif()
78    add_link_options(/d2:-FH4-)
79endif()
80
81# Generate Warnings Level 3
82add_compile_options(/W3)
83
84# Disable overly sensitive warnings as well as those that generally aren't
85# useful to us.
86# - C4244: implicit integer truncation
87# - C4290: C++ exception specification ignored
88# - C4800: forcing value to bool 'true' or 'false' (performance warning)
89# - C4200: nonstandard extension used : zero-sized array in struct/union
90# - C4214: nonstandard extension used : bit field types other than int
91add_compile_options(/wd4244 /wd4290 /wd4800 /wd4200 /wd4214)
92
93# FIXME: Temporarily disable C4018 until we fix more of the others. CORE-10113
94add_compile_options(/wd4018)
95
96# Allow all warnings on msbuild/VS IDE
97if (MSVC_IDE)
98    set(ALLOW_WARNINGS TRUE)
99endif()
100
101# On x86 Debug builds, if it's not Clang-CL or msbuild, treat all warnings as errors
102if ((ARCH STREQUAL "i386") AND (CMAKE_BUILD_TYPE STREQUAL "Debug") AND (CMAKE_C_COMPILER_ID STREQUAL "MSVC") AND (NOT MSVC_IDE))
103    set(TREAT_ALL_WARNINGS_AS_ERRORS=TRUE)
104endif()
105
106# Define ALLOW_WARNINGS=TRUE on the cmake/configure command line to bypass errors
107if (ALLOW_WARNINGS)
108    # Nothing
109elseif (TREAT_ALL_WARNINGS_AS_ERRORS)
110    add_compile_options(/WX)
111else()
112# The following warnings are treated as errors:
113# - C4013: implicit function declaration
114# - C4020: too many actual parameters
115# - C4022: pointer type mismatch for parameter
116# - C4028: formal parameter different from declaration
117# - C4047: different level of indirection
118# - C4090: different 'modifier' qualifiers (for C programs only;
119#          for C++ programs, the compiler error C2440 is issued)
120# - C4098: void function returning a value
121# - C4113: parameter lists differ
122# - C4129: unrecognized escape sequence
123# - C4133: incompatible types - from '<x> *' to '<y> *'
124# - C4163: 'identifier': not available as an intrinsic function
125# - C4229: modifiers on data are ignored
126# - C4311: pointer truncation from '<pointer>' to '<integer>'
127# - C4312: conversion from '<integer>' to '<pointer>' of greater size
128# - C4313: 'fprintf': '%x' in format string conflicts with argument n of type 'HANDLE'
129# - C4477: '_snprintf' : format string '%ld' requires an argument of type 'long', but variadic argument 1 has type 'DWORD_PTR'
130# - C4603: macro is not defined or definition is different after precompiled header use
131# - C4700: uninitialized variable usage
132# - C4715: 'function': not all control paths return a value
133# - C4716: function must return a value
134add_compile_options(/we4013 /we4020 /we4022 /we4028 /we4047 /we4090 /we4098 /we4113 /we4129 /we4133 /we4163 /we4229 /we4311 /we4312 /we4313 /we4477 /we4603 /we4700 /we4715 /we4716)
135
136# - C4101: unreferenced local variable
137# - C4189: local variable initialized but not referenced
138# Not in Release mode, msbuild generator doesn't like CMAKE_BUILD_TYPE
139if(MSVC_IDE OR CMAKE_BUILD_TYPE STREQUAL "Debug")
140    add_compile_options(/we4101 /we4189)
141endif()
142
143endif()
144
145# Enable warnings above the default level, but don't treat them as errors:
146# - C4115: named type definition in parentheses
147add_compile_options(/w14115)
148
149if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
150    add_compile_options("$<$<COMPILE_LANGUAGE:C,CXX>:-nostdinc>")
151    add_compile_options(
152        -Wno-unknown-warning-option
153        -Wno-multichar
154        -Wno-char-subscripts
155        -Wno-microsoft-enum-forward-reference
156        -Wno-pragma-pack
157        -Wno-microsoft-anon-tag
158        -Wno-parentheses-equality
159        -Wno-unknown-pragmas
160        -Wno-ignored-pragmas
161        -Wno-ignored-pragma-intrinsic
162        -Wno-microsoft-exception-spec
163    )
164endif()
165
166# Debugging
167if(NOT (_PREFAST_ OR _VS_ANALYZE_))
168    add_compile_options($<$<CONFIG:Debug>:/Zi>)
169endif()
170add_compile_definitions($<$<CONFIG:Release>:NDEBUG=>)
171
172# Hotpatchable images
173if(ARCH STREQUAL "i386")
174    if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
175        add_compile_options(/hotpatch)
176    endif()
177    set(_hotpatch_link_flag "/FUNCTIONPADMIN:5")
178elseif(ARCH STREQUAL "amd64")
179    set(_hotpatch_link_flag "/FUNCTIONPADMIN:6")
180endif()
181
182if(MSVC_IDE AND (NOT DEFINED USE_FOLDER_STRUCTURE))
183    set(USE_FOLDER_STRUCTURE TRUE)
184endif()
185
186if(RUNTIME_CHECKS)
187    add_definitions(-D__RUNTIME_CHECKS__)
188    add_compile_options(/RTC1)
189endif()
190
191add_link_options(/MANIFEST:NO /INCREMENTAL:NO /SAFESEH:NO /NODEFAULTLIB /RELEASE ${_hotpatch_link_flag} /IGNORE:4039)
192
193set(CMAKE_MSVC_RUNTIME_LIBRARY "")
194
195# HACK: Remove the /implib argument, implibs are generated separately
196string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
197string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
198string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_C_CREATE_SHARED_LIBRARY "${CMAKE_C_CREATE_SHARED_LIBRARY}")
199string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_CXX_CREATE_SHARED_LIBRARY "${CMAKE_CXX_CREATE_SHARED_LIBRARY}")
200string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_C_CREATE_SHARED_MODULE "${CMAKE_C_CREATE_SHARED_MODULE}")
201string(REPLACE "/implib:<TARGET_IMPLIB>" "" CMAKE_CXX_CREATE_SHARED_MODULE "${CMAKE_CXX_CREATE_SHARED_MODULE}")
202
203# HACK2: CMake lacks the ability to completely remove the 'implib' argument for solution files...
204# To work around this, we just let it create a dummy file
205if(MSVC_IDE)
206    set(CMAKE_IMPORT_LIBRARY_SUFFIX ".dummy")
207endif()
208
209
210if(CMAKE_DISABLE_NINJA_DEPSLOG)
211    set(cl_includes_flag "")
212else()
213    set(cl_includes_flag "/showIncludes")
214endif()
215
216if(MSVC_IDE)
217    # For VS builds we'll only have en-US in resource files
218    add_definitions(/DLANGUAGE_EN_US)
219else()
220    set(CMAKE_RC_COMPILE_OBJECT "<CMAKE_RC_COMPILER> /nologo <INCLUDES> <FLAGS> <DEFINES> ${I18N_DEFS} /fo <OBJECT> <SOURCE>")
221endif()
222
223if(MSVC_VERSION GREATER_EQUAL 1936)
224    set(_quiet_flag "/quiet")
225endif()
226
227# We don't put <INCLUDES> <DEFINES> <FLAGS> because this is handled in add_asm_files macro
228if (NOT MSVC_IDE)
229    if(ARCH STREQUAL "arm" OR ARCH STREQUAL "arm64")
230        set(CMAKE_ASM_MASM_COMPILE_OBJECT "<CMAKE_ASM_MASM_COMPILER> -nologo -o <OBJECT> <SOURCE>")
231    else()
232        set(CMAKE_ASM_MASM_COMPILE_OBJECT "<CMAKE_ASM_MASM_COMPILER> /nologo ${_quiet_flag} /Cp /Fo <OBJECT> /c /Ta <SOURCE>")
233    endif()
234endif()
235
236if(_VS_ANALYZE_)
237    message("-- VS static analysis enabled!")
238    add_compile_options(/analyze:WX-)
239elseif(_PREFAST_)
240    message("PREFAST enabled!")
241    set(CMAKE_C_COMPILE_OBJECT "prefast <CMAKE_C_COMPILER> ${CMAKE_START_TEMP_FILE} ${CMAKE_CL_NOLOGO} <INCLUDES> <FLAGS> <DEFINES> /Fo<OBJECT> -c <SOURCE>${CMAKE_END_TEMP_FILE}"
242    "prefast LIST")
243    set(CMAKE_CXX_COMPILE_OBJECT "prefast <CMAKE_CXX_COMPILER> ${CMAKE_START_TEMP_FILE} ${CMAKE_CL_NOLOGO} <INCLUDES> <FLAGS> <DEFINES> /TP /Fo<OBJECT> -c <SOURCE>${CMAKE_END_TEMP_FILE}"
244    "prefast LIST")
245    set(CMAKE_C_LINK_EXECUTABLE
246    "<CMAKE_C_COMPILER> ${CMAKE_CL_NOLOGO} <OBJECTS> ${CMAKE_START_TEMP_FILE} <INCLUDES> <FLAGS> /Fe<TARGET> -link /implib:<TARGET_IMPLIB> /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <CMAKE_C_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES>${CMAKE_END_TEMP_FILE}")
247    set(CMAKE_CXX_LINK_EXECUTABLE
248    "<CMAKE_CXX_COMPILER> ${CMAKE_CL_NOLOGO} <OBJECTS> ${CMAKE_START_TEMP_FILE} <INCLUDES> <FLAGS> /Fe<TARGET> -link /implib:<TARGET_IMPLIB> /version:<TARGET_VERSION_MAJOR>.<TARGET_VERSION_MINOR> <CMAKE_CXX_LINK_FLAGS> <LINK_FLAGS> <LINK_LIBRARIES>${CMAKE_END_TEMP_FILE}")
249endif()
250
251set(CMAKE_RC_CREATE_SHARED_LIBRARY ${CMAKE_C_CREATE_SHARED_LIBRARY})
252set(CMAKE_ASM_MASM_CREATE_SHARED_LIBRARY ${CMAKE_C_CREATE_SHARED_LIBRARY})
253set(CMAKE_RC_CREATE_SHARED_MODULE ${CMAKE_C_CREATE_SHARED_MODULE})
254set(CMAKE_ASM_MASM_CREATE_SHARED_MODULE ${CMAKE_C_CREATE_SHARED_MODULE})
255set(CMAKE_ASM_CREATE_STATIC_LIBRARY ${CMAKE_C_CREATE_STATIC_LIBRARY})
256
257function(set_entrypoint _module _entrypoint)
258    if(${_entrypoint} STREQUAL "0")
259        target_link_options(${_module} PRIVATE "/NOENTRY")
260    elseif(ARCH STREQUAL "i386")
261        set(_entrysymbol ${_entrypoint})
262        if(${ARGC} GREATER 2)
263            set(_entrysymbol ${_entrysymbol}@${ARGV2})
264        endif()
265        target_link_options(${_module} PRIVATE "/ENTRY:${_entrysymbol}")
266    else()
267        target_link_options(${_module} PRIVATE "/ENTRY:${_entrypoint}")
268    endif()
269endfunction()
270
271function(set_subsystem MODULE SUBSYSTEM)
272    string(TOUPPER ${SUBSYSTEM} _subsystem)
273    if(ARCH STREQUAL "amd64")
274        target_link_options(${MODULE} PRIVATE "/SUBSYSTEM:${_subsystem},5.02")
275    elseif(ARCH STREQUAL "arm")
276        target_link_options(${MODULE} PRIVATE "/SUBSYSTEM:${_subsystem},6.02")
277    elseif(ARCH STREQUAL "arm64")
278        target_link_options(${MODULE} PRIVATE "/SUBSYSTEM:${_subsystem},6.02")
279    else()
280        target_link_options(${MODULE} PRIVATE "/SUBSYSTEM:${_subsystem},5.01")
281    endif()
282endfunction()
283
284function(set_image_base MODULE IMAGE_BASE)
285    target_link_options(${MODULE} PRIVATE "/BASE:${IMAGE_BASE}")
286endfunction()
287
288function(set_module_type_toolchain MODULE TYPE)
289    # Set the PE image version numbers from the NT OS version ReactOS is based on
290    target_link_options(${MODULE} PRIVATE "/VERSION:5.01")
291
292    if((TYPE STREQUAL win32dll) OR (TYPE STREQUAL win32ocx) OR (TYPE STREQUAL cpl))
293        target_link_options(${MODULE} PRIVATE /DLL)
294    elseif(TYPE IN_LIST KERNEL_MODULE_TYPES)
295        # Mark INIT section as Executable Read Write Discardable
296        target_link_options(${MODULE} PRIVATE /SECTION:INIT,ERWD)
297
298        if(TYPE STREQUAL kernelmodedriver)
299            target_link_options(${MODULE} PRIVATE /DRIVER)
300        elseif(TYPE STREQUAL wdmdriver)
301            target_link_options(${MODULE} PRIVATE /DRIVER:WDM)
302        elseif (TYPE STREQUAL kernel)
303            # Mark .rsrc section as non-disposable non-pageable, as bugcheck code needs to access it
304            target_link_options(${MODULE} PRIVATE /SECTION:.rsrc,!DP)
305        endif()
306    endif()
307
308    if(RUNTIME_CHECKS)
309        target_link_libraries(${MODULE} runtmchk)
310    endif()
311
312endfunction()
313
314function(add_delay_importlibs _module)
315    get_target_property(_module_type ${_module} TYPE)
316    if(_module_type STREQUAL "STATIC_LIBRARY")
317        message(FATAL_ERROR "Cannot add delay imports to a static library")
318    endif()
319    foreach(_lib ${ARGN})
320        get_filename_component(_basename "${_lib}" NAME_WE)
321        get_filename_component(_ext "${_lib}" EXT)
322        if(NOT _ext)
323            set(_ext ".dll")
324        endif()
325        target_link_options(${_module} PRIVATE "/DELAYLOAD:${_basename}${_ext}")
326        target_link_libraries(${_module} "lib${_basename}")
327    endforeach()
328    target_link_libraries(${_module} delayimp)
329endfunction()
330
331function(fixup_load_config _target)
332    # msvc knows how to generate a load_config so no hacks here
333endfunction()
334
335function(generate_import_lib _libname _dllname _spec_file __version_arg)
336
337    set(_def_file ${CMAKE_CURRENT_BINARY_DIR}/${_libname}_implib.def)
338    set(_asm_stubs_file ${CMAKE_CURRENT_BINARY_DIR}/${_libname}_stubs.asm)
339    set(_asm_impalias_file ${CMAKE_CURRENT_BINARY_DIR}/${_libname}_impalias.asm)
340
341    # Generate the def, asm stub and alias files
342    add_custom_command(
343        OUTPUT ${_asm_stubs_file} ${_def_file} ${_asm_impalias_file}
344        COMMAND native-spec2def --ms ${__version_arg} -a=${SPEC2DEF_ARCH} --implib -n=${_dllname} -d=${_def_file} -l=${_asm_stubs_file} -i=${_asm_impalias_file} ${CMAKE_CURRENT_SOURCE_DIR}/${_spec_file}
345        DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${_spec_file} native-spec2def)
346
347    # Compile the generated asm stub file
348    if(ARCH STREQUAL "arm" OR ARCH STREQUAL "arm64")
349        set(_asm_stub_command ${CMAKE_ASM_MASM_COMPILER} -nologo -o ${_asm_stubs_file}.obj ${_asm_stubs_file})
350    else()
351        set(_asm_stub_command ${CMAKE_ASM_MASM_COMPILER} /nologo ${_quiet_flag} /Cp /Fo${_asm_stubs_file}.obj /c /Ta ${_asm_stubs_file})
352    endif()
353    add_custom_command(
354        OUTPUT ${_asm_stubs_file}.obj
355        COMMAND ${_asm_stub_command}
356        DEPENDS ${_asm_stubs_file})
357
358    # generate the intermediate import lib
359    set(_libfile_tmp ${CMAKE_CURRENT_BINARY_DIR}/${_libname}_tmp.lib)
360    set(_static_lib_options )
361
362    set(_implib_command ${CMAKE_LINKER} /LIB /NOLOGO /MACHINE:${WINARCH}
363        $<TARGET_PROPERTY:${_libname},STATIC_LIBRARY_FLAGS> $<TARGET_PROPERTY:${_libname},STATIC_LIBRARY_OPTIONS>
364        /DEF:${_def_file} /OUT:${_libfile_tmp} ${_asm_stubs_file}.obj)
365
366    add_custom_command(
367        OUTPUT ${_libfile_tmp}
368        COMMAND ${_implib_command}
369        DEPENDS ${_asm_stubs_file}.obj ${_def_file})
370
371    # By giving the import lib as an object input, LIB extracts the relevant object files and make a new library.
372    # This allows us to treat the implib as a regular static library
373    set_source_files_properties(${_libfile_tmp} PROPERTIES EXTERNAL_OBJECT TRUE)
374    add_library(${_libname} STATIC ${_libfile_tmp} ${_asm_impalias_file})
375
376    set_target_properties(${_libname} PROPERTIES LINKER_LANGUAGE "C")
377endfunction()
378
379if(ARCH STREQUAL "amd64")
380    # This is NOT a typo.
381    # See https://software.intel.com/en-us/forums/topic/404643
382    add_definitions(/D__x86_64)
383    set(SPEC2DEF_ARCH x86_64)
384elseif(ARCH STREQUAL "arm")
385    set(SPEC2DEF_ARCH arm)
386elseif(ARCH STREQUAL "arm64")
387    add_definitions(/D__arm64__)
388    set(SPEC2DEF_ARCH arm64)
389else()
390    set(SPEC2DEF_ARCH i386)
391endif()
392function(spec2def _dllname _spec_file)
393
394    cmake_parse_arguments(__spec2def "ADD_IMPORTLIB;NO_PRIVATE_WARNINGS;WITH_RELAY" "VERSION" "" ${ARGN})
395
396    # Get library basename
397    get_filename_component(_file ${_dllname} NAME_WE)
398
399    # Error out on anything else than spec
400    if(NOT ${_spec_file} MATCHES ".*\\.spec")
401        message(FATAL_ERROR "spec2def only takes spec files as input.")
402    endif()
403
404    if(__spec2def_WITH_RELAY)
405        set(__with_relay_arg "--with-tracing")
406    endif()
407
408    if(__spec2def_VERSION)
409        set(__version_arg "--version=0x${__spec2def_VERSION}")
410    else()
411        set(__version_arg "--version=${DLL_EXPORT_VERSION}")
412    endif()
413
414    # Generate exports def and C stubs file for the DLL
415    add_custom_command(
416        OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${_file}.def ${CMAKE_CURRENT_BINARY_DIR}/${_file}_stubs.c
417        COMMAND native-spec2def --ms -a=${SPEC2DEF_ARCH} -n=${_dllname} -d=${CMAKE_CURRENT_BINARY_DIR}/${_file}.def -s=${CMAKE_CURRENT_BINARY_DIR}/${_file}_stubs.c ${__with_relay_arg} ${__version_arg} ${CMAKE_CURRENT_SOURCE_DIR}/${_spec_file}
418        DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${_spec_file} native-spec2def)
419
420    # Do not use precompiled headers for the stub file
421    set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${_file}_stubs.c PROPERTIES SKIP_PRECOMPILE_HEADERS ON)
422
423    if(__spec2def_ADD_IMPORTLIB)
424        generate_import_lib(lib${_file} ${_dllname} ${_spec_file} "${__version_arg}")
425        if(__spec2def_NO_PRIVATE_WARNINGS)
426            set_property(TARGET lib${_file} APPEND PROPERTY STATIC_LIBRARY_OPTIONS /ignore:4104)
427        endif()
428    endif()
429endfunction()
430
431macro(macro_mc FLAG FILE)
432    set(COMMAND_MC ${CMAKE_MC_COMPILER} -u ${FLAG} -b -h ${CMAKE_CURRENT_BINARY_DIR}/ -r ${CMAKE_CURRENT_BINARY_DIR}/ ${FILE})
433endmacro()
434
435# PSEH workaround
436set(PSEH_LIB "pseh")
437
438# Setup MASM/ML for compiling 16-bit x86 ASM code on x86 or non-x86 ports.
439if(NOT ARCH STREQUAL "i386")
440    if((MSVC_VERSION LESS_EQUAL 1900) AND (DEFINED ENV{VCINSTALLDIR}))
441        set(CMAKE_ASM16_COMPILER $ENV{VCINSTALLDIR}/bin/ml.exe)
442    elseif(DEFINED ENV{VCToolsInstallDir})
443        set(CMAKE_ASM16_COMPILER $ENV{VCToolsInstallDir}/bin/Host$ENV{VSCMD_ARG_HOST_ARCH}/x86/ml.exe)
444    else()
445        set(CMAKE_ASM16_COMPILER ml.exe)
446    endif()
447else()
448    set(CMAKE_ASM16_COMPILER ml.exe)
449endif()
450
451function(CreateBootSectorTarget _target_name _asm_file _binary_file _base_address)
452    set(_object_file ${_binary_file}.obj)
453    set(_temp_file ${_binary_file}.tmp)
454
455    get_defines(_defines)
456    get_includes(_includes)
457
458    if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
459        set(_no_std_includes_flag "-nostdinc")
460    else()
461        set(_no_std_includes_flag "/X")
462    endif()
463
464    add_custom_command(
465        OUTPUT ${_temp_file}
466        COMMAND ${CMAKE_C_COMPILER} /nologo ${_no_std_includes_flag} /I${REACTOS_SOURCE_DIR}/sdk/include/asm /I${REACTOS_BINARY_DIR}/sdk/include/asm ${_includes} ${_defines} /D__ASM__ /D_USE_ML /EP /c ${_asm_file} > ${_temp_file}
467        DEPENDS ${_asm_file})
468
469    set(_asm16_command ${CMAKE_ASM16_COMPILER} /nologo ${_quiet_flag} /Cp /Fo${_object_file} /c /Ta ${_temp_file})
470
471    add_custom_command(
472        OUTPUT ${_object_file}
473        COMMAND ${_asm16_command}
474        DEPENDS ${_temp_file})
475
476    add_custom_command(
477        OUTPUT ${_binary_file}
478        COMMAND native-obj2bin ${_object_file} ${_binary_file} ${_base_address}
479        DEPENDS ${_object_file} native-obj2bin)
480
481    set_source_files_properties(${_object_file} ${_temp_file} ${_binary_file} PROPERTIES GENERATED TRUE)
482
483    add_custom_target(${_target_name} ALL DEPENDS ${_binary_file})
484endfunction()
485
486function(allow_warnings __module)
487endfunction()
488
489macro(add_asm_files _target)
490    get_defines(_directory_defines)
491    get_includes(_directory_includes)
492    get_directory_property(_defines COMPILE_DEFINITIONS)
493    foreach(_source_file ${ARGN})
494        get_filename_component(_extension ${_source_file} EXT)
495        if (("${_extension}" STREQUAL ".asm") OR ("${_extension}" STREQUAL ".inc"))
496            list(APPEND ${_target} ${_source_file})
497        else()
498            get_filename_component(_source_file_base_name ${_source_file} NAME_WE)
499            get_filename_component(_source_file_full_path ${_source_file} ABSOLUTE)
500            set(_preprocessed_asm_file ${CMAKE_CURRENT_BINARY_DIR}/asm/${_source_file_base_name}_${_target}.asm)
501            get_source_file_property(_defines_semicolon_list ${_source_file_full_path} COMPILE_DEFINITIONS)
502            unset(_source_file_defines)
503            foreach(_define ${_defines_semicolon_list})
504                if(NOT ${_define} STREQUAL "NOTFOUND")
505                    list(APPEND _source_file_defines -D${_define})
506                endif()
507            endforeach()
508            add_custom_command(
509                OUTPUT ${_preprocessed_asm_file}
510                COMMAND cl /nologo /X /I${REACTOS_SOURCE_DIR}/sdk/include/asm /I${REACTOS_BINARY_DIR}/sdk/include/asm ${_directory_includes} ${_source_file_defines} ${_directory_defines} /D__ASM__ /D_USE_ML /EP /c ${_source_file_full_path} > ${_preprocessed_asm_file}
511                DEPENDS ${_source_file_full_path})
512            list(APPEND ${_target} ${_preprocessed_asm_file})
513        endif()
514    endforeach()
515endmacro()
516
517function(add_linker_script _target _linker_script_file)
518    get_filename_component(_file_full_path ${_linker_script_file} ABSOLUTE)
519    get_filename_component(_file_name ${_linker_script_file} NAME)
520    set(_generated_file_path_prefix "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${_target}.dir/${_file_name}")
521
522    # Generate the ASM module containing sections specifications and layout.
523    set(_generated_file "${_generated_file_path_prefix}.S")
524    add_custom_command(
525        OUTPUT ${_generated_file}
526        COMMAND "${CMAKE_COMMAND}" -E copy_if_different "${_file_full_path}" "${_generated_file}"
527        DEPENDS ${_file_full_path})
528    set_source_files_properties(${_generated_file} PROPERTIES LANGUAGE "ASM_MASM" GENERATED TRUE)
529    add_asm_files(${_target}_linker_file ${_generated_file})
530
531    # Generate the C module containing extra sections specifications and layout,
532    # as well as comment-type linker #pragma directives.
533    set(_generated_file "${_generated_file_path_prefix}.c")
534    add_custom_command(
535        OUTPUT ${_generated_file}
536        COMMAND "${CMAKE_COMMAND}" -E copy_if_different "${_file_full_path}" "${_generated_file}"
537        DEPENDS ${_file_full_path})
538    set_source_files_properties(${_generated_file} PROPERTIES LANGUAGE "C" GENERATED TRUE)
539    list(APPEND ${_target}_linker_file ${_generated_file})
540
541    # Add both files to the sources of the target.
542    target_sources(${_target} PRIVATE "${${_target}_linker_file}")
543
544    # Create the additional linker response file.
545    set(_generated_file "${_generated_file_path_prefix}.rsp")
546    if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
547        set(_no_std_includes_flag "-nostdinc")
548    else()
549        set(_no_std_includes_flag "/X")
550    endif()
551    if(MSVC_IDE)
552        # MSBuild, via the VS IDE, uses response files when calling CL or LINK.
553        # We cannot specify a custom response file on the linker command-line,
554        # since specifying response files from within response files is forbidden.
555        # We therefore have to pre-process, at configuration time, the linker
556        # script so as to retrieve the custom linker options to be appended
557        # to the linker command-line.
558        execute_process(
559            COMMAND ${CMAKE_C_COMPILER} /nologo ${_no_std_includes_flag} /D__LINKER__ /EP /c "${_file_full_path}"
560            # OUTPUT_FILE "${_generated_file}"
561            OUTPUT_VARIABLE linker_options
562            ERROR_QUIET
563            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
564            RESULT_VARIABLE linker_rsp_result
565            OUTPUT_STRIP_TRAILING_WHITESPACE)
566        if(NOT linker_rsp_result EQUAL 0)
567            message(FATAL_ERROR "Generating pre-processed linker options for target '${_target}' failed with error ${linker_rsp_result}.")
568        endif()
569        # file(STRINGS ${_generated_file} linker_options NEWLINE_CONSUME)
570        string(REGEX REPLACE "[\r\n]+" ";" linker_options "${linker_options}")
571        target_link_options(${_target} PRIVATE ${linker_options})
572    else()
573        # Generate at compile-time a linker response file and append it
574        # to the linker command-line.
575        add_custom_command(
576            # OUTPUT ${_generated_file}
577            TARGET ${_target} PRE_LINK # PRE_BUILD
578            COMMAND ${CMAKE_C_COMPILER} /nologo ${_no_std_includes_flag} /D__LINKER__ /EP /c "${_file_full_path}" > "${_generated_file}"
579            DEPENDS ${_file_full_path}
580            VERBATIM)
581        set_source_files_properties(${_generated_file} PROPERTIES GENERATED TRUE)
582        # add_custom_target("${_target}_${_file_name}" ALL DEPENDS ${_generated_file})
583        # add_dependencies(${_target} "${_target}_${_file_name}")
584        target_link_options(${_target} PRIVATE "@${_generated_file}")
585        set_property(TARGET ${_target} APPEND PROPERTY LINK_DEPENDS ${_file_full_path})
586    endif()
587endfunction()
588
589# handle C++ options
590# disable RTTI unless said so
591add_compile_options("$<$<COMPILE_LANGUAGE:CXX>:$<IF:$<BOOL:$<TARGET_PROPERTY:WITH_CXX_RTTI>>,/GR,/GR->>")
592# disable exceptions unless said so
593add_compile_options("$<$<COMPILE_LANGUAGE:CXX>:$<IF:$<BOOL:$<TARGET_PROPERTY:WITH_CXX_EXCEPTIONS>>,/EHsc,/EHs-c->>")
594
595# Create our interface libraries wrapping the needed library for this compiler
596add_library(cppstl INTERFACE)
597target_link_libraries(cppstl INTERFACE cpprt stlport oldnames)
598# We set this properties through our INTERFACE library
599set_target_properties(cppstl PROPERTIES INTERFACE_WITH_CXX_STL TRUE)
600# add_library(cpprt INTERFACE)
601# Our runtime library is already called cpprt
602