1# Author: williamjcm <w.jcm59@gmail.com>
2# Contributor: mosra <mosra@centrum.cz>
3# Based on the Corrade Arch Linux PKGBUILD maintained by xyproto and the MSYS2/MinGW PKGBUILD templates
4
5_realname=corrade
6pkgbase=mingw-w64-${_realname}
7pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}"
8pkgver=2019.10
9pkgrel=1
10pkgdesc='C++11/C++14 multiplatform utility library'
11arch=('any')
12url='https://magnum.graphics/corrade/'
13license=('MIT')
14makedepends=("${MINGW_PACKAGE_PREFIX}-cmake" "${MINGW_PACKAGE_PREFIX}-ninja" 'git')
15# The .tar.gz / .zip download contains symlinks (.travis.yml), making tar and
16# unzip on Windows grumpy because dangling symlinks are created. Could be fixed
17# by manually extracting everything except symlinks, but that's hard to
18# maintain. Downloading a Git tag works.
19source=("${_realname}-${pkgver}"::"git+https://github.com/mosra/corrade.git#tag=v$pkgver")
20sha1sums=('SKIP')
21
22build() {
23    mkdir -p "${srcdir}"/build-${CARCH} && cd "${srcdir}"/build-${CARCH}
24
25    declare -a extra_config
26    if check_option "debug" "n"; then
27        extra_config+=("-DCMAKE_BUILD_TYPE=Release")
28    else
29        extra_config+=("-DCMAKE_BUILD_TYPE=Debug")
30    fi
31
32    MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
33        ${MINGW_PREFIX}/bin/cmake \
34            -G'Ninja' \
35            -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
36            "${extra_config[@]}" \
37            ../${_realname}-${pkgver}
38    ninja
39}
40
41package() {
42    cd "${srcdir}"/build-${CARCH}
43    DESTDIR="${pkgdir}" ninja install
44
45    install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" \
46        "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING"
47}
48