1in vec3 position1;
2in vec3 position2;
3in float bone1; // No ints as shader attributes in GLSL 1.20
4in float bone2; // No ints as shader attributes in GLSL 1.20
5in float boneWeight;
6in vec3 normal;
7in vec2 texcoord;
8
9out vec2 Texcoord;
10out vec3 Color;
11
12struct Light {
13	vec4 position;
14	vec3 direction;
15	vec3 color;
16	vec4 params;
17};
18
19const int lightTypePoint       = 1;
20const int lightTypeDirectional = 2;
21const int lightTypeSpot        = 4;
22
23const int maxLights = 10;
24const int maxBones = 70;
25
26uniform mat4 modelViewMatrix;
27uniform mat4 projectionMatrix;
28uniform mat3 normalMatrix;
29uniform vec4 boneRotation[maxBones];
30uniform vec3 bonePosition[maxBones];
31uniform Light lights[maxLights];
32uniform vec3 ambientColor;
33uniform vec3 color;
34uniform bool textured;
35
36vec4 eyePosition;
37vec3 eyeNormal;
38
39vec3 qrot(vec4 q, vec3 v) {
40	return v + 2.0 * cross(q.xyz, cross(q.xyz, v) + q.w * v);
41}
42
43vec3 pointLight(vec3 position, vec3 color, float falloffNear, float falloffFar) {
44	vec3 vertexToLight = position - eyePosition.xyz;
45
46	float dist = length(vertexToLight);
47	float attn = clamp((falloffFar - dist) / max(0.001, falloffFar - falloffNear), 0.0, 1.0);
48
49	vertexToLight = normalize(vertexToLight);
50	float incidence = max(0.0, dot(eyeNormal, vertexToLight));
51
52	return color * attn * incidence;
53}
54
55vec3 directionalLight(vec3 direction, vec3 color) {
56	float incidence = max(0.0, dot(eyeNormal, -direction));
57
58	return color * incidence;
59}
60
61vec3 spotLight(vec3 position, vec3 color, float falloffNear, float falloffFar, vec3 direction, float cosInnerAngle, float cosOuterAngle) {
62	vec3 vertexToLight = position - eyePosition.xyz;
63	vertexToLight = normalize(vertexToLight);
64
65	float cosAngle = max(0.0, dot(vertexToLight, -direction));
66	float cone = clamp((cosAngle - cosInnerAngle) / max(0.001, cosOuterAngle - cosInnerAngle), 0.0, 1.0);
67
68	return pointLight(position, color, falloffNear, falloffFar) * cone;
69}
70
71void main()
72{
73	Texcoord = texcoord;
74
75	// Compute the vertex position in eye-space
76	vec3 b1 = qrot(boneRotation[int(bone1)], position1) + bonePosition[int(bone1)];
77	vec3 b2 = qrot(boneRotation[int(bone2)], position2) + bonePosition[int(bone2)];
78	vec3 modelPosition = mix(b2, b1, boneWeight);
79	eyePosition = modelViewMatrix * vec4(modelPosition.xyz, 1.0);
80
81	// Compute the vertex normal in eye-space
82	vec3 n1 = qrot(boneRotation[int(bone1)], normal);
83	vec3 n2 = qrot(boneRotation[int(bone2)], normal);
84	vec3 modelNormal = normalize(mix(n2, n1, boneWeight));
85	eyeNormal = normalMatrix * modelNormal;
86	eyeNormal = normalize(eyeNormal);
87
88	// Compute the vertex position in screen-space
89	gl_Position = projectionMatrix * eyePosition;
90
91	// Set the initial vertex color
92	if (textured) {
93		Color = vec3(1.0);
94	} else {
95		Color = color;
96	}
97
98	// Shade the vertex color according to the lights
99	vec3 lightColor = ambientColor;
100	for (int i = 0; i < maxLights; i++) {
101		int type = int(lights[i].position.w);
102		if (type == lightTypePoint) {
103			lightColor += pointLight(lights[i].position.xyz, lights[i].color, lights[i].params.x, lights[i].params.y);
104		} else if (type == lightTypeDirectional) {
105			lightColor += directionalLight(lights[i].direction, lights[i].color);
106		} else if (type == lightTypeSpot) {
107			lightColor += spotLight(lights[i].position.xyz, lights[i].color, lights[i].params.x, lights[i].params.y,
108									lights[i].direction, lights[i].params.z, lights[i].params.w);
109		}
110	}
111
112	Color *= clamp(lightColor, 0.0, 1.0);
113}
114