1
2#global defaults
3qtPrepareTool(QMAKE_MOC, moc)
4isEmpty(MOC_DIR):MOC_DIR = .
5isEmpty(QMAKE_H_MOD_MOC):QMAKE_H_MOD_MOC = moc_
6isEmpty(QMAKE_EXT_CPP_MOC):QMAKE_EXT_CPP_MOC = .moc
7
8MOC_INCLUDEPATH =
9for (inc, INCLUDEPATH): \
10    MOC_INCLUDEPATH += $$absolute_path($$inc, $$_PRO_FILE_PWD_)
11!no_include_pwd:!isEqual(OUT_PWD, $$_PRO_FILE_PWD_): \
12    MOC_INCLUDEPATH += .
13MOC_INCLUDEPATH = $$QMAKESPEC $$_PRO_FILE_PWD_ $$MOC_INCLUDEPATH $$QMAKE_DEFAULT_INCDIRS
14
15# On Windows, put the includes into a .inc file which moc will read, if the project
16# has too many includes. We do this to overcome a command-line limit on Win < XP
17WIN_INCLUDETEMP=
18win32:count(MOC_INCLUDEPATH, 40, >) {
19    WIN_INCLUDETEMP = $$MOC_DIR/mocinclude.opt
20
21    WIN_INCLUDETEMP_CONT =
22    for (inc, MOC_INCLUDEPATH): \
23        WIN_INCLUDETEMP_CONT += -I$$inc
24    write_file($$absolute_path($$WIN_INCLUDETEMP, $$OUT_PWD), WIN_INCLUDETEMP_CONT)|error()
25}
26
27# QNX's compiler sets "gcc" config, but does not support the -dM option;
28# UIKit builds are always multi-arch due to simulator_and_device (unless
29# -sdk is used) so this feature cannot possibly work.
30if(gcc|intel_icl|msvc):!rim_qcc:!uikit:!no_moc_predefs:if(!macos|count(QMAKE_APPLE_DEVICE_ARCHS, 1)) {
31    moc_predefs.name = "Generate moc_predefs.h"
32    moc_predefs.CONFIG = no_link
33    gcc:            moc_predefs.commands = $$QMAKE_CXX $$QMAKE_CXXFLAGS -dM -E -o ${QMAKE_FILE_OUT} ${QMAKE_FILE_IN}
34    else:intel_icl: moc_predefs.commands = $$QMAKE_CXX $$QMAKE_CXXFLAGS -QdM -P -Fi${QMAKE_FILE_OUT} ${QMAKE_FILE_IN}
35    else:msvc {
36        moc_predefs.commands += $$QMAKE_CXX -Bx$$shell_quote($$shell_path($$QMAKE_QMAKE)) $$QMAKE_CXXFLAGS \
37                                    -E ${QMAKE_FILE_IN} 2>NUL >${QMAKE_FILE_OUT}
38    } else:         error("Oops, I messed up")
39    moc_predefs.output = $$MOC_DIR/moc_predefs.h
40    moc_predefs.input = MOC_PREDEF_FILE
41    silent: moc_predefs.commands = @echo generating $$moc_predefs.output$$escape_expand(\\n\\t)@$$moc_predefs.commands
42    QMAKE_EXTRA_COMPILERS += moc_predefs
43    MOC_PREDEF_FILE = $$[QT_HOST_DATA/src]/mkspecs/features/data/dummy.cpp
44}
45
46defineReplace(mocCmdBase) {
47    !isEmpty(WIN_INCLUDETEMP) {
48        incvar = @$$shell_quote($$WIN_INCLUDETEMP)
49    } else {
50        incvar =
51        for (inc, MOC_INCLUDEPATH): \
52            incvar += -I$$shell_quote($$inc)
53        incvar += $$QMAKE_FRAMEWORKPATH_FLAGS
54    }
55
56    RET = $$QMAKE_MOC $(DEFINES)
57    msvc: RET += --compiler-flavor=msvc
58
59    isEmpty(MOC_PREDEF_FILE): RET += $$join(QMAKE_COMPILER_DEFINES, " -D", -D)
60    else: RET += --include $$shell_quote($$absolute_path($$moc_predefs.output, $$OUT_PWD))
61
62    RET += $$incvar $$QMAKE_MOC_OPTIONS
63    return($$RET)
64}
65
66#moc headers
67moc_header.CONFIG = moc_verify
68moc_header.dependency_type = TYPE_C
69moc_header.commands = ${QMAKE_FUNC_mocCmdBase} ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
70moc_header.output = $$MOC_DIR/$${QMAKE_H_MOD_MOC}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_CPP)}
71moc_header.input = HEADERS
72moc_header.variable_out = SOURCES
73moc_header.name = MOC ${QMAKE_FILE_IN}
74moc_header.depends += $$WIN_INCLUDETEMP $$moc_predefs.output
75silent:moc_header.commands = @echo moc ${QMAKE_FILE_IN} && $$moc_header.commands
76QMAKE_EXTRA_COMPILERS += moc_header
77INCREDIBUILD_XGE += moc_header
78
79#moc objc headers
80moc_objc_header.CONFIG = moc_verify
81moc_objc_header.dependency_type = TYPE_C
82moc_objc_header.commands = ${QMAKE_FUNC_mocCmdBase} ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
83moc_objc_header.output = $$MOC_DIR/$${QMAKE_H_MOD_MOC}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJCXX)}
84moc_objc_header.input = OBJECTIVE_HEADERS
85moc_objc_header.variable_out = SOURCES
86moc_objc_header.name = MOC ${QMAKE_FILE_IN}
87moc_objc_header.depends += $$WIN_INCLUDETEMP $$moc_predefs.output
88silent:moc_objc_header.commands = @echo moc ${QMAKE_FILE_IN} && $$moc_objc_header.commands
89QMAKE_EXTRA_COMPILERS += moc_objc_header
90INCREDIBUILD_XGE += moc_objc_header
91
92#moc sources
93moc_source.CONFIG = no_link moc_verify
94moc_source.dependency_type = TYPE_C
95moc_source.commands = ${QMAKE_FUNC_mocCmdBase} ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
96moc_source.output = $$MOC_DIR/$${QMAKE_CPP_MOD_MOC}${QMAKE_FILE_BASE}$${QMAKE_EXT_CPP_MOC}
97moc_source.input = SOURCES
98moc_source.name = MOC ${QMAKE_FILE_IN}
99moc_source.depends += $$WIN_INCLUDETEMP $$moc_predefs.output
100silent:moc_source.commands = @echo moc ${QMAKE_FILE_IN} && $$moc_source.commands
101QMAKE_EXTRA_COMPILERS += moc_source
102INCREDIBUILD_XGE += moc_source
103
104#make sure we can include these files
105INCLUDEPATH += $$absolute_path($$MOC_DIR, $$OUT_PWD)
106
107#auto depend on moc
108!no_mocdepend {
109     moc_source.depends += $$QMAKE_MOC_EXE
110     moc_header.depends += $$QMAKE_MOC_EXE
111     moc_objc_header.depends += $$QMAKE_MOC_EXE
112}
113
114#generate a mocclean
115build_pass|isEmpty(BUILDS):mocclean.depends = compiler_moc_header_clean compiler_moc_objc_header_clean compiler_moc_source_clean
116else:mocclean.CONFIG += recursive
117QMAKE_EXTRA_TARGETS += mocclean
118
119#generate a mocables
120build_pass|isEmpty(BUILDS):mocables.depends = compiler_moc_header_make_all compiler_moc_objc_header_make_all compiler_moc_source_make_all
121else:mocables.CONFIG += recursive
122QMAKE_EXTRA_TARGETS += mocables
123