1# - try to find QVRPN library
2#
3# Of course, you may also just choose to make QVRPN a submodule of your
4# project itself.
5#
6# Cache Variables:
7#  QVRPN_LIBRARY
8#  QVRPN_INCLUDE_DIR
9#
10# Non-cache variables you might use in your CMakeLists.txt:
11#  QVRPN_FOUND
12#  QVRPN_LIBRARIES
13#  QVRPN_INCLUDE_DIRS
14#
15# QVRPN_ROOT_DIR is searched preferentially for these files
16#
17# Requires these CMake modules:
18#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
19#
20# Refactored from FindVRPN.cmake by:
21# Juan Sebastian Casallas <casallas@iastate.edu>
22#
23# FindVRPN.cmake Original Author:
24# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
25# http://academic.cleardefinition.com
26# Iowa State University HCI Graduate Program/VRAC
27#
28# Copyright Iowa State University 2009-2012.
29# Distributed under the Boost Software License, Version 1.0.
30# (See accompanying file LICENSE_1_0.txt or copy at
31# http://www.boost.org/LICENSE_1_0.txt)
32
33set(QVRPN_ROOT_DIR
34	"${QVRPN_ROOT_DIR}"
35	CACHE
36	PATH
37	"Root directory to search for QVRPN")
38
39if(CMAKE_SIZEOF_VOID_P MATCHES "8")
40	set(_LIBSUFFIXES /lib64 /lib)
41else()
42	set(_LIBSUFFIXES /lib)
43endif()
44
45###
46# Configure QVRPN
47###
48
49find_path(QVRPN_INCLUDE_DIR
50	NAMES
51	vrpn_QMainloopContainer.h
52	PATH_SUFFIXES
53	include
54	include/qvrpn
55	HINTS
56	"${QVRPN_ROOT_DIR}")
57
58find_library(QVRPN_LIBRARY
59	NAMES
60	qvrpn
61	PATH_SUFFIXES
62	${_libsuffixes}
63	HINTS
64	"${QVRPN_ROOT_DIR}")
65
66# handle the QUIETLY and REQUIRED arguments and set xxx_FOUND to TRUE if
67# all listed variables are TRUE
68include(FindPackageHandleStandardArgs)
69find_package_handle_standard_args(QVRPN
70	DEFAULT_MSG
71	QVRPN_LIBRARY
72	QVRPN_INCLUDE_DIR)
73
74if(QVRPN_FOUND)
75	set(QVRPN_INCLUDE_DIRS "${QVRPN_INCLUDE_DIR}")
76	set(QVRPN_LIBRARIES "${QVRPN_LIBRARY}")
77
78	mark_as_advanced(QVRPN_ROOT_DIR)
79endif()
80
81mark_as_advanced(QVRPN_LIBRARY QVRPN_INCLUDE_DIR)
82