1// RUN: mlir-opt %s \
2// RUN:   -convert-scf-to-std \
3// RUN:   -gpu-kernel-outlining \
4// RUN:   -pass-pipeline='gpu.module(strip-debuginfo,convert-gpu-to-rocdl,gpu-to-hsaco)' \
5// RUN:   -gpu-to-llvm \
6// RUN: | mlir-cpu-runner \
7// RUN:   --shared-libs=%linalg_test_lib_dir/libmlir_rocm_runtime%shlibext \
8// RUN:   --shared-libs=%linalg_test_lib_dir/libmlir_runner_utils%shlibext \
9// RUN:   --entry-point-result=void \
10// RUN: | FileCheck %s
11
12func @vecadd(%arg0 : memref<?xf32>, %arg1 : memref<?xf32>, %arg2 : memref<?xf32>) {
13  %c0 = constant 0 : index
14  %c1 = constant 1 : index
15  %block_dim = dim %arg0, %c0 : memref<?xf32>
16  gpu.launch blocks(%bx, %by, %bz) in (%grid_x = %c1, %grid_y = %c1, %grid_z = %c1)
17             threads(%tx, %ty, %tz) in (%block_x = %block_dim, %block_y = %c1, %block_z = %c1) {
18    %a = load %arg0[%tx] : memref<?xf32>
19    %b = load %arg1[%tx] : memref<?xf32>
20    %c = addf %a, %b : f32
21    store %c, %arg2[%tx] : memref<?xf32>
22    gpu.terminator
23  }
24  return
25}
26
27// CHECK: [2.46, 2.46, 2.46, 2.46, 2.46]
28func @main() {
29  %c0 = constant 0 : index
30  %c1 = constant 1 : index
31  %c5 = constant 5 : index
32  %cf1dot23 = constant 1.23 : f32
33  %0 = alloc() : memref<5xf32>
34  %1 = alloc() : memref<5xf32>
35  %2 = alloc() : memref<5xf32>
36  %3 = memref_cast %0 : memref<5xf32> to memref<?xf32>
37  %4 = memref_cast %1 : memref<5xf32> to memref<?xf32>
38  %5 = memref_cast %2 : memref<5xf32> to memref<?xf32>
39  scf.for %i = %c0 to %c5 step %c1 {
40    store %cf1dot23, %3[%i] : memref<?xf32>
41    store %cf1dot23, %4[%i] : memref<?xf32>
42  }
43  %6 = memref_cast %3 : memref<?xf32> to memref<*xf32>
44  %7 = memref_cast %4 : memref<?xf32> to memref<*xf32>
45  %8 = memref_cast %5 : memref<?xf32> to memref<*xf32>
46  gpu.host_register %6 : memref<*xf32>
47  gpu.host_register %7 : memref<*xf32>
48  gpu.host_register %8 : memref<*xf32>
49  %9 = call @mgpuMemGetDeviceMemRef1dFloat(%3) : (memref<?xf32>) -> (memref<?xf32>)
50  %10 = call @mgpuMemGetDeviceMemRef1dFloat(%4) : (memref<?xf32>) -> (memref<?xf32>)
51  %11 = call @mgpuMemGetDeviceMemRef1dFloat(%5) : (memref<?xf32>) -> (memref<?xf32>)
52
53  call @vecadd(%9, %10, %11) : (memref<?xf32>, memref<?xf32>, memref<?xf32>) -> ()
54  call @print_memref_f32(%8) : (memref<*xf32>) -> ()
55  return
56}
57
58func private @mgpuMemGetDeviceMemRef1dFloat(%ptr : memref<?xf32>) -> (memref<?xf32>)
59func private @print_memref_f32(%ptr : memref<*xf32>)
60