1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4#[=======================================================================[.rst:
5FindSDL_image
6-------------
7
8Locate SDL_image library
9
10This module defines:
11
12::
13
14  SDL_IMAGE_LIBRARIES, the name of the library to link against
15  SDL_IMAGE_INCLUDE_DIRS, where to find the headers
16  SDL_IMAGE_FOUND, if false, do not try to link against
17  SDL_IMAGE_VERSION_STRING - human-readable string containing the
18                             version of SDL_image
19
20
21
22For backward compatibility the following variables are also set:
23
24::
25
26  SDLIMAGE_LIBRARY (same value as SDL_IMAGE_LIBRARIES)
27  SDLIMAGE_INCLUDE_DIR (same value as SDL_IMAGE_INCLUDE_DIRS)
28  SDLIMAGE_FOUND (same value as SDL_IMAGE_FOUND)
29
30
31
32$SDLDIR is an environment variable that would correspond to the
33./configure --prefix=$SDLDIR used in building SDL.
34
35Created by Eric Wing.  This was influenced by the FindSDL.cmake
36module, but with modifications to recognize OS X frameworks and
37additional Unix paths (FreeBSD, etc).
38#]=======================================================================]
39
40if(NOT SDL_IMAGE_INCLUDE_DIR AND SDLIMAGE_INCLUDE_DIR)
41  set(SDL_IMAGE_INCLUDE_DIR ${SDLIMAGE_INCLUDE_DIR} CACHE PATH "directory cache
42entry initialized from old variable name")
43endif()
44find_path(SDL_IMAGE_INCLUDE_DIR SDL_image.h
45  HINTS
46    ENV SDLIMAGEDIR
47    ENV SDLDIR
48  PATH_SUFFIXES SDL
49                # path suffixes to search inside ENV{SDLDIR}
50                include/SDL include/SDL12 include/SDL11 include
51)
52
53if(CMAKE_SIZEOF_VOID_P EQUAL 8)
54  set(VC_LIB_PATH_SUFFIX lib/x64)
55else()
56  set(VC_LIB_PATH_SUFFIX lib/x86)
57endif()
58
59if(NOT SDL_IMAGE_LIBRARY AND SDLIMAGE_LIBRARY)
60  set(SDL_IMAGE_LIBRARY ${SDLIMAGE_LIBRARY} CACHE FILEPATH "file cache entry
61initialized from old variable name")
62endif()
63find_library(SDL_IMAGE_LIBRARY
64  NAMES SDL_image
65  HINTS
66    ENV SDLIMAGEDIR
67    ENV SDLDIR
68  PATH_SUFFIXES lib ${VC_LIB_PATH_SUFFIX}
69)
70
71if(SDL_IMAGE_INCLUDE_DIR AND EXISTS "${SDL_IMAGE_INCLUDE_DIR}/SDL_image.h")
72  file(STRINGS "${SDL_IMAGE_INCLUDE_DIR}/SDL_image.h" SDL_IMAGE_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_IMAGE_MAJOR_VERSION[ \t]+[0-9]+$")
73  file(STRINGS "${SDL_IMAGE_INCLUDE_DIR}/SDL_image.h" SDL_IMAGE_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_IMAGE_MINOR_VERSION[ \t]+[0-9]+$")
74  file(STRINGS "${SDL_IMAGE_INCLUDE_DIR}/SDL_image.h" SDL_IMAGE_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_IMAGE_PATCHLEVEL[ \t]+[0-9]+$")
75  string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_IMAGE_VERSION_MAJOR "${SDL_IMAGE_VERSION_MAJOR_LINE}")
76  string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_IMAGE_VERSION_MINOR "${SDL_IMAGE_VERSION_MINOR_LINE}")
77  string(REGEX REPLACE "^#define[ \t]+SDL_IMAGE_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL_IMAGE_VERSION_PATCH "${SDL_IMAGE_VERSION_PATCH_LINE}")
78  set(SDL_IMAGE_VERSION_STRING ${SDL_IMAGE_VERSION_MAJOR}.${SDL_IMAGE_VERSION_MINOR}.${SDL_IMAGE_VERSION_PATCH})
79  unset(SDL_IMAGE_VERSION_MAJOR_LINE)
80  unset(SDL_IMAGE_VERSION_MINOR_LINE)
81  unset(SDL_IMAGE_VERSION_PATCH_LINE)
82  unset(SDL_IMAGE_VERSION_MAJOR)
83  unset(SDL_IMAGE_VERSION_MINOR)
84  unset(SDL_IMAGE_VERSION_PATCH)
85endif()
86
87set(SDL_IMAGE_LIBRARIES ${SDL_IMAGE_LIBRARY})
88set(SDL_IMAGE_INCLUDE_DIRS ${SDL_IMAGE_INCLUDE_DIR})
89
90include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
91
92FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL_image
93                                  REQUIRED_VARS SDL_IMAGE_LIBRARIES SDL_IMAGE_INCLUDE_DIRS
94                                  VERSION_VAR SDL_IMAGE_VERSION_STRING)
95
96# for backward compatibility
97set(SDLIMAGE_LIBRARY ${SDL_IMAGE_LIBRARIES})
98set(SDLIMAGE_INCLUDE_DIR ${SDL_IMAGE_INCLUDE_DIRS})
99set(SDLIMAGE_FOUND ${SDL_IMAGE_FOUND})
100
101mark_as_advanced(SDL_IMAGE_LIBRARY SDL_IMAGE_INCLUDE_DIR)
102