1# Process this file with autoreconf to produce a configure script.
2
3AC_PREREQ(2.64)
4AC_INIT(package-unused, version-unused,, libstdc++)
5AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
6AC_CONFIG_HEADER(config.h)
7
8# This works around the fact that libtool configuration may change LD
9# for this particular configuration, but some shells, instead of
10# keeping the changes in LD private, export them just because LD is
11# exported.  Only used at the end of this file.
12### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
13
14# Find the rest of the source tree framework.
15AM_ENABLE_MULTILIB(, ..)
16
17# Gets build, host, target, *_vendor, *_cpu, *_os, etc.
18#
19# You will slowly go insane if you do not grok the following fact:  when
20# building v3 as part of the compiler, the top-level /target/ becomes the
21# library's /host/.  configure then causes --target to default to --host,
22# exactly like any other package using autoconf.  Therefore, 'target' and
23# 'host' will always be the same.  This makes sense both for native and
24# cross compilers, just think about it for a little while.  :-)
25#
26# Also, if v3 is being configured as part of a cross compiler, the top-level
27# configure script will pass the "real" host as $with_cross_host.
28#
29# Do not delete or change the following two lines.  For why, see
30# http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
31AC_CANONICAL_SYSTEM
32target_alias=${target_alias-$host_alias}
33
34# Handy for debugging:
35#AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
36
37if test "$build" != "$host"; then
38  # We are being configured with some form of cross compiler.
39  GLIBCXX_IS_NATIVE=false
40  case "$host","$target" in
41    # Darwin crosses can use the host system's libraries and headers,
42    # because of the fat library support.  Of course, it must be the
43    # same version of Darwin on both sides.  Allow the user to
44    # just say --target=foo-darwin without a version number to mean
45    # "the version on this system".
46      *-*-darwin*,*-*-darwin*)
47	hostos=`echo $host | sed 's/.*-darwin/darwin/'`
48	targetos=`echo $target | sed 's/.*-darwin/darwin/'`
49	if test $hostos = $targetos -o $targetos = darwin ; then
50	  GLIBCXX_IS_NATIVE=true
51	fi
52	;;
53
54      *)
55	GCC_NO_EXECUTABLES
56	;;
57  esac
58else
59  GLIBCXX_IS_NATIVE=true
60fi
61
62# Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
63# following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
64#  1.x:  minimum required version
65#  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
66#              of other PACKAGE_* variables will, however, and there's nothing
67#              we can do about that; they come from AC_INIT).
68#  foreign:  we don't follow the normal rules for GNU packages (no COPYING
69#            file in the top srcdir, etc, etc), so stop complaining.
70#  no-dependencies:  turns off auto dependency generation (just for now)
71#  no-dist:  we don't want 'dist' and related rules.
72#  -Wall:  turns on all automake warnings...
73#  -Wno-portability:  ...except this one, since GNU make is now required.
74AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
75AH_TEMPLATE(PACKAGE, [Name of package])
76AH_TEMPLATE(VERSION, [Version number of package])
77
78# -fno-builtin must be present here so that a non-conflicting form of
79# std::exit can be guessed by AC_PROG_CXX, and used in later tests.
80
81save_CXXFLAGS="$CXXFLAGS"
82CXXFLAGS="$CXXFLAGS -fno-builtin"
83AC_PROG_CC
84AC_PROG_CXX
85CXXFLAGS="$save_CXXFLAGS"
86
87# Runs configure.host, and assorted other critical bits.  Sets
88# up critical shell variables.
89GLIBCXX_CONFIGURE
90
91# Libtool setup.
92if test "x${with_newlib}" != "xyes"; then
93  AC_LIBTOOL_DLOPEN
94fi
95AM_PROG_LIBTOOL
96ACX_LT_HOST_FLAGS
97AC_SUBST(enable_shared)
98AC_SUBST(enable_static)
99
100if test "$enable_vtable_verify" = yes; then
101  predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
102  postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
103fi
104
105
106# libtool variables for C++ shared and position-independent compiles.
107#
108# Use glibcxx_lt_pic_flag to designate the automake variable
109# used to encapsulate the default libtool approach to creating objects
110# with position-independent code. Default: -prefer-pic.
111#
112# Use glibcxx_compiler_shared_flag to designate a compile-time flags for
113# creating shared objects. Default: -D_GLIBCXX_SHARED.
114#
115# Use glibcxx_compiler_pic_flag to designate a compile-time flags for
116# creating position-independent objects. This varies with the target
117# hardware and operating system, but is often: -DPIC -fPIC.
118if test "$enable_shared" = yes; then
119  glibcxx_lt_pic_flag="-prefer-pic"
120  glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
121  glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
122
123else
124  glibcxx_lt_pic_flag=
125  glibcxx_compiler_pic_flag=
126  glibcxx_compiler_shared_flag=
127fi
128AC_SUBST(glibcxx_lt_pic_flag)
129AC_SUBST(glibcxx_compiler_pic_flag)
130AC_SUBST(glibcxx_compiler_shared_flag)
131
132# Override the libtool's pic_flag and pic_mode.
133# Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
134# NB: this impacts --with-pic and --without-pic.
135lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
136pic_mode='default'
137
138# Eliminate -lstdc++ addition to postdeps for cross compiles.
139postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
140
141# Possibly disable most of the library.
142## TODO: Consider skipping unncessary tests altogether in this case, rather
143## than just ignoring the results.  Faster /and/ more correct, win win.
144GLIBCXX_ENABLE_HOSTED
145
146# Enable descriptive messages to standard output on termination.
147GLIBCXX_ENABLE_VERBOSE
148
149# Enable compiler support that doesn't require linking.
150GLIBCXX_ENABLE_PCH($is_hosted)
151GLIBCXX_ENABLE_THREADS
152GLIBCXX_ENABLE_ATOMIC_BUILTINS
153GLIBCXX_ENABLE_DECIMAL_FLOAT
154GLIBCXX_ENABLE_INT128_FLOAT128
155if test "$enable_float128" = yes; then
156  port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
157fi
158
159# Checks for compiler support that doesn't require linking.
160GLIBCXX_CHECK_COMPILER_FEATURES
161
162# Enable all the variable C++ runtime options that don't require linking.
163GLIBCXX_ENABLE_CSTDIO
164GLIBCXX_ENABLE_CLOCALE
165GLIBCXX_ENABLE_ALLOCATOR
166GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
167GLIBCXX_ENABLE_LONG_LONG([yes])
168GLIBCXX_ENABLE_WCHAR_T([yes])
169GLIBCXX_ENABLE_C99([yes])
170GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
171GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
172GLIBCXX_ENABLE_DEBUG([no])
173GLIBCXX_ENABLE_PARALLEL([yes])
174GLIBCXX_ENABLE_CXX_FLAGS
175GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
176GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
177GLIBCXX_ENABLE_PYTHON
178GLIBCXX_ENABLE_WERROR([yes])
179GLIBCXX_ENABLE_VTABLE_VERIFY([no])
180
181# Checks for operating systems support that doesn't require linking.
182GLIBCXX_CHECK_STDIO_PROTO
183GLIBCXX_CHECK_MATH11_PROTO
184GLIBCXX_CHECK_SYSTEM_ERROR
185GLIBCXX_CHECK_UCHAR_H
186
187# For the streamoff typedef.
188GLIBCXX_CHECK_INT64_T
189
190# For LFS support.
191GLIBCXX_CHECK_LFS
192
193# For showmanyc_helper().
194AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
195GLIBCXX_CHECK_POLL
196GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
197
198# For xsputn_2().
199AC_CHECK_HEADERS(sys/uio.h)
200GLIBCXX_CHECK_WRITEV
201
202# Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
203# so that the check is done with the C compiler (not C++).
204# Checking with C++ can break a canadian cross build if either
205# file does not exist in C but does in C++.
206AC_CHECK_HEADERS(fenv.h complex.h)
207
208# For C99 support to TR1.
209GLIBCXX_CHECK_C99_TR1
210
211# For the EOF, SEEK_CUR, and SEEK_END integer constants.
212GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
213
214# For gettimeofday support.
215GLIBCXX_CHECK_GETTIMEOFDAY
216
217# For clock_gettime, nanosleep and sched_yield support.
218GLIBCXX_ENABLE_LIBSTDCXX_TIME
219
220# Check for tmpnam which is obsolescent in POSIX.1-2008
221GLIBCXX_CHECK_TMPNAM
222
223AC_LC_MESSAGES
224
225# For hardware_concurrency
226AC_CHECK_HEADERS(sys/sysinfo.h)
227GLIBCXX_CHECK_GET_NPROCS
228AC_CHECK_HEADERS(unistd.h)
229GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
230GLIBCXX_CHECK_SC_NPROC_ONLN
231GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
232GLIBCXX_CHECK_SYSCTL_HW_NCPU
233GLIBCXX_CHECK_SDT_H
234
235# Check for available headers.
236AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
237locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
238strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
239sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
240wchar.h wctype.h linux/types.h])
241
242AC_CHECK_HEADERS([linux/random.h], [], [],
243[[#ifdef HAVE_LINUX_TYPES_H
244# include <linux/types.h>
245#endif
246]])
247
248# Only do link tests if native. Else, hardcode.
249if $GLIBCXX_IS_NATIVE; then
250
251  # We can do more elaborate tests that assume a working linker.
252  CANADIAN=no
253
254  GLIBCXX_CHECK_LINKER_FEATURES
255  GLIBCXX_CHECK_MATH_SUPPORT
256  GLIBCXX_CHECK_STDLIB_SUPPORT
257
258  # For /dev/random and /dev/urandom for TR1.
259  GLIBCXX_CHECK_RANDOM_TR1
260
261  # For TLS support.
262  GCC_CHECK_TLS
263
264  AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
265  AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
266
267  # For iconv support.
268  AM_ICONV
269
270else
271
272  # This lets us hard-code the functionality we know we'll have in the cross
273  # target environment.  "Let" is a sugar-coated word placed on an especially
274  # dull and tedious hack, actually.
275  #
276  # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
277  # that involve linking, can't be used:
278  #    "cannot open sim-crt0.o"
279  #    "cannot open crt0.o"
280  # etc.  All this is because there currently exists no unified, consistent
281  # way for top level CC information to be passed down to target directories:
282  # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
283  # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
284  # crosses can be removed.
285
286  # If Canadian cross, then don't pick up tools from the build directory.
287  # Used only in GLIBCXX_EXPORT_INCLUDES.
288  if test -n "$with_cross_host" &&
289     test x"$build_alias" != x"$with_cross_host" &&
290     test x"$build" != x"$target";
291  then
292    CANADIAN=yes
293  else
294    CANADIAN=no
295  fi
296
297  # Construct crosses by hand, eliminating bits that need ld...
298  # GLIBCXX_CHECK_MATH_SUPPORT
299
300  # First, test for "known" system libraries.  We may be using newlib even
301  # on a hosted environment.
302  if test "x${with_newlib}" = "xyes"; then
303    os_include_dir="os/newlib"
304    AC_DEFINE(HAVE_HYPOT)
305
306    # GLIBCXX_CHECK_STDLIB_SUPPORT
307    AC_DEFINE(HAVE_STRTOF)
308
309    AC_DEFINE(HAVE_ACOSF)
310    AC_DEFINE(HAVE_ASINF)
311    AC_DEFINE(HAVE_ATAN2F)
312    AC_DEFINE(HAVE_ATANF)
313    AC_DEFINE(HAVE_CEILF)
314    AC_DEFINE(HAVE_COSF)
315    AC_DEFINE(HAVE_COSHF)
316    AC_DEFINE(HAVE_EXPF)
317    AC_DEFINE(HAVE_FABSF)
318    AC_DEFINE(HAVE_FLOORF)
319    AC_DEFINE(HAVE_FMODF)
320    AC_DEFINE(HAVE_FREXPF)
321    AC_DEFINE(HAVE_LDEXPF)
322    AC_DEFINE(HAVE_LOG10F)
323    AC_DEFINE(HAVE_LOGF)
324    AC_DEFINE(HAVE_MODFF)
325    AC_DEFINE(HAVE_POWF)
326    AC_DEFINE(HAVE_SINF)
327    AC_DEFINE(HAVE_SINHF)
328    AC_DEFINE(HAVE_SQRTF)
329    AC_DEFINE(HAVE_TANF)
330    AC_DEFINE(HAVE_TANHF)
331
332    AC_DEFINE(HAVE_ICONV)
333    AC_DEFINE(HAVE_MEMALIGN)
334  else
335    GLIBCXX_CROSSCONFIG
336  fi
337
338  # At some point, we should differentiate between architectures
339  # like x86, which have long double versions, and alpha/powerpc/etc.,
340  # which don't. For the time being, punt.
341  if test x"long_double_math_on_this_cpu" = x"yes"; then
342    AC_DEFINE(HAVE_ACOSL)
343    AC_DEFINE(HAVE_ASINL)
344    AC_DEFINE(HAVE_ATAN2L)
345    AC_DEFINE(HAVE_ATANL)
346    AC_DEFINE(HAVE_CEILL)
347    AC_DEFINE(HAVE_COSL)
348    AC_DEFINE(HAVE_COSHL)
349    AC_DEFINE(HAVE_EXPL)
350    AC_DEFINE(HAVE_FABSL)
351    AC_DEFINE(HAVE_FLOORL)
352    AC_DEFINE(HAVE_FMODL)
353    AC_DEFINE(HAVE_FREXPL)
354    AC_DEFINE(HAVE_LDEXPL)
355    AC_DEFINE(HAVE_LOG10L)
356    AC_DEFINE(HAVE_LOGL)
357    AC_DEFINE(HAVE_MODFL)
358    AC_DEFINE(HAVE_POWL)
359    AC_DEFINE(HAVE_SINCOSL)
360    AC_DEFINE(HAVE_SINL)
361    AC_DEFINE(HAVE_SINHL)
362    AC_DEFINE(HAVE_SQRTL)
363    AC_DEFINE(HAVE_TANL)
364    AC_DEFINE(HAVE_TANHL)
365  fi
366fi
367
368# Check for _Unwind_GetIPInfo.
369GCC_CHECK_UNWIND_GETIPINFO
370
371GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
372
373GCC_HEADER_STDINT(include/gstdint.h)
374
375GLIBCXX_ENABLE_SYMVERS([yes])
376AC_SUBST(libtool_VERSION)
377
378GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
379
380GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
381GLIBCXX_DEFAULT_ABI
382
383ac_ldbl_compat=no
384LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
385case "$target" in
386  powerpc*-*-linux* | \
387  sparc*-*-linux* | \
388  s390*-*-linux* | \
389  alpha*-*-linux*)
390  AC_TRY_COMPILE(, [
391#if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
392#error no need for long double compatibility
393#endif
394  ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
395  if test "$ac_ldbl_compat" = yes; then
396    AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
397	      [Define if compatibility should be provided for -mlong-double-64.])
398    port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
399    case "$target" in
400      powerpc*-*-linux*)
401	LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute" ;;
402    esac
403  fi
404esac
405AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
406GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
407
408# Check if assembler supports disabling hardware capability support.
409GCC_CHECK_ASSEMBLER_HWCAP
410
411# Check if assembler supports rdrand opcode.
412GLIBCXX_CHECK_X86_RDRAND
413
414# This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
415GLIBCXX_CONFIGURE_TESTSUITE
416
417# For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
418GLIBCXX_CHECK_GTHREADS
419
420# For Filesystem TS.
421AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
422GLIBCXX_ENABLE_FILESYSTEM_TS
423GLIBCXX_CHECK_FILESYSTEM_DEPS
424
425# For Transactional Memory TS
426GLIBCXX_CHECK_SIZE_T_MANGLING
427
428# Check which release added std::exception_ptr for the target
429GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
430
431# Define documentation rules conditionally.
432
433# See if makeinfo has been installed and is modern enough
434# that we can use it.
435ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
436		   [GNU texinfo.* \([0-9][0-9.]*\)],
437		   [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
438AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
439
440# Check for doxygen
441AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
442AC_CHECK_PROG([DOT], dot, yes, no)
443
444# Check for docbook
445AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
446AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
447GLIBCXX_CONFIGURE_DOCBOOK
448
449# Check for xml/html dependencies.
450AM_CONDITIONAL(BUILD_XML,
451	       test $ac_cv_prog_DOXYGEN = "yes" &&
452	       test $ac_cv_prog_DOT = "yes" &&
453	       test $ac_cv_prog_XSLTPROC = "yes" &&
454	       test $ac_cv_prog_XMLLINT = "yes" &&
455	       test $glibcxx_stylesheets = "yes")
456
457AM_CONDITIONAL(BUILD_HTML,
458	       test $ac_cv_prog_DOXYGEN = "yes" &&
459	       test $ac_cv_prog_DOT = "yes" &&
460	       test $ac_cv_prog_XSLTPROC = "yes" &&
461	       test $ac_cv_prog_XMLLINT = "yes" &&
462	       test $glibcxx_stylesheets = "yes")
463
464# Check for man dependencies.
465AM_CONDITIONAL(BUILD_MAN,
466	       test $ac_cv_prog_DOXYGEN = "yes" &&
467	       test $ac_cv_prog_DOT = "yes")
468
469# Check for pdf dependencies.
470AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
471AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
472AM_CONDITIONAL(BUILD_PDF,
473	       test $ac_cv_prog_DBLATEX = "yes" &&
474	       test $ac_cv_prog_PDFLATEX = "yes")
475
476case "$build" in
477 *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
478 * ) glibcxx_include_dir_notparallel=no ;;
479esac
480AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
481               test $glibcxx_include_dir_notparallel = "yes")
482
483# Propagate the target-specific source directories through the build chain.
484ATOMICITY_SRCDIR=config/${atomicity_dir}
485ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
486ATOMIC_FLAGS=${atomic_flags}
487CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
488OS_INC_SRCDIR=config/${os_include_dir}
489ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
490ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
491CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
492CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
493AC_SUBST(ATOMICITY_SRCDIR)
494AC_SUBST(ATOMIC_WORD_SRCDIR)
495AC_SUBST(ATOMIC_FLAGS)
496AC_SUBST(CPU_DEFINES_SRCDIR)
497AC_SUBST(ABI_TWEAKS_SRCDIR)
498AC_SUBST(OS_INC_SRCDIR)
499AC_SUBST(ERROR_CONSTANTS_SRCDIR)
500AC_SUBST(CPU_OPT_EXT_RANDOM)
501AC_SUBST(CPU_OPT_BITS_RANDOM)
502
503
504# Add CET specific flags if Intel CET is enabled.
505GCC_CET_FLAGS(CET_FLAGS)
506EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
507EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
508AC_SUBST(EXTRA_CFLAGS)
509AC_SUBST(EXTRA_CXX_FLAGS)
510
511# Determine cross-compile flags and AM_CONDITIONALs.
512#AC_SUBST(GLIBCXX_IS_NATIVE)
513#AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
514GLIBCXX_EVALUATE_CONDITIONALS
515
516AC_CACHE_SAVE
517
518if test ${multilib} = yes; then
519  multilib_arg="--enable-multilib"
520else
521  multilib_arg=
522fi
523
524# Export all the install information.
525GLIBCXX_EXPORT_INSTALL_INFO
526
527# Export all the include and flag information to Makefiles.
528GLIBCXX_EXPORT_INCLUDES
529GLIBCXX_EXPORT_FLAGS
530
531# Determine what GCC version number to use in filesystem paths.
532GCC_BASE_VER
533
534dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
535dnl which can all be called multiple times as needed, plus one (different)
536dnl AC_OUTPUT macro.  This one lists the files to be created:
537AC_CONFIG_FILES(Makefile)
538AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
539AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
540AC_CONFIG_FILES([doc/xsl/customization.xsl])
541
542# Multilibs need MULTISUBDIR defined correctly in certain makefiles so
543# that multilib installs will end up installed in the correct place.
544# The testsuite needs it for multilib-aware ABI baseline files.
545# To work around this not being passed down from config-ml.in ->
546# srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
547# append it here.  Only modify Makefiles that have just been created.
548#
549# Also, get rid of this simulated-VPATH thing that automake does.
550AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
551  [cat > vpsed$$ << \_EOF
552s!`test -f '$<' || echo '$(srcdir)/'`!!
553_EOF
554   sed -f vpsed$$ $ac_file > tmp$$
555   mv tmp$$ $ac_file
556   rm vpsed$$
557   echo 'MULTISUBDIR =' >> $ac_file
558   ml_norecursion=yes
559   . ${multi_basedir}/config-ml.in
560   AS_UNSET([ml_norecursion])
561])
562
563AC_CONFIG_COMMANDS([generate-headers],
564  [(cd include && ${MAKE-make} pch_build= )])
565
566dnl And this actually makes things happen:
567AC_OUTPUT
568