1<CsoundSynthesizer>
2
3; Id: E01_a.CSD mg (2006, rev.2009)
4; author: marco gasperini (marcogsp at yahoo dot it)
5
6; G.M. Koenig
7; ESSAY (1957)
8
9<CsOptions>
10-W -f -oE01_a.wav
11</CsOptions>
12
13<CsInstruments>
14
15sr     = 192000
16kr     = 192000
17ksmps  = 1
18nchnls = 1
19
20;=============================================
21; SINUS TONES (S)
22;=============================================
23	instr 1
24iamp	= ampdb(90+p4)
25ifreq	= p5
26
27a1	oscili iamp , ifreq , 1
28aenv	expseg .001 , .005, 1 , p3-.01 ,1, .005,.001
29
30aout	= a1 * aenv
31
32	out aout
33	endin
34;=============================================
35
36;=============================================
37; FILTERED NOISE (N)
38;=============================================
39	instr 2
40iamp	= ampdb(87+p4)
41ifreq	= p5
42ibw	= ifreq * .05		; filtered noise's bandwidth 5% of central frequency
43
44a1	rnd31 iamp , 1
45k1	rms a1
46
47afilt	butterbp a1 , ifreq , ibw
48afilt	butterbp afilt , ifreq , ibw
49
50aenv	expseg .001 , .005, .8 , p3-.01 ,.8 ,.005,.001
51
52aout	gain afilt , k1
53aout	= aout * aenv
54
55	out aout
56	endin
57;=============================================
58
59;=============================================
60; FILTERED IMPULSES (I)
61;=============================================
62	instr 3
63iamp	= ampdb(86+p4)
64ifreq	= p5
65ibw	= ifreq * .01		; filtered pulse's bandwidth 1% of central frequency
66
67if1	= ifreq-(ibw/3)
68if2	= ifreq+((2*ibw)/3)
69
70
71a1	mpulse iamp , 0
72
73afilt	atonex a1 , if1 , 2
74afilt	tonex afilt*100 , if2 , 2
75afilt	butterbp afilt*900 , ifreq , ibw*.05
76
77
78aenv	linseg 1 , p3-.01, 1 , .01 , 0
79
80aout	= afilt * aenv
81
82	out aout*(sr/192000)
83	endin
84;=============================================
85</CsInstruments>
86<CsScore>
87;functions--------------------------------------------------
88f1	0	8192	10	1	; sinusoid
89;/functions--------------------------------------------------
90
91t0	4572	; 76.2 cm/sec. tape speed (durations in cm)
92
93;test--------------------------------------------------
94;mute-------------------------------------------------
95q 1 0 1
96q 2 0 1
97q 3 0 1
98;/mute-------------------------------------------------
99;/test-------------------------------------------------
100
101;====================================================
102; 150. MATERIAL E
103; 151. total length: 577.1 cm, 8 sections
104;
105; sequence a
106;
107; length    sequence
108; 133.5  cm (7)
109; 89     cm (6)
110; 26.3   cm (3)
111; 200.2  cm (8)
112;==================================================
113
114;==================================151.11
115; 133.5 cm 6/5
116;----------------------------------------
117;			p4	p5
118;			iamp	ifreq	timbre
119;			[dB]	[Hz]
120i3	0	20.1	-10	11763	; I
121i3	+	16.8	-8	8300    ; I
122i3	+	9.7	-9.5	10763   ; I
123i3	+	29	-5.5	5869    ; I
124i3	+	24.2	-7	7611    ; I
125i3	+	11.6	-3	4150    ; I
126i2	111.4	8.1	-3	5382    ; R
127i3	119.5	14	-9	9870	; I
128s
129t0	4572
130;==================================151.12
131; 89 cm 7/6
132;----------------------------------------
133i3	0	11.3	-6.5	6979	; I
134i3	+	9.7	-.5	2934    ; I
135i3	+	6.1	-2.5	3805    ; I
136i2	27.1	15.4	-4	4935    ; R
137i2	+	13.2	-4	2691    ; R
138i3	55.7	7.1	-8.5	9051    ; I
139i3	+	17.9	2.5	2075    ; I
140i3	+	8.3	-2	3490    ; I
141s
142t0	4572
143;==================================151.13
144; 26.3 cm 10/9
145;----------------------------------------
146i2	0	2.5	-5	6400	; R
147i2	+	2.2	-5	1903    ; R
148i2	+	3.7	-5	2468    ; R
149i3	8.4	3	-3.5	4525    ; I
150i3	+	2.7	5	1467    ; I
151i2	14.1	4.2	-6	3200    ; R
152i2	+	3.4	-6	1745    ; R
153i2	+	4.6	-6	1345    ; R
154s
155t0	4572
156;==================================151.14
157; 200.2 cm 5/4
158;----------------------------------------
159i2	0	48.1	-5	2263	; R
160i3	48.1	38.5	6.5	1234    ; I
161i2	86.6	19.7	-4	1600    ; R
162i2	+	12.6	-4	1037    ; R
163i2	+	10.1	-4	951     ; R
164i2	+	24.6	-4	1131    ; R
165i2	+	15.8	-4	872     ; R
166i2	+	30.8	-4	800     ; R
167
168; total length E(a): 449 cm
169e
170
171</CsScore>
172</CsoundSynthesizer>