1AC_DEFUN([AC_CHECK_FLTK], [
2  AC_ARG_VAR([FLTK_CONFIG], [Path to fltk-config utility])
3  AC_ARG_VAR([FLTK_CFLAGS], [C compiler flags for FLTK, overriding fltk-config])
4  AC_ARG_VAR([FLTK_LIBS], [linker flags for FLTK, overriding fltk-config])
5
6  if test "x$FLTK_CFLAGS" = "x" && test "x$FLTK_LIBS" = "x"; then
7      if test "x$FLTK_CONFIG" = "x"; then
8          AC_PATH_PROG([FLTK_CONFIG], [fltk-config], [no])
9      else
10          AC_MSG_CHECKING([for fltk-config])
11          AC_MSG_RESULT([$FLTK_CONFIG])
12      fi
13      if test "$FLTK_CONFIG" = "no"; then
14          AC_MSG_ERROR([
15  *** The fltk-config script could not be found. Please install the development
16  *** headers and libraries for FLTK 1.1.x, or set PATH to the directory that
17  *** contains fltk-config.
18          ])
19      fi
20      HAVE_FLTK_API_VERSION=no
21      FLTK_API_VERSION="`$FLTK_CONFIG --api-version`"
22      if test $? -ne 0; then
23          AC_MSG_ERROR([$FLTK_CONFIG failed])
24      fi
25      if test "x$FLTK_API_VERSION" = "x1.1" || test "x$FLTK_API_VERSION" = "x1.3"; then
26          HAVE_FLTK_API_VERSION=yes
27      fi
28      if test "${HAVE_FLTK_API_VERSION}" = "no"; then
29          AC_MSG_ERROR([
30  *** The version of FLTK found on your system provides API version $FLTK_API_VERSION.
31  *** To build $PACKAGE you need a FLTK version that provides API 1.1 or 1.3.
32          ])
33      fi
34      FLTK_CFLAGS=`$FLTK_CONFIG --cxxflags`
35      if test "x$ac_cv_static" != "xyes"; then
36          FLTK_LIBS=`$FLTK_CONFIG --ldflags --use-images`
37      else
38          FLTK_LIBS=`$FLTK_CONFIG --ldstaticflags --use-images`
39      fi
40  else
41      AC_MSG_NOTICE([not checking for FLTK])
42  fi
43  AC_SUBST([FLTK_CFLAGS])
44  AC_SUBST([FLTK_LIBS])
45  AC_DEFINE_UNQUOTED([FLTK_BUILD_VERSION], ["`$FLTK_CONFIG --version`"], [FLTK version])
46
47  AC_ARG_VAR([FLUID], [Fast Light User-Interface Designer])
48  AC_CHECK_PROG([FLUID], [fluid], [fluid])
49  AM_CONDITIONAL([HAVE_FLUID], [test -n "$FLUID"])
50])
51