1# Copyright (c) 2010, 2021, Oracle and/or its affiliates.
2#
3# This program is free software; you can redistribute it and/or modify
4# it under the terms of the GNU General Public License, version 2.0,
5# as published by the Free Software Foundation.
6#
7# This program is also distributed with certain software (including
8# but not limited to OpenSSL) that is licensed under separate terms,
9# as designated in a particular file or component or in included license
10# documentation.  The authors of MySQL hereby grant you an additional
11# permission to link the program and your derivative works with the
12# separately licensed software that they have included with MySQL.
13#
14# This program is distributed in the hope that it will be useful,
15# but WITHOUT ANY WARRANTY; without even the implied warranty of
16# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17# GNU General Public License, version 2.0, for more details.
18#
19# You should have received a copy of the GNU General Public License
20# along with this program; if not, write to the Free Software
21# Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
22
23# Produce meaningful package name for the binary package
24# The logic is rather involved with special cases for  different OSes
25
26MACRO(GET_PACKAGE_FILE_NAME Var)
27IF(NOT VERSION)
28    MESSAGE(FATAL_ERROR
29     "Variable VERSION needs to be set prior to calling GET_PACKAGE_FILE_NAME")
30  ENDIF()
31  IF(NOT SYSTEM_NAME_AND_PROCESSOR)
32    SET(NEED_DASH_BETWEEN_PLATFORM_AND_MACHINE 1)
33    SET(DEFAULT_PLATFORM ${CMAKE_SYSTEM_NAME})
34    SET(DEFAULT_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
35    IF(SIZEOF_VOIDP EQUAL 8)
36      SET(64BIT 1)
37    ENDIF()
38
39    IF(CMAKE_SYSTEM_NAME MATCHES "Windows")
40      SET(NEED_DASH_BETWEEN_PLATFORM_AND_MACHINE 0)
41      SET(DEFAULT_PLATFORM "win")
42      IF(64BIT)
43        SET(DEFAULT_MACHINE "x64")
44      ELSE()
45        SET(DEFAULT_MACHINE "32")
46      ENDIF()
47    ELSEIF(CMAKE_SYSTEM_NAME MATCHES "Linux")
48      IF(NOT 64BIT AND CMAKE_SYSTEM_PROCESSOR MATCHES "x86_64")
49        SET(DEFAULT_MACHINE "i686")
50      ENDIF()
51    ELSEIF(CMAKE_SYSTEM_NAME MATCHES "SunOS")
52      # SunOS 5.10=> solaris10
53      STRING(REPLACE "5." "" VER "${CMAKE_SYSTEM_VERSION}")
54      SET(DEFAULT_PLATFORM "solaris${VER}")
55      IF(64BIT)
56        IF(CMAKE_SYSTEM_PROCESSOR MATCHES "i386")
57          SET(DEFAULT_MACHINE "x86_64")
58        ELSE()
59          SET(DEFAULT_MACHINE "${CMAKE_SYSTEM_PROCESSOR}-64bit")
60        ENDIF()
61      ENDIF()
62    ELSEIF(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
63      STRING(REGEX MATCH "[0-9]+\\.[0-9]+"  VER "${CMAKE_SYSTEM_VERSION}")
64      SET(DEFAULT_PLATFORM "${CMAKE_SYSTEM_NAME}${VER}")
65      IF(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64")
66        SET(DEFAULT_MACHINE "x86_64")
67        IF(NOT 64BIT)
68          SET(DEFAULT_MACHINE "i386")
69        ENDIF()
70      ENDIF()
71    ELSEIF(CMAKE_SYSTEM_NAME MATCHES "Darwin")
72      IF(CMAKE_OSX_DEPLOYMENT_TARGET)
73        SET(DEFAULT_PLATFORM "osx${CMAKE_OSX_DEPLOYMENT_TARGET}")
74      ELSE()
75        SET(VER "${CMAKE_SYSTEM_VERSION}")
76        STRING(REGEX REPLACE "([0-9]+)\\.[0-9]+\\.[0-9]+" "\\1" VER "${VER}")
77        # Subtract 4 from Darwin version to get correct osx10.X
78        MATH(EXPR VER  "${VER} -4")
79        SET(DEFAULT_PLATFORM "osx10.${VER}")
80      ENDIF()
81
82      IF(CMAKE_OSX_ARCHITECTURES)
83        LIST(LENGTH CMAKE_OSX_ARCHITECTURES LEN)
84        IF(LEN GREATER 1)
85          SET(DEFAULT_MACHINE "universal")
86        ELSE()
87          SET(DEFAULT_MACHINE "${CMAKE_OSX_ARCHITECTURES}")
88        ENDIF()
89      ELSE()
90        IF(64BIT)
91          SET(DEFAULT_MACHINE "x86_64")
92        ENDIF()
93      ENDIF()
94
95      IF(DEFAULT_MACHINE MATCHES "i386")
96        SET(DEFAULT_MACHINE "x86")
97      ENDIF()
98    ENDIF()
99
100    IF(NOT PLATFORM)
101      SET(PLATFORM ${DEFAULT_PLATFORM})
102    ENDIF()
103    IF(NOT MACHINE)
104      SET(MACHINE ${DEFAULT_MACHINE})
105    ENDIF()
106
107    IF(NEED_DASH_BETWEEN_PLATFORM_AND_MACHINE)
108      SET(SYSTEM_NAME_AND_PROCESSOR "${PLATFORM}-${MACHINE}")
109    ELSE()
110      SET(SYSTEM_NAME_AND_PROCESSOR "${PLATFORM}${MACHINE}")
111    ENDIF()
112  ENDIF()
113
114  IF(SHORT_PRODUCT_TAG)
115    SET(PRODUCT_TAG "-${SHORT_PRODUCT_TAG}")
116  ELSEIF(MYSQL_SERVER_SUFFIX)
117    SET(PRODUCT_TAG "${MYSQL_SERVER_SUFFIX}")  # Already has a leading dash
118  ELSE()
119    SET(PRODUCT_TAG)
120  ENDIF()
121
122  IF("${VERSION}" MATCHES "-ndb-")
123    STRING(REGEX REPLACE "^.*-ndb-" "" NDBVERSION "${VERSION}")
124    SET(package_name "mysql-cluster${PRODUCT_TAG}-${NDBVERSION}-${SYSTEM_NAME_AND_PROCESSOR}")
125  ELSE()
126    SET(package_name "mysql${PRODUCT_TAG}-${VERSION}-${SYSTEM_NAME_AND_PROCESSOR}")
127  ENDIF()
128
129  MESSAGE(STATUS "Packaging as: ${package_name}")
130
131  # Sometimes package suffix is added (something like "-icc-glibc23")
132  IF(PACKAGE_SUFFIX)
133    SET(package_name "${package_name}${PACKAGE_SUFFIX}")
134  ENDIF()
135  STRING(TOLOWER ${package_name} package_name)
136  SET(${Var} ${package_name})
137ENDMACRO()
138