1# -helper macro to add a "doxy" target with CMake build system.
2# and configure Doxyfile.in to Doxyfile
3#
4# target "doxy" allows building the documentation with doxygen/dot on WIN32 and Linux
5# Creates .chm windows help file if MS HTML help workshop
6# (available from http://msdn.microsoft.com/workshop/author/htmlhelp)
7# is installed with its DLLs in PATH.
8#
9#
10# Please note, that the tools, e.g.:
11# doxygen, dot, latex, dvips, makeindex, gswin32, etc.
12# must be in path.
13#
14# Note about Visual Studio Projects:
15# MSVS hast its own path environment which may differ from the shell.
16# See "Menu Tools/Options/Projects/VC++ Directories" in VS 7.1
17#
18# author Jan Woetzel 2004-2006
19# www.mip.informatik.uni-kiel.de/~jw
20
21FIND_PACKAGE(Doxygen)
22
23IF (DOXYGEN)
24
25   MESSAGE("found Doxygen")
26
27  # click+jump in Emacs and Visual Studio (for Doxyfile) (jw)
28  IF    (CMAKE_BUILD_TOOL MATCHES "(msdev|devenv)")
29    SET(DOXY_WARN_FORMAT "\"$file($line) : $text \"")
30  ELSE  (CMAKE_BUILD_TOOL MATCHES "(msdev|devenv)")
31    SET(DOXY_WARN_FORMAT "\"$file:$line: $text \"")
32  ENDIF (CMAKE_BUILD_TOOL MATCHES "(msdev|devenv)")
33
34  # we need latex for doxygen because of the formulas
35  FIND_PACKAGE(LATEX)
36  IF    (NOT LATEX_COMPILER)
37    MESSAGE(STATUS "latex command LATEX_COMPILER not found but usually required. You will probably get warnings and user inetraction on doxy run.")
38  ENDIF (NOT LATEX_COMPILER)
39  IF    (NOT MAKEINDEX_COMPILER)
40    MESSAGE(STATUS "makeindex command MAKEINDEX_COMPILER not found but usually required.")
41  ENDIF (NOT MAKEINDEX_COMPILER)
42  IF    (NOT DVIPS_CONVERTER)
43    MESSAGE(STATUS "dvips command DVIPS_CONVERTER not found but usually required.")
44  ENDIF (NOT DVIPS_CONVERTER)
45
46  IF   (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in")
47    MESSAGE(STATUS "configured ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in --> ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile")
48    CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in
49      ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
50      @ONLY )
51    # use (configured) Doxyfile from (out of place) BUILD tree:
52    SET(DOXY_CONFIG "${CMAKE_CURRENT_BINARY_DIR}/Doxyfile")
53  ELSE (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in")
54    # use static hand-edited Doxyfile from SOURCE tree:
55    SET(DOXY_CONFIG "${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile")
56    IF   (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile")
57      MESSAGE(STATUS "WARNING: using existing ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile instead of configuring from Doxyfile.in file.")
58    ELSE (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile")
59      IF   (EXISTS "${CMAKE_MODULE_PATH}/Doxyfile.in")
60        # using template Doxyfile.in
61        MESSAGE(STATUS "configured ${CMAKE_CMAKE_MODULE_PATH}/Doxyfile.in --> ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile")
62        CONFIGURE_FILE(${CMAKE_MODULE_PATH}/Doxyfile.in
63          ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
64          @ONLY )
65        SET(DOXY_CONFIG "${CMAKE_CURRENT_BINARY_DIR}/Doxyfile")
66      ELSE (EXISTS "${CMAKE_MODULE_PATH}/Doxyfile.in")
67        # failed completely...
68        MESSAGE(SEND_ERROR "Please create ${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in (or Doxyfile as fallback)")
69      ENDIF(EXISTS "${CMAKE_MODULE_PATH}/Doxyfile.in")
70
71    ENDIF(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile")
72  ENDIF(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in")
73
74  ADD_CUSTOM_TARGET(doxy ${DOXYGEN} ${DOXY_CONFIG})
75
76  # create a windows help .chm file using hhc.exe
77  # HTMLHelp DLL must be in path!
78  # fallback: use hhw.exe interactively
79  IF    (WIN32)
80    FIND_PACKAGE(HTMLHelp)
81    IF   (HTML_HELP_COMPILER)
82      SET (TMP "${CMAKE_CURRENT_BINARY_DIR}\\Doc\\html\\index.hhp")
83      STRING(REGEX REPLACE "[/]" "\\\\" HHP_FILE ${TMP} )
84      # MESSAGE(SEND_ERROR "DBG  HHP_FILE=${HHP_FILE}")
85      ADD_CUSTOM_TARGET(winhelp ${HTML_HELP_COMPILER} ${HHP_FILE})
86      ADD_DEPENDENCIES (winhelp doxy)
87
88      IF (NOT TARGET_DOC_SKIP_INSTALL)
89      # install windows help?
90      # determine useful name for output file
91      # should be project and version unique to allow installing
92      # multiple projects into one global directory
93      IF   (EXISTS "${PROJECT_BINARY_DIR}/Doc/html/index.chm")
94        IF   (PROJECT_NAME)
95          SET(OUT "${PROJECT_NAME}")
96        ELSE (PROJECT_NAME)
97          SET(OUT "Documentation") # default
98        ENDIF(PROJECT_NAME)
99        IF   (${PROJECT_NAME}_VERSION_MAJOR)
100          SET(OUT "${OUT}-${${PROJECT_NAME}_VERSION_MAJOR}")
101          IF   (${PROJECT_NAME}_VERSION_MINOR)
102            SET(OUT  "${OUT}.${${PROJECT_NAME}_VERSION_MINOR}")
103            IF   (${PROJECT_NAME}_VERSION_PATCH)
104              SET(OUT "${OUT}.${${PROJECT_NAME}_VERSION_PATCH}")
105            ENDIF(${PROJECT_NAME}_VERSION_PATCH)
106          ENDIF(${PROJECT_NAME}_VERSION_MINOR)
107        ENDIF(${PROJECT_NAME}_VERSION_MAJOR)
108        # keep suffix
109        SET(OUT  "${OUT}.chm")
110
111        #MESSAGE("DBG ${PROJECT_BINARY_DIR}/Doc/html/index.chm \n${OUT}")
112        # create target used by install and package commands
113        INSTALL(FILES "${PROJECT_BINARY_DIR}/Doc/html/index.chm"
114          DESTINATION "doxy"
115          RENAME "${OUT}"
116        )
117      ENDIF(EXISTS "${PROJECT_BINARY_DIR}/Doc/html/index.chm")
118      ENDIF(NOT TARGET_DOC_SKIP_INSTALL)
119
120    ENDIF(HTML_HELP_COMPILER)
121    # MESSAGE(SEND_ERROR "HTML_HELP_COMPILER=${HTML_HELP_COMPILER}")
122  ENDIF (WIN32)
123ELSE(DOXYGEN)
124  MESSAGE("Doxygen not found")
125ENDIF(DOXYGEN)
126