1# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
2# file Copyright.txt or https://cmake.org/licensing for details.
3
4#[=======================================================================[.rst:
5FindTclsh
6---------
7
8Find tclsh
9
10This module finds if TCL is installed and determines where the include
11files and libraries are.  It also determines what the name of the
12library is.  This code sets the following variables:
13
14::
15
16  TCLSH_FOUND = TRUE if tclsh has been found
17  TCL_TCLSH = the path to the tclsh executable
18#]=======================================================================]
19
20get_filename_component(TK_WISH_PATH "${TK_WISH}" PATH)
21get_filename_component(TK_WISH_PATH_PARENT "${TK_WISH_PATH}" PATH)
22string(REGEX REPLACE
23  "^.*wish([0-9]\\.*[0-9]).*$" "\\1" TK_WISH_VERSION "${TK_WISH}")
24
25get_filename_component(TCL_INCLUDE_PATH_PARENT "${TCL_INCLUDE_PATH}" PATH)
26get_filename_component(TK_INCLUDE_PATH_PARENT "${TK_INCLUDE_PATH}" PATH)
27
28get_filename_component(TCL_LIBRARY_PATH "${TCL_LIBRARY}" PATH)
29get_filename_component(TCL_LIBRARY_PATH_PARENT "${TCL_LIBRARY_PATH}" PATH)
30string(REGEX REPLACE
31  "^.*tcl([0-9]\\.*[0-9]).*$" "\\1" TCL_LIBRARY_VERSION "${TCL_LIBRARY}")
32
33get_filename_component(TK_LIBRARY_PATH "${TK_LIBRARY}" PATH)
34get_filename_component(TK_LIBRARY_PATH_PARENT "${TK_LIBRARY_PATH}" PATH)
35string(REGEX REPLACE
36  "^.*tk([0-9]\\.*[0-9]).*$" "\\1" TK_LIBRARY_VERSION "${TK_LIBRARY}")
37
38set(TCLTK_POSSIBLE_BIN_PATHS
39  "${TCL_INCLUDE_PATH_PARENT}/bin"
40  "${TK_INCLUDE_PATH_PARENT}/bin"
41  "${TCL_LIBRARY_PATH_PARENT}/bin"
42  "${TK_LIBRARY_PATH_PARENT}/bin"
43  "${TK_WISH_PATH_PARENT}/bin"
44  )
45
46if(WIN32)
47  get_filename_component(
48    ActiveTcl_CurrentVersion
49    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\ActiveState\\ActiveTcl;CurrentVersion]"
50    NAME)
51  set(TCLTK_POSSIBLE_BIN_PATHS ${TCLTK_POSSIBLE_BIN_PATHS}
52    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\ActiveState\\ActiveTcl\\${ActiveTcl_CurrentVersion}]/bin"
53    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.6;Root]/bin"
54    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.5;Root]/bin"
55    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.4;Root]/bin"
56    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.3;Root]/bin"
57    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.2;Root]/bin"
58    "[HKEY_LOCAL_MACHINE\\SOFTWARE\\Scriptics\\Tcl\\8.0;Root]/bin"
59    )
60endif()
61
62set(TCL_TCLSH_NAMES
63  tclsh
64  tclsh${TCL_LIBRARY_VERSION} tclsh${TK_LIBRARY_VERSION} tclsh${TK_WISH_VERSION}
65  tclsh87 tclsh8.7
66  tclsh86 tclsh8.6
67  tclsh85 tclsh8.5
68  tclsh84 tclsh8.4
69  tclsh83 tclsh8.3
70  tclsh82 tclsh8.2
71  tclsh80 tclsh8.0
72  )
73
74find_program(TCL_TCLSH
75  NAMES ${TCL_TCLSH_NAMES}
76  HINTS ${TCLTK_POSSIBLE_BIN_PATHS}
77  )
78
79if(TCL_TCLSH)
80  execute_process(COMMAND "${CMAKE_COMMAND}" -E echo puts "\$tcl_version"
81                  COMMAND "${TCL_TCLSH}"
82                  OUTPUT_VARIABLE TCLSH_VERSION_STRING
83                  ERROR_QUIET
84                  OUTPUT_STRIP_TRAILING_WHITESPACE)
85endif()
86
87include(${CMAKE_CURRENT_LIST_DIR}/FindPackageHandleStandardArgs.cmake)
88if (CMAKE_FIND_PACKAGE_NAME STREQUAL "TCL" OR
89    CMAKE_FIND_PACKAGE_NAME STREQUAL "TclStub")
90  # FindTCL include()'s this module. It's an old pattern, but rather than
91  # trying to suppress this from outside the module (which is then sensitive to
92  # the contents, detect the case in this module and suppress it explicitly.
93  # Transitively, FindTclStub includes FindTCL.
94  set(FPHSA_NAME_MISMATCHED 1)
95endif ()
96FIND_PACKAGE_HANDLE_STANDARD_ARGS(Tclsh
97                                  REQUIRED_VARS TCL_TCLSH
98                                  VERSION_VAR TCLSH_VERSION_STRING)
99unset(FPHSA_NAME_MISMATCHED)
100
101mark_as_advanced(TCL_TCLSH)
102