1# Copyright (c) 2015, Daniel Black. All rights reserved.
2#
3# This program is free software; you can redistribute it and/or modify
4# it under the terms of the GNU General Public License as published by
5# the Free Software Foundation; version 2 of the License.
6#
7# This program is distributed in the hope that it will be useful,
8# but WITHOUT ANY WARRANTY; without even the implied warranty of
9# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
10# GNU General Public License for more details.
11#
12# You should have received a copy of the GNU General Public License
13# along with this program; if not, write to the Free Software
14# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1335  USA
15
16MACRO(CHECK_SYSTEMD)
17  IF(UNIX)
18    INCLUDE(FindPkgConfig)
19    # http://www.cmake.org/cmake/help/v3.0/module/FindPkgConfig.html
20    SET(WITH_SYSTEMD "auto" CACHE STRING "Enable systemd scripts and notification support. Allowed values yes/no/auto.")
21    IF(WITH_SYSTEMD STREQUAL "yes" OR WITH_SYSTEMD STREQUAL "auto")
22      IF(PKG_CONFIG_FOUND)
23        IF (NOT DEFINED LIBSYSTEMD_FOUND)
24          IF(WITH_SYSTEMD STREQUAL "yes")
25            pkg_search_module(LIBSYSTEMD REQUIRED libsystemd libsystemd-daemon)
26          ELSE()
27            pkg_search_module(LIBSYSTEMD libsystemd libsystemd-daemon)
28          ENDIF()
29        ENDIF()
30        IF(HAVE_DLOPEN)
31          SET(LIBSYSTEMD ${LIBSYSTEMD_LDFLAGS} ${LIBSYSTEMD_LIBRARIES})
32        ELSE()
33          SET(LIBSYSTEMD ${LIBSYSTEMD_STATIC_LDFLAGS} ${LIBSYSTEMD_STATIC_LIBRARIES})
34        ENDIF()
35      ELSE()
36        SET(LIBSYSTEMD systemd)
37      ENDIF()
38      SET(CMAKE_REQUIRED_LIBRARIES ${LIBSYSTEMD})
39      CHECK_LIBRARY_EXISTS(systemd sd_listen_fds "" HAVE_SYSTEMD_SD_LISTEN_FDS)
40      CHECK_INCLUDE_FILES(systemd/sd-daemon.h HAVE_SYSTEMD_SD_DAEMON_H)
41      CHECK_FUNCTION_EXISTS(sd_notify HAVE_SYSTEMD_SD_NOTIFY)
42      CHECK_FUNCTION_EXISTS(sd_notifyf HAVE_SYSTEMD_SD_NOTIFYF)
43      SET(CMAKE_REQUIRED_LIBRARIES)
44      IF(HAVE_SYSTEMD_SD_DAEMON_H AND HAVE_SYSTEMD_SD_LISTEN_FDS
45         AND HAVE_SYSTEMD_SD_NOTIFY AND HAVE_SYSTEMD_SD_NOTIFYF)
46        SET(HAVE_SYSTEMD TRUE)
47        SET(SYSTEMD_SCRIPTS mariadb-service-convert galera_new_cluster galera_recovery)
48        IF(DEB)
49          SET(SYSTEMD_EXECSTARTPRE "ExecStartPre=/usr/bin/install -m 755 -o mysql -g root -d /var/run/mysqld")
50          SET(SYSTEMD_EXECSTARTPOST "ExecStartPost=/etc/mysql/debian-start")
51        ENDIF()
52        IF(NOT DEB AND NOT RPM)
53          SET(SYSTEMD_READWRITEPATH "# Database dir: '${MYSQL_DATADIR}' should be writable even
54# ProtectSystem=full prevents it
55ReadWritePaths=-${MYSQL_DATADIR}\n")
56        ENDIF()
57
58        MESSAGE_ONCE(systemd "Systemd features enabled")
59      ELSE()
60        UNSET(LIBSYSTEMD)
61        UNSET(HAVE_SYSTEMD)
62        UNSET(HAVE_SYSTEMD_SD_DAEMON_H)
63        UNSET(HAVE_SYSTEMD_SD_LISTEN_FDS)
64        UNSET(HAVE_SYSTEMD_SD_NOTIFY)
65        UNSET(HAVE_SYSTEMD_SD_NOTIFYF)
66        MESSAGE_ONCE(systemd "Systemd features not enabled")
67        IF(WITH_SYSTEMD STREQUAL "yes")
68          MESSAGE(FATAL_ERROR "Requested WITH_SYSTEMD=yes however no dependencies installed/found")
69        ENDIF()
70      ENDIF()
71    ELSEIF(NOT WITH_SYSTEMD STREQUAL "no")
72      MESSAGE(FATAL_ERROR "Invalid value for WITH_SYSTEMD. Must be 'yes', 'no', or 'auto'.")
73    ENDIF()
74    ADD_FEATURE_INFO(SYSTEMD LIBSYSTEMD "Systemd scripts and notification support")
75  ENDIF()
76ENDMACRO()
77