1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4#[=======================================================================[.rst:
5FindSDL_net
6-----------
7
8Locate SDL_net library
9
10This module defines:
11
12::
13
14  SDL_NET_LIBRARIES, the name of the library to link against
15  SDL_NET_INCLUDE_DIRS, where to find the headers
16  SDL_NET_FOUND, if false, do not try to link against
17  SDL_NET_VERSION_STRING - human-readable string containing the version of SDL_net
18
19
20
21For backward compatibility the following variables are also set:
22
23::
24
25  SDLNET_LIBRARY (same value as SDL_NET_LIBRARIES)
26  SDLNET_INCLUDE_DIR (same value as SDL_NET_INCLUDE_DIRS)
27  SDLNET_FOUND (same value as SDL_NET_FOUND)
28
29
30
31$SDLDIR is an environment variable that would correspond to the
32./configure --prefix=$SDLDIR used in building SDL.
33
34Created by Eric Wing.  This was influenced by the FindSDL.cmake
35module, but with modifications to recognize OS X frameworks and
36additional Unix paths (FreeBSD, etc).
37#]=======================================================================]
38
39if(NOT SDL_NET_INCLUDE_DIR AND SDLNET_INCLUDE_DIR)
40  set(SDL_NET_INCLUDE_DIR ${SDLNET_INCLUDE_DIR} CACHE PATH "directory cache
41entry initialized from old variable name")
42endif()
43find_path(SDL_NET_INCLUDE_DIR SDL_net.h
44  HINTS
45    ENV SDLNETDIR
46    ENV SDLDIR
47  PATH_SUFFIXES SDL
48                # path suffixes to search inside ENV{SDLDIR}
49                include/SDL include/SDL12 include/SDL11 include
50)
51
52if(CMAKE_SIZEOF_VOID_P EQUAL 8)
53  set(VC_LIB_PATH_SUFFIX lib/x64)
54else()
55  set(VC_LIB_PATH_SUFFIX lib/x86)
56endif()
57
58if(NOT SDL_NET_LIBRARY AND SDLNET_LIBRARY)
59  set(SDL_NET_LIBRARY ${SDLNET_LIBRARY} CACHE FILEPATH "file cache entry
60initialized from old variable name")
61endif()
62find_library(SDL_NET_LIBRARY
63  NAMES SDL_net
64  HINTS
65    ENV SDLNETDIR
66    ENV SDLDIR
67  PATH_SUFFIXES lib ${VC_LIB_PATH_SUFFIX}
68)
69
70if(SDL_NET_INCLUDE_DIR AND EXISTS "${SDL_NET_INCLUDE_DIR}/SDL_net.h")
71  file(STRINGS "${SDL_NET_INCLUDE_DIR}/SDL_net.h" SDL_NET_VERSION_MAJOR_LINE REGEX "^#define[ \t]+SDL_NET_MAJOR_VERSION[ \t]+[0-9]+$")
72  file(STRINGS "${SDL_NET_INCLUDE_DIR}/SDL_net.h" SDL_NET_VERSION_MINOR_LINE REGEX "^#define[ \t]+SDL_NET_MINOR_VERSION[ \t]+[0-9]+$")
73  file(STRINGS "${SDL_NET_INCLUDE_DIR}/SDL_net.h" SDL_NET_VERSION_PATCH_LINE REGEX "^#define[ \t]+SDL_NET_PATCHLEVEL[ \t]+[0-9]+$")
74  string(REGEX REPLACE "^#define[ \t]+SDL_NET_MAJOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_NET_VERSION_MAJOR "${SDL_NET_VERSION_MAJOR_LINE}")
75  string(REGEX REPLACE "^#define[ \t]+SDL_NET_MINOR_VERSION[ \t]+([0-9]+)$" "\\1" SDL_NET_VERSION_MINOR "${SDL_NET_VERSION_MINOR_LINE}")
76  string(REGEX REPLACE "^#define[ \t]+SDL_NET_PATCHLEVEL[ \t]+([0-9]+)$" "\\1" SDL_NET_VERSION_PATCH "${SDL_NET_VERSION_PATCH_LINE}")
77  set(SDL_NET_VERSION_STRING ${SDL_NET_VERSION_MAJOR}.${SDL_NET_VERSION_MINOR}.${SDL_NET_VERSION_PATCH})
78  unset(SDL_NET_VERSION_MAJOR_LINE)
79  unset(SDL_NET_VERSION_MINOR_LINE)
80  unset(SDL_NET_VERSION_PATCH_LINE)
81  unset(SDL_NET_VERSION_MAJOR)
82  unset(SDL_NET_VERSION_MINOR)
83  unset(SDL_NET_VERSION_PATCH)
84endif()
85
86set(SDL_NET_LIBRARIES ${SDL_NET_LIBRARY})
87set(SDL_NET_INCLUDE_DIRS ${SDL_NET_INCLUDE_DIR})
88
89include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
90
91FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL_net
92                                  REQUIRED_VARS SDL_NET_LIBRARIES SDL_NET_INCLUDE_DIRS
93                                  VERSION_VAR SDL_NET_VERSION_STRING)
94
95# for backward compatibility
96set(SDLNET_LIBRARY ${SDL_NET_LIBRARIES})
97set(SDLNET_INCLUDE_DIR ${SDL_NET_INCLUDE_DIRS})
98set(SDLNET_FOUND ${SDL_NET_FOUND})
99
100mark_as_advanced(SDL_NET_LIBRARY SDL_NET_INCLUDE_DIR)
101