1# - try to find cppunit library
2#
3# Cache Variables: (probably not for direct use in your scripts)
4#  CPPUNIT_INCLUDE_DIR
5#  CPPUNIT_LIBRARY
6#
7# Non-cache variables you might use in your CMakeLists.txt:
8#  CPPUNIT_FOUND
9#  CPPUNIT_INCLUDE_DIRS
10#  CPPUNIT_LIBRARIES
11#
12# Requires these CMake modules:
13#  SelectLibraryConfigurations (included with CMake >= 2.8.0)
14#  FindPackageHandleStandardArgs (known included with CMake >=2.6.2)
15#
16# Original Author:
17# 2009-2011 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
18# http://academic.cleardefinition.com
19# Iowa State University HCI Graduate Program/VRAC
20#
21# Copyright Iowa State University 2009-2011.
22# Distributed under the Boost Software License, Version 1.0.
23# (See accompanying file LICENSE_1_0.txt or copy at
24# http://www.boost.org/LICENSE_1_0.txt)
25
26set(CPPUNIT_ROOT_DIR
27	"${CPPUNIT_ROOT_DIR}"
28	CACHE
29	PATH
30	"Directory to search")
31
32find_library(CPPUNIT_LIBRARY_RELEASE
33	NAMES
34	cppunit
35	HINTS
36	"${CPPUNIT_ROOT_DIR}")
37
38find_library(CPPUNIT_LIBRARY_DEBUG
39	NAMES
40	cppunitd
41	HINTS
42	"${CPPUNIT_ROOT_DIR}")
43
44include(SelectLibraryConfigurations)
45select_library_configurations(CPPUNIT)
46
47# Might want to look close to the library first for the includes.
48get_filename_component(_libdir "${CPPUNIT_LIBRARY_RELEASE}" PATH)
49
50find_path(CPPUNIT_INCLUDE_DIR
51	NAMES
52	cppunit/TestCase.h
53	HINTS
54	"${_libdir}/.."
55	PATHS
56	"${CPPUNIT_ROOT_DIR}"
57	PATH_SUFFIXES
58	include/)
59
60
61include(FindPackageHandleStandardArgs)
62find_package_handle_standard_args(cppunit
63	DEFAULT_MSG
64	CPPUNIT_LIBRARY
65	CPPUNIT_INCLUDE_DIR)
66
67if(CPPUNIT_FOUND)
68	set(CPPUNIT_LIBRARIES ${CPPUNIT_LIBRARY} ${CMAKE_DL_LIBS})
69	set(CPPUNIT_INCLUDE_DIRS "${CPPUNIT_INCLUDE_DIR}")
70	mark_as_advanced(CPPUNIT_ROOT_DIR)
71endif()
72
73mark_as_advanced(CPPUNIT_INCLUDE_DIR
74	CPPUNIT_LIBRARY_RELEASE
75	CPPUNIT_LIBRARY_DEBUG)
76