1# Qt network access module
2
3HEADERS += \
4    access/qnetworkaccessauthenticationmanager_p.h \
5    access/qnetworkaccessmanager.h \
6    access/qnetworkaccessmanager_p.h \
7    access/qnetworkaccesscache_p.h \
8    access/qnetworkaccessbackend_p.h \
9    access/qnetworkaccessdebugpipebackend_p.h \
10    access/qnetworkaccessfilebackend_p.h \
11    access/qnetworkaccesscachebackend_p.h \
12    access/qnetworkcookie.h \
13    access/qnetworkcookie_p.h \
14    access/qnetworkcookiejar.h \
15    access/qnetworkcookiejar_p.h \
16    access/qnetworkrequest.h \
17    access/qnetworkrequest_p.h \
18    access/qnetworkreply.h \
19    access/qnetworkreply_p.h \
20    access/qnetworkreplyimpl_p.h \
21    access/qnetworkreplydataimpl_p.h \
22    access/qnetworkreplyfileimpl_p.h \
23    access/qabstractnetworkcache_p.h \
24    access/qabstractnetworkcache.h \
25    access/qnetworkfile_p.h \
26    access/qhsts_p.h \
27    access/qhstspolicy.h
28
29SOURCES += \
30    access/qnetworkaccessauthenticationmanager.cpp \
31    access/qnetworkaccessmanager.cpp \
32    access/qnetworkaccesscache.cpp \
33    access/qnetworkaccessbackend.cpp \
34    access/qnetworkaccessdebugpipebackend.cpp \
35    access/qnetworkaccessfilebackend.cpp \
36    access/qnetworkaccesscachebackend.cpp \
37    access/qnetworkcookie.cpp \
38    access/qnetworkcookiejar.cpp \
39    access/qnetworkrequest.cpp \
40    access/qnetworkreply.cpp \
41    access/qnetworkreplyimpl.cpp \
42    access/qnetworkreplydataimpl.cpp \
43    access/qnetworkreplyfileimpl.cpp \
44    access/qabstractnetworkcache.cpp \
45    access/qnetworkfile.cpp \
46    access/qhsts.cpp \
47    access/qhstspolicy.cpp
48
49qtConfig(ftp) {
50    HEADERS += \
51        access/qftp_p.h \
52        access/qnetworkaccessftpbackend_p.h
53
54    SOURCES += \
55        access/qftp.cpp \
56        access/qnetworkaccessftpbackend.cpp
57}
58
59qtConfig(networkdiskcache) {
60    HEADERS += \
61        access/qnetworkdiskcache_p.h \
62        access/qnetworkdiskcache.h
63
64    SOURCES += access/qnetworkdiskcache.cpp
65}
66
67qtConfig(settings) {
68    HEADERS += \
69        access/qhstsstore_p.h
70
71    SOURCES += \
72        access/qhstsstore.cpp
73}
74
75mac: LIBS_PRIVATE += -framework Security
76
77wasm {
78    SOURCES += \
79        access/qnetworkreplywasmimpl.cpp
80    HEADERS += \
81        access/qnetworkreplywasmimpl_p.h
82}
83
84include($$PWD/../../3rdparty/zlib_dependency.pri)
85
86qtConfig(http) {
87    include($$PWD/http2/http2.pri)
88
89    SOURCES += \
90        access/qabstractprotocolhandler.cpp \
91        access/qhttp2protocolhandler.cpp \
92        access/qhttpmultipart.cpp \
93        access/qhttpnetworkconnection.cpp \
94        access/qhttpnetworkconnectionchannel.cpp \
95        access/qhttpnetworkheader.cpp \
96        access/qhttpnetworkreply.cpp \
97        access/qhttpnetworkrequest.cpp \
98        access/qhttpprotocolhandler.cpp \
99        access/qhttpthreaddelegate.cpp \
100        access/qnetworkreplyhttpimpl.cpp \
101        access/qhttp2configuration.cpp
102
103    HEADERS += \
104        access/qabstractprotocolhandler_p.h \
105        access/qhttp2protocolhandler_p.h \
106        access/qhttpmultipart.h \
107        access/qhttpmultipart_p.h \
108        access/qhttpnetworkconnection_p.h \
109        access/qhttpnetworkconnectionchannel_p.h \
110        access/qhttpnetworkheader_p.h \
111        access/qhttpnetworkreply_p.h \
112        access/qhttpnetworkrequest_p.h \
113        access/qhttpprotocolhandler_p.h \
114        access/qhttpthreaddelegate_p.h \
115        access/qnetworkreplyhttpimpl_p.h \
116        access/qhttp2configuration.h
117
118    qtConfig(ssl) {
119        SOURCES += \
120            access/qspdyprotocolhandler.cpp
121        HEADERS += \
122            access/qspdyprotocolhandler_p.h
123    }
124}
125