1# Configure paths for libogg
2# updated by Karl Heyes 10-Jun-2003
3# Jack Moffitt <jack@icecast.org> 10-21-2000
4# Shamelessly stolen from Owen Taylor and Manish Singh
5
6dnl XIPH_PATH_OGG([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
7dnl Test for libogg, and define OGG_CFLAGS OGG_LDFLAGS and OGG_LIBS
8dnl
9AC_DEFUN([XIPH_PATH_OGG],
10[dnl
11AC_ARG_VAR([OGG_PREFIX],[path to ogg installation])
12AC_ARG_WITH(ogg,
13    [AC_HELP_STRING([--with-ogg=PREFIX],
14        [Prefix where libogg is installed (optional)])],
15    ogg_prefix="$withval",
16    ogg_prefix="$OGG_PREFIX"
17    )
18if test "x$ogg_prefix" = "x" -o "x$ogg_prefix" = "xyes"; then
19    if test "x$prefix" = "xNONE"; then
20        ogg_prefix=/usr/local
21    else
22        ogg_prefix="$prefix"
23    fi
24fi
25
26XIPH_GCC_WARNING([-I$ogg_prefix/include],,
27    [ OGG_CFLAGS="-I$ogg_prefix/include"
28      OGG_LDFLAGS="-L$ogg_prefix/lib"
29      ])
30AC_CACHE_CHECK([for libogg], xt_cv_lib_ogg,
31[dnl
32OGG_LIBS="-logg"
33
34#
35# check if the installed Ogg is sufficiently new.
36#
37ac_save_CFLAGS="$CFLAGS"
38ac_save_LIBS="$LIBS"
39ac_save_LDFLAGS="$LDFLAGS"
40CFLAGS="$CFLAGS $OGG_CFLAGS"
41LIBS="$LIBS $OGG_LIBS"
42LDFLAGS="$LDFLAGS $OGG_LDFLAGS"
43AC_TRY_LINK_FUNC(ogg_sync_init,
44    [ xt_cv_lib_ogg=ok ],
45    [ AC_TRY_LINK([#include <ogg/ogg.h>],,
46        [ xt_cv_lib_ogg="pre v1.0, needs updating" ],
47        [ xt_cv_lib_ogg="not found" ])
48    ])
49CFLAGS="$ac_save_CFLAGS"
50LDFLAGS="$ac_save_LDFLAGS"
51LIBS="$ac_save_LIBS"
52])
53if test "x$xt_cv_lib_ogg" = "xok"; then
54    ifelse([$1],,,[$1])
55    AC_DEFINE([HAVE_OGG], [1], [Define if you have libogg installed])
56else
57    OGG_LIBS=""
58    OGG_CFLAGS=""
59    OGG_LDFLAGS=""
60    ifelse([$2],,,[$2])
61fi
62AC_SUBST(OGG_LIBS)
63AC_SUBST(OGG_CFLAGS)
64AC_SUBST(OGG_LDFLAGS)
65])
66