1dnl GP_CHECK_CPPCHECK
2dnl Checks for cppcheck
3AC_DEFUN([GP_CHECK_CPPCHECK],
4[
5    AC_ARG_ENABLE([cppcheck],
6                  AS_HELP_STRING([--enable-cppcheck],
7                                 [use cppcheck to check the source code
8                                  @<:@default=auto@:>@]),
9                  [enable_cppcheck="$enableval"],
10                  [enable_cppcheck="auto"])
11
12    gp_have_cppcheck=no
13    AS_IF([test "x$enable_cppcheck" != xno],
14          [AC_PATH_PROG([CPPCHECK], [cppcheck], [NONE])
15           AS_IF([test "x$CPPCHECK" != xNONE],
16                 [gp_have_cppcheck=yes
17                  AC_SUBST([CPPCHECK])],
18                 [gp_have_cppcheck=no
19                  AS_IF([test "x$enable_cppcheck" != xauto],
20                        [AC_MSG_ERROR([cannot find cppcheck])])])])
21    AM_CONDITIONAL([HAVE_CPPCHECK], [test "x$gp_have_cppcheck" = xyes])
22    GP_STATUS_BUILD_FEATURE_ADD([Static code checking],
23                                [$gp_have_cppcheck])
24
25    GP_GEANY_PKG_CONFIG_PATH_PUSH
26    PKG_CHECK_VAR([GEANY_INCLUDEDIR], [geany], [includedir], [], [])
27    GP_GEANY_PKG_CONFIG_PATH_POP
28])
29